Option Explicit
    
'ВАЖНО: для успешности всего процесса следует включить "галочку" в меню Excel:
'Разработчик / Безопасность макросов/ Параметры макросов / опция "Доверять доступ к объкетной модели VBA" - устанавливаем!
    
'для использования в программе и получения информации о следующих объектах:
' -- в Excel перейти в редактор Visual Basic,
' -- в меню Tools/References подключить "галочкой" ссылку на
'    "Microsoft Visual Basic for Applications Extensibility 5.3"
'    (расположение на диске: C:\Program Files\Common Files\Microsoft Shared\VBA\VBA6\VBE6EXT.OLB)
' -- в меню View/Object Browser (F2) порассматривать библиотеку VBIDE
    
Dim vbc     As VBComponents
Dim vbmdl   As VBComponent
Dim vbcode  As CodeModule
    
Sub runTemporarySub()
        
    '1. в текущей рабочей книге создаем новый модуль
    Set vbc = ThisWorkbook.VBProject.VBComponents
    Set vbmdl = vbc.Add(1)
    vbmdl.Name = "OurTemporaryModule"
    Set vbcode = vbmdl.CodeModule
        
    '2. добавляем строки кода новой процедуры в новый модуль
    addCodeLine "Sub newSub20170412()"
    addCodeLine "    MsgBox ""Привет из новой Sub"""
    addCodeLine "End Sub"
        
    '3. выполняем только что созданную процедуру
    Application.Run "newSub20170412"
        
    '4. удаляем только что созданный модуль
    vbmdl.Collection.Remove vbmdl
    
End Sub
    
Sub addCodeLine(codeText As String)
    vbcode.InsertLines vbcode.CountOfLines + 1, codeText
    'самый первый раз CountOfLines необходимо на тот случай,
    'если ваш Excel настроен на автоматическое добавление
    'оператора Option Explicit в новый модуль
End Sub

    For i = 1 To 3
        ActiveWorkbook.VBProject.VBComponents(1).CodeModule.ReplaceLine i + 1, Range("J" & 22 + i)
    Next i

Sub runDynamicOperator()
    With CreateObject("ScriptControl")
        .Language = "vbscript"
        .AddObject "xlApp", Excel.Application
        .ExecuteStatement "xlApp.Range(""C4"").Value = ""ПРИВЕТ из динамического оператора"""
    End With
End Sub