Удаление информации с ячейки Листа 1 - фраз в листе 2

Старая форма входа

Страница 1 из 1 1
Модератор форума: китин, _Boroda_

Мир MS Excel » Вопросы и решения » Вопросы по VBA » Удаление информации с ячейки Листа 1 - фраз в листе 2 (Макросы/Sub)

wwizard

Дата: Понедельник, 26.12.2016, 19:15 | Сообщение № 1

Группа: Проверенные

Ранг: Форумчанин

Сообщений: 176

Репутация: 0 ±

Замечаний: 40% ±

Существует книга. На первом Листе содержится прайс лист. В Колонке №9 которого есть не нужные мне слова.
На листе 2, в столбце 4 - прописаны теже слова, которые мне не нужны.
Требуется, небольшой макрос, который может Убрать с Листа 1 столбца 9, слова представленные в Листе 2 столбец 4
Пример приложил.
Спасибо.

К сообщению приложен файл: 1111387.xlsx (9.7 Kb)

Ответить

Karataev

Дата: Понедельник, 26.12.2016, 19:27 | Сообщение № 2

Группа: Проверенные

Ранг: Старожил

Сообщений: 1334

Репутация: 533 ±

Замечаний: 0% ±

Excel

В коде есть комментарий, под ним Вы можете указать нужные имена листов.
[vba]

Код

Sub Удалить_ненужные_слова()

    Dim sh1 As Worksheet, sh2 As Worksheet, arr1()
    Dim lr As Long, i As Long

    Application.ScreenUpdating = False

    'здесь укажите имена листов
    Set sh1 = Worksheets("Лист1")
    Set sh2 = Worksheets("Лист2")

    lr = sh1.Cells(sh1.Rows.Count, "I").End(xlUp).Row
    arr1() = sh1.Range("I1:I" & lr).Value

    For i = 2 To UBound(arr1)
        If WorksheetFunction.CountIf(sh2.Columns("D"), arr1(i, 1)) <> 0 Then
            arr1(i, 1) = Empty
        End If
    Next

    sh1.Range("I1:I" & UBound(arr1)).Value = arr1()

    Application.ScreenUpdating = True

    MsgBox "Готово!", vbInformation

End Sub

[/vba]

Ответить

Wasilich

Дата: Понедельник, 26.12.2016, 20:39 | Сообщение № 3

Группа: Друзья

Ранг: Старожил

Сообщений: 1232

Репутация: 326 ±

Замечаний: 0% ±

2003

Это уже для другого прайса?

[vba]

Код

Sub www()
  Dim s&, j&, DL$
  s = Range("I" & Rows.Count).End(xlUp).Row
  With Sheets("Лист2")
    For j = 2 To .Range("D" & Rows.Count).End(xlUp).Row
       DL = .Cells(j, 4)
       Range("I2:I" & s).Replace DL, "", xlPart
    Next
  End With
End Sub

[/vba]

Сообщение отредактировал Wasilich - Понедельник, 26.12.2016, 22:57

Ответить

Мир MS Excel » Вопросы и решения » Вопросы по VBA » Удаление информации с ячейки Листа 1 - фраз в листе 2 (Макросы/Sub)

Страница 1 из 1
1