Sub selectData()
                      
     Dim rst As Object
     Set rst = CreateObject("ADODB.Recordset")
                  
     rst.Open _
     "TRANSFORM First(Value) " & _
     "SELECT Row " & _
     "FROM [Лист1$K:M] " & _
     "GROUP BY Row " & _
     "PIVOT Column" _
     , _
     "Provider=Microsoft.ACE.OLEDB.12.0;" & _
     "Data Source=" & ThisWorkbook.FullName & ";" & _
     "Extended Properties='Excel 12.0;HDR=Yes'"
                  
     [Лист1!P2].CopyFromRecordset rst
                    
     'Заголовки
     Dim i As Integer
     Dim arrName() As Variant
     ReDim Preserve arrName(0 To rst.Fields.Count - 1)
     For i = 0 To rst.Fields.Count - 1
         arrName(i) = rst.Fields(i).Name
     Next i
     With Range("P1").Resize(1, rst.Fields.Count)
         .Value = arrName
         .Font.Bold = True
     End With

End Sub

Sub parseRawText2()
     Dim rngSource As Range, c As Range
     Dim i As Integer, j As Integer
     Dim arrRow, arrVal, arrOut()

     Set rngSource = Range("A2:A3")
          
     ReDim arrOut(1 To rngSource.Cells.Count * 20, 1 To 3)
          
     For Each c In rngSource.Cells
         arrRow = Split(c, ";")
         For i = LBound(arrRow) To UBound(arrRow)
             arrVal = Split(arrRow(i), ":")
             j = j + 1
             arrOut(j, 1) = c.Row
             arrOut(j, 2) = arrVal(0)
             arrOut(j, 3) = "'" & arrVal(1) 'ВНИМАНИЕ! здесь поменялось!
         Next i
     Next c
          
     With Range("K1").Resize(1, 3)
         .Value = Array("Row", "Column", "Value") 'и здесь поменялось!
         .Font.Bold = True
     End With
     Range("K2").Resize(j, 3).Value = arrOut
End Sub