Private Enum DataLocationIds

 data\_row = 3 'Номер строки начала таблицы с данными

 LastName = 1

 FirstName = 2

 MiddleName = 3

 Snils = 4

 Position = 5

 EmployerInn = 6

 EmployerTitle = 7

 Inn = 8

 Title = 9

 TestisPassed = 10

 learnProgramId = 11

 LearnProgramTitle = 12

 Date = 13

 ProtocolNumber = 14

End Enum

Public Sub ExportXML2()

 Dim dataArr As Variant

 Dim rootNode As Object, xmlDoc As Object, i As Long

 dataArr = getDataArray

 Set xmlDoc = getXmlDoc

 Set rootNode = xmlDoc.createElement("RegistryRecord")

 xmlDoc.appendChild rootNode

 For i = 1 To UBound(dataArr)

 rootNode.appendChild getWorkerNode(xmlDoc, i, dataArr)

 rootNode.appendChild getOrganizationNode(xmlDoc, i, dataArr)

 rootNode.appendChild getTestNode(xmlDoc, i, dataArr)

 Next

 transformXML xmlDoc

 xmlDoc.Save Application.GetSaveAsFilename(FileFilter:="Файл экспорта (\*.xml),\*.xml", Title:="Введите имя файла")

End Sub

Private Function getDataArray() As Variant

 Dim pSheet As Worksheet, LRow As Long

 Set pSheet = ActiveSheet

 LRow = pSheet.Cells(pSheet.Rows.Count, DataLocationIds.LastName).End(xlUp).Row

 getDataArray = pSheet.Range(pSheet.Cells(DataLocationIds.data\_row, DataLocationIds.LastName), pSheet.Cells(LRow, DataLocationIds.ProtocolNumber)).Value

End Function

Private Function getXmlDoc() As Object

 Dim xmlDoc As Object

 Set xmlDoc = CreateObject("MSXML2.DOMDocument")

 xmlDoc.appendChild xmlDoc.createProcessingInstruction("xml", "version='1.0' encoding='utf-8'")

 Set getXmlDoc = xmlDoc

End Function

Private Function getWorkerNode(ByVal xmlDoc As Object, ByVal curRow As Long, ByVal dataArr As Variant) As Object

 Dim pNode As Object

 Set pNode = xmlDoc.createElement("Worker")

 'pNode.setAttribute "num", dataArr(curRow, DataLocationIds.certNum)

 pNode.appendChild(xmlDoc.createElement("LastName")).Text = dataArr(curRow, DataLocationIds.LastName)

 pNode.appendChild(xmlDoc.createElement("FirstName")).Text = dataArr(curRow, DataLocationIds.FirstName)

 pNode.appendChild(xmlDoc.createElement("MiddleName")).Text = dataArr(curRow, DataLocationIds.MiddleName)

 pNode.appendChild(xmlDoc.createElement("Snils")).Text = dataArr(curRow, DataLocationIds.Snils)

 pNode.appendChild(xmlDoc.createElement("Position")).Text = dataArr(curRow, DataLocationIds.Position)

 pNode.appendChild(xmlDoc.createElement("EmployerInn")).Text = dataArr(curRow, DataLocationIds.EmployerInn)

 pNode.appendChild(xmlDoc.createElement("EmployerTitle")).Text = dataArr(curRow, DataLocationIds.EmployerTitle)

 Set getWorkerNode = pNode

 End Function

 Private Function getOrganizationNode(ByVal xmlDoc As Object, ByVal curRow As Long, ByVal dataArr As Variant) As Object

 Dim pNode As Object

 Set pNode = xmlDoc.createElement("Organization")

 'pNode.setAttribute "num", dataArr(curRow, DataLocationIds.certNum)

 pNode.appendChild(xmlDoc.createElement("Inn")).Text = dataArr(curRow, DataLocationIds.Inn)

 pNode.appendChild(xmlDoc.createElement("Title")).Text = dataArr(curRow, DataLocationIds.Title)

 Set getOrganizationNode = pNode

End Function

Private Function getTestNode(ByVal xmlDoc As Object, ByVal curRow As Long, ByVal dataArr As Variant) As Object

 Dim pNode As Object

 Set pNode = xmlDoc.createElement("Test")

 'pNode.setAttribute "num", dataArr(curRow, DataLocationIds.certNum)

 pNode.appendChild(xmlDoc.createElement("TestisPassed")).Text = dataArr(curRow, DataLocationIds.TestisPassed)

pNode.appendChild(xmlDoc.createElement("Date")).Text = dataArr(curRow, DataLocationIds.Date)

pNode.appendChild(xmlDoc.createElement("learnProgramId")).Text = dataArr(curRow, DataLocationIds.learnProgramId)

pNode.appendChild(xmlDoc.createElement("ProtocolNumber")).Text = dataArr(curRow, DataLocationIds.ProtocolNumber)

pNode.appendChild(xmlDoc.createElement("LearnProgramTitle")).Text = dataArr(curRow, DataLocationIds.LearnProgramTitle)

 Set getTestNode = pNode

End Function

'Процедура для придания XML читабельного вида (с отступами)

Sub transformXML(ByRef xml As Variant)

 'Cоздание объекта XSL

 Set xsl = CreateObject("MSXML2.DOMDocument")

 'Загрузка XSL из строки (не требует наличия отдельного XSL-файла)

 xsl.LoadXML ("<xsl:stylesheet version='1.0' xmlns:xsl='http://www.w3.org/1999/XSL/Transform'>" & vbCrLf & \_

 "<xsl:output method='xml' version='1.0' encoding='utf-8' indent='yes'/>" & vbCrLf & \_

 "<xsl:template match='@\*|node()'>" & vbCrLf & \_

 "<xsl:copy>" & vbCrLf & \_

 "<xsl:apply-templates select='@\*|node()' />" & vbCrLf & \_

 "</xsl:copy>" & vbCrLf & \_

 "</xsl:template>" & vbCrLf & \_

 "</xsl:stylesheet>")

 'Выполнение преобразования

 xml.transformNodeToObject xsl, xml

End Sub