Public stolb As Integer
Public stolbV As Integer
Public strokaFirst As Integer

Private Sub UserForm_Initialize()
     stolb = 1       'задаем столбец для поиска А-1 В-2 С-3 и тд
     stolbV = 7      'задаем столбец для выбора А-1 В-2 С-3 и тд
     strokaFirst = 2 'задаем номер верхней строки, начиная с которой осуществляем поиск
End Sub

Private Sub TextBox1_Change()
'очистка списка найденых элементов
     ListBox1.Clear
'при отсутствии символов для поиска - выход
     If Len(TextBox1.Value) = 0 Then Exit Sub
'вычисляем номер последней строки, до которой осуществляем поиск
     strokaLast = Cells(Rows.Count, stolb).End(xlUp).Row
'задаем индекс первого элемента списка ListBox1
     j = 0
'переводим искомый текст в вверхний регистр
     textS = UCase(TextBox1.Value)

  For i = strokaFirst To strokaLast
   'для одного символа
      If Len(TextBox1.Value) = 1 Then
         If UCase(Left(Cells(i, stolb), 1)) = textS Then
           'при совпадении добавляем элемент в список
            ListBox1.AddItem i
            ListBox1.List(j, 1) = Cells(i, stolb)
           'задаем индекс для следующего элемента списка
            j = j + 1
         End If
   'для двух и более символов
      Else
         If InStr(1, UCase(Cells(i, stolb)), textS) > 0 Then
           'при совпадении добавляем элемент в список
            ListBox1.AddItem i
            ListBox1.List(j, 1) = Cells(i, stolb)
           'задаем индекс для следующего элемента списка
            j = j + 1
         End If
      End If
  Next
   
'если найден только один эл-т, то переходим к нему
      If j = 1 Then Cells(ListBox1.List(0, 0), stolbV).Select
End Sub

Private Sub ListBox1_Click()
'если не выбран элемент списка - выход
    If ListBox1.ListIndex = -1 Then Exit Sub
'переход к ячейке листа, содержащей выбранный элемент списка
    Cells(ListBox1.Value, stolbV).Select
End Sub