Домашняя страница Undo Do Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Макрос Outlook по сбору адресатов - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: _Boroda_, китин  
Мир MS Excel » Вопросы и решения » Excel и другие приложения » Outlook » Макрос Outlook по сбору адресатов (Иное/Other)
Макрос Outlook по сбору адресатов
Денис Дата: Вторник, 30.12.2014, 16:59 | Сообщение № 1
Группа: Гости
Добрый день, есть Outlook с папками входящие, отправленные и их подпапками.
Необходимо пройти по всем письмам и составить список уникальных E-mail адресов, для дальнейшей рассылки. Приветсвуется созданиие в Excel списка.
Можно просто через точку с запятой.
Также хотелось бы условие по наличию определенного домена в адресате, чтобы отобрать письма только от одного домена.
 
Ответить
СообщениеДобрый день, есть Outlook с папками входящие, отправленные и их подпапками.
Необходимо пройти по всем письмам и составить список уникальных E-mail адресов, для дальнейшей рассылки. Приветсвуется созданиие в Excel списка.
Можно просто через точку с запятой.
Также хотелось бы условие по наличию определенного домена в адресате, чтобы отобрать письма только от одного домена.

Автор - Денис
Дата добавления - 30.12.2014 в 16:59
Gustav Дата: Суббота, 10.01.2015, 04:20 | Сообщение № 2
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2697
Репутация: 1123 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
Приведенное ниже решает поставленную задачу. Код надо поместить в модуль VBA в Excel и запустить на выполнение процедуру main. Результатом будет создание новой книги со списком уникальных адресов. Предполагается, что дальнейшую необходимую обработку списка (сортировку, выделение домена после "собаки" и т.п.) можно будет сделать вручную на рабочем листе.
[vba]
Код
Option Explicit

Dim colAddress As Collection

Sub main() 'запускаем эту процедуру

     Dim olApp   As Object 'Outlook.Application
     Dim fldr    As Object 'Outlook.Folder
     Dim arr(), i
      
     Set colAddress = New Collection
      
     Set olApp = CreateObject("Outlook.Application")
      
     'обрабатываем папку Входящие и вложенные в нее
     Set fldr = olApp.Session.GetDefaultFolder(6)  '6 = olFolderInbox
     Call processFolder(fldr)
      
     'обрабатываем папку Исходящие и вложенные в нее
     Set fldr = olApp.Session.GetDefaultFolder(5) '5 = olFolderSentMail
     Call processFolder(fldr)
      
     'вывод уникальных адресов в новую книгу Excel
     ReDim arr(1 To colAddress.Count, 1 To 1)
     For i = 1 To colAddress.Count
         arr(i, 1) = colAddress(i)
     Next i
     Application.Workbooks.Add.Worksheets(1).Range("A1").Resize(colAddress.Count) = arr
      
End Sub

Sub processFolder(ByVal pFolder As Object) 'Outlook.Folder)
     Dim fldr    As Object 'Outlook.Folder
     Dim item    As Object
     Dim mail    As Object 'Outlook.mailItem
     Dim rcpnt   As Object 'Outlook.Recipient
     Dim i

     'перебор элементов в папке
     For Each item In pFolder.Items
         If item.Class = 43 Then 'обрабатываем только письма, 43 = olMail
             Set mail = item
             i = i + 1
             'If i > 10 Then Exit For
             Debug.Print "Письмо " & i & " в папке " & pFolder.Name
             Call addAddress(mail.Sender, mail.Sender.Address) 'запоминаем отправителя
             For Each rcpnt In mail.Recipients 'цикл по получателям
                 Call addAddress(rcpnt.AddressEntry, rcpnt.Address) 'запоминаем получателя
             Next rcpnt
             Set mail = Nothing
         End If
     Next item
      
     'перебор папок (первого уровня вложенности)
     For Each fldr In pFolder.Folders
         Call processFolder(fldr) 'рекурсия
     Next fldr
End Sub

Sub addAddress(ByVal pAddressEntry As Object, _
                ByVal altaddr As String) 'Outlook.AddressEntry
     Dim pa      As Object 'PropertyAccessor
     Dim addr    As String
     Set pa = pAddressEntry.PropertyAccessor
     On Error Resume Next
     addr = pa.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x39FE001E")
     If addr = "" Then addr = altaddr
     colAddress.Add addr, addr 'добавляем уникальный адрес
     On Error GoTo 0
End Sub
[/vba]


МОИ: Ник, Tip box: 41001663842605
 
Ответить
СообщениеПриведенное ниже решает поставленную задачу. Код надо поместить в модуль VBA в Excel и запустить на выполнение процедуру main. Результатом будет создание новой книги со списком уникальных адресов. Предполагается, что дальнейшую необходимую обработку списка (сортировку, выделение домена после "собаки" и т.п.) можно будет сделать вручную на рабочем листе.
[vba]
Код
Option Explicit

Dim colAddress As Collection

Sub main() 'запускаем эту процедуру

     Dim olApp   As Object 'Outlook.Application
     Dim fldr    As Object 'Outlook.Folder
     Dim arr(), i
      
     Set colAddress = New Collection
      
     Set olApp = CreateObject("Outlook.Application")
      
     'обрабатываем папку Входящие и вложенные в нее
     Set fldr = olApp.Session.GetDefaultFolder(6)  '6 = olFolderInbox
     Call processFolder(fldr)
      
     'обрабатываем папку Исходящие и вложенные в нее
     Set fldr = olApp.Session.GetDefaultFolder(5) '5 = olFolderSentMail
     Call processFolder(fldr)
      
     'вывод уникальных адресов в новую книгу Excel
     ReDim arr(1 To colAddress.Count, 1 To 1)
     For i = 1 To colAddress.Count
         arr(i, 1) = colAddress(i)
     Next i
     Application.Workbooks.Add.Worksheets(1).Range("A1").Resize(colAddress.Count) = arr
      
End Sub

Sub processFolder(ByVal pFolder As Object) 'Outlook.Folder)
     Dim fldr    As Object 'Outlook.Folder
     Dim item    As Object
     Dim mail    As Object 'Outlook.mailItem
     Dim rcpnt   As Object 'Outlook.Recipient
     Dim i

     'перебор элементов в папке
     For Each item In pFolder.Items
         If item.Class = 43 Then 'обрабатываем только письма, 43 = olMail
             Set mail = item
             i = i + 1
             'If i > 10 Then Exit For
             Debug.Print "Письмо " & i & " в папке " & pFolder.Name
             Call addAddress(mail.Sender, mail.Sender.Address) 'запоминаем отправителя
             For Each rcpnt In mail.Recipients 'цикл по получателям
                 Call addAddress(rcpnt.AddressEntry, rcpnt.Address) 'запоминаем получателя
             Next rcpnt
             Set mail = Nothing
         End If
     Next item
      
     'перебор папок (первого уровня вложенности)
     For Each fldr In pFolder.Folders
         Call processFolder(fldr) 'рекурсия
     Next fldr
End Sub

Sub addAddress(ByVal pAddressEntry As Object, _
                ByVal altaddr As String) 'Outlook.AddressEntry
     Dim pa      As Object 'PropertyAccessor
     Dim addr    As String
     Set pa = pAddressEntry.PropertyAccessor
     On Error Resume Next
     addr = pa.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x39FE001E")
     If addr = "" Then addr = altaddr
     colAddress.Add addr, addr 'добавляем уникальный адрес
     On Error GoTo 0
End Sub
[/vba]

Автор - Gustav
Дата добавления - 10.01.2015 в 04:20
kkol Дата: Вторник, 17.03.2015, 15:36 | Сообщение № 3
Группа: Пользователи
Ранг: Новичок
Сообщений: 17
Репутация: 0 ±
Замечаний: 20% ±

Excel 2010
Уважаемый Gustav,
совершенно случайно обнаружил ваш пост, и оказалось это именно то что надо. У меня очень большая корреспонденция за день, и я естественно распределяю принятую почту по темам, то есть по папкам раскидываю.

Вопрос: Что надо изменить для поиска адресов только во вложенной папке с уникальным именем?


kkol#list.ru
 
Ответить
СообщениеУважаемый Gustav,
совершенно случайно обнаружил ваш пост, и оказалось это именно то что надо. У меня очень большая корреспонденция за день, и я естественно распределяю принятую почту по темам, то есть по папкам раскидываю.

Вопрос: Что надо изменить для поиска адресов только во вложенной папке с уникальным именем?

Автор - kkol
Дата добавления - 17.03.2015 в 15:36
Pisozo Дата: Вторник, 19.04.2016, 04:20 | Сообщение № 4
Группа: Пользователи
Ранг: Прохожий
Сообщений: 1
Репутация: 0 ±
Замечаний: 0% ±

Excel 2007
Gustav, подскажите пожалуйста
на строке
[vba]
Код
Call addAddress(mail.Sender, mail.Sender.Address) 'запоминаем отправителя
[/vba]

выдает ошибку 438

как исправить
:'(


Сообщение отредактировал Pisozo - Вторник, 19.04.2016, 04:24
 
Ответить
СообщениеGustav, подскажите пожалуйста
на строке
[vba]
Код
Call addAddress(mail.Sender, mail.Sender.Address) 'запоминаем отправителя
[/vba]

выдает ошибку 438

как исправить
:'(

Автор - Pisozo
Дата добавления - 19.04.2016 в 04:20
Gustav Дата: Среда, 20.04.2016, 19:34 | Сообщение № 5
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2697
Репутация: 1123 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
выдает ошибку 438

как исправить

Трудно сказать, не имея возможности запустить отладку... Попробуйте сами в отладчике посмотреть элементы этой строки. Вы именно в моём виде код используете или что-то от себя добавили? Версия Outlook какая? Попробуйте погуглить по "словам" из ошибочной строки: mailitem sender address 438


МОИ: Ник, Tip box: 41001663842605
 
Ответить
Сообщение
выдает ошибку 438

как исправить

Трудно сказать, не имея возможности запустить отладку... Попробуйте сами в отладчике посмотреть элементы этой строки. Вы именно в моём виде код используете или что-то от себя добавили? Версия Outlook какая? Попробуйте погуглить по "словам" из ошибочной строки: mailitem sender address 438

Автор - Gustav
Дата добавления - 20.04.2016 в 19:34
Gustav Дата: Среда, 20.04.2016, 22:19 | Сообщение № 6
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2697
Репутация: 1123 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
Вопрос: Что надо изменить для поиска адресов только во вложенной папке с уникальным именем?


Извиняюсь, своевременно не увидел этого вопроса. Наверстываю.

Допустим, мы регулярно отправляем письма-поздравления с ДР своим деловым партнерам. И после отправки "для порядка" сохраняем эти письма в подпапке "Дни рождения" стандартной папки "Исходящие". Внутри папки "Дни рождения" дополнительно организуем подпапки по месяцам: "01 Январь", "02 Февраль" и т.д.

Так вот, чтобы организовать обработку единственной вложенной папки, например, по маршруту "Исходящие\Дни рождения\08 Август", можно внести следующие несложные изменения в середину процедуры main():
[vba]
Код
    'обрабатываем папку Входящие и вложенные в нее
    'КОММЕНТИРУЕМ ПАПКУ ВХОДЯЩИЕ - сейчас она нам не нужна
    'Set fldr = olApp.Session.GetDefaultFolder(6)  '6 = olFolderInbox
    'Call processFolder(fldr)
    
    'обрабатываем папку Исходящие и вложенные в нее
    Set fldr = olApp.Session.GetDefaultFolder(5) '5 = olFolderSentMail
    'ДОБАВЛЯЕМ УТОЧНЕНИЕ ПАПКИ - расписываем маршрут через вложенные Folders
    Set fldr = fldr.Folders("Дни рождения").Folders("08 Август")
    Call processFolder(fldr)
[/vba]


МОИ: Ник, Tip box: 41001663842605
 
Ответить
Сообщение
Вопрос: Что надо изменить для поиска адресов только во вложенной папке с уникальным именем?


Извиняюсь, своевременно не увидел этого вопроса. Наверстываю.

Допустим, мы регулярно отправляем письма-поздравления с ДР своим деловым партнерам. И после отправки "для порядка" сохраняем эти письма в подпапке "Дни рождения" стандартной папки "Исходящие". Внутри папки "Дни рождения" дополнительно организуем подпапки по месяцам: "01 Январь", "02 Февраль" и т.д.

Так вот, чтобы организовать обработку единственной вложенной папки, например, по маршруту "Исходящие\Дни рождения\08 Август", можно внести следующие несложные изменения в середину процедуры main():
[vba]
Код
    'обрабатываем папку Входящие и вложенные в нее
    'КОММЕНТИРУЕМ ПАПКУ ВХОДЯЩИЕ - сейчас она нам не нужна
    'Set fldr = olApp.Session.GetDefaultFolder(6)  '6 = olFolderInbox
    'Call processFolder(fldr)
    
    'обрабатываем папку Исходящие и вложенные в нее
    Set fldr = olApp.Session.GetDefaultFolder(5) '5 = olFolderSentMail
    'ДОБАВЛЯЕМ УТОЧНЕНИЕ ПАПКИ - расписываем маршрут через вложенные Folders
    Set fldr = fldr.Folders("Дни рождения").Folders("08 Август")
    Call processFolder(fldr)
[/vba]

Автор - Gustav
Дата добавления - 20.04.2016 в 22:19
Alex_Gur Дата: Понедельник, 29.01.2018, 20:33 | Сообщение № 7
Группа: Пользователи
Ранг: Прохожий
Сообщений: 2
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Уважаемые коллеги!

Мне нужно выгрузить адреса получателей из папки Отправленные Outlook в файл Excel.
Написал следующий макрос:

[vba]
Код
Sub main2() 'запускаем эту процедуру из Excel

    Dim olApp   As Object 'Outlook.Application
    Dim fldr    As Object 'Outlook.Folder
    
    Set olApp = CreateObject("Outlook.Application")
    
    'обрабатываем папку Отправленные
    PrintInCell ("Адресаты из папки Отправленные")
    Set fldr = olApp.Session.GetDefaultFolder(5)  '5 = olFolderSentMail

    For Each Item1 In fldr.Items
        'Выписываем адресатов
        If Item1.Class = 43 Then  'сообщения -  Class = 43
            str1 = Item1.To
            PrintInCell (str1)
            str1 = Item1.CC
            PrintInCell (str1)
            str1 = Item1.BCC
            PrintInCell (str1)
        End If
    Next

End Sub

Sub PrintInCell(val1 As String)
     'Пользовательская функция записи
    ActiveCell.Value = val1
    ActiveCell.Offset(1, 0).Range("A1").Select
End Sub
[/vba]

Все работает хорошо, но вместо электронного адреса часто выдаются ФИО получателя.
У атрибутов To, CC и BCC дочерних атрибутов нет.
Подскажите, пожалуйста, как выгрузить именно электронный адрес?
Ведь в системе электронный адрес имеется (см. скриншот в приложении). И выгрузка Файл - Импорт и экспорт также показывает и ФИО, и электронный адрес.
Как можно получить этот электронный адрес, зная ФИО?
К сообщению приложен файл: 2390172.png (16.4 Kb)
 
Ответить
СообщениеУважаемые коллеги!

Мне нужно выгрузить адреса получателей из папки Отправленные Outlook в файл Excel.
Написал следующий макрос:

[vba]
Код
Sub main2() 'запускаем эту процедуру из Excel

    Dim olApp   As Object 'Outlook.Application
    Dim fldr    As Object 'Outlook.Folder
    
    Set olApp = CreateObject("Outlook.Application")
    
    'обрабатываем папку Отправленные
    PrintInCell ("Адресаты из папки Отправленные")
    Set fldr = olApp.Session.GetDefaultFolder(5)  '5 = olFolderSentMail

    For Each Item1 In fldr.Items
        'Выписываем адресатов
        If Item1.Class = 43 Then  'сообщения -  Class = 43
            str1 = Item1.To
            PrintInCell (str1)
            str1 = Item1.CC
            PrintInCell (str1)
            str1 = Item1.BCC
            PrintInCell (str1)
        End If
    Next

End Sub

Sub PrintInCell(val1 As String)
     'Пользовательская функция записи
    ActiveCell.Value = val1
    ActiveCell.Offset(1, 0).Range("A1").Select
End Sub
[/vba]

Все работает хорошо, но вместо электронного адреса часто выдаются ФИО получателя.
У атрибутов To, CC и BCC дочерних атрибутов нет.
Подскажите, пожалуйста, как выгрузить именно электронный адрес?
Ведь в системе электронный адрес имеется (см. скриншот в приложении). И выгрузка Файл - Импорт и экспорт также показывает и ФИО, и электронный адрес.
Как можно получить этот электронный адрес, зная ФИО?

Автор - Alex_Gur
Дата добавления - 29.01.2018 в 20:33
sboy Дата: Вторник, 30.01.2018, 11:09 | Сообщение № 8
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2566
Репутация: 724 ±
Замечаний: 0% ±

Excel 2010
Добрый день.
Попробуйте эту часть кода заменить
[vba]
Код

    For Each Item1 In fldr.Items
        'Выписываем адресатов
        If Item1.Class = 43 Then  'сообщения -  Class = 43
            For Each rec In Item1.Recepients
                Str1 = rec.Address
                PrintInCell (Str1)
            Next          
            'str1 = Item1.To
            'PrintInCell (str1)
           ' str1 = Item1.CC
            'PrintInCell (str1)
            'str1 = Item1.BCC
            'PrintInCell (str1)
        End If
    Next
[/vba]


Яндекс: 410016850021169
 
Ответить
СообщениеДобрый день.
Попробуйте эту часть кода заменить
[vba]
Код

    For Each Item1 In fldr.Items
        'Выписываем адресатов
        If Item1.Class = 43 Then  'сообщения -  Class = 43
            For Each rec In Item1.Recepients
                Str1 = rec.Address
                PrintInCell (Str1)
            Next          
            'str1 = Item1.To
            'PrintInCell (str1)
           ' str1 = Item1.CC
            'PrintInCell (str1)
            'str1 = Item1.BCC
            'PrintInCell (str1)
        End If
    Next
[/vba]

Автор - sboy
Дата добавления - 30.01.2018 в 11:09
Alex_Gur Дата: Вторник, 30.01.2018, 11:17 | Сообщение № 9
Группа: Пользователи
Ранг: Прохожий
Сообщений: 2
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
Добрый день.
Попробуйте эту часть кода заменить


Большое спасибо! Отличное решение! Все работает
 
Ответить
Сообщение
Добрый день.
Попробуйте эту часть кода заменить


Большое спасибо! Отличное решение! Все работает

Автор - Alex_Gur
Дата добавления - 30.01.2018 в 11:17
kiko Дата: Пятница, 21.06.2019, 16:21 | Сообщение № 10
Группа: Пользователи
Ранг: Прохожий
Сообщений: 3
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
sboy, Добрый день! Не поможете докрутить макрос, который будет выгружать не только адреса получателей из папки Отправленные Outlook в файл Excel, но и дату отправки и тему письма?
Опубликованный ранее пользователем Alex_Gur макрос по выгрузке адресов получателей из папки Отправленные Outlook в файл Excel:

Sub main2() 'запускаем эту процедуру из Excel

Dim olApp As Object 'Outlook.Application
Dim fldr As Object 'Outlook.Folder

Set olApp = CreateObject("Outlook.Application")

'обрабатываем папку Отправленные
PrintInCell ("Адресаты из папки Отправленные")
Set fldr = olApp.Session.GetDefaultFolder(5) '5 = olFolderSentMail

For Each Item1 In fldr.Items
'Выписываем адресатов
If Item1.Class = 43 Then 'сообщения - Class = 43
str1 = Item1.To
PrintInCell (str1)
str1 = Item1.CC
PrintInCell (str1)
str1 = Item1.BCC
PrintInCell (str1)
End If
Next

End Sub

Sub PrintInCell(val1 As String)
'Пользовательская функция записи
ActiveCell.Value = val1
ActiveCell.Offset(1, 0).Range("A1").Select
End Sub
 
Ответить
Сообщениеsboy, Добрый день! Не поможете докрутить макрос, который будет выгружать не только адреса получателей из папки Отправленные Outlook в файл Excel, но и дату отправки и тему письма?
Опубликованный ранее пользователем Alex_Gur макрос по выгрузке адресов получателей из папки Отправленные Outlook в файл Excel:

Sub main2() 'запускаем эту процедуру из Excel

Dim olApp As Object 'Outlook.Application
Dim fldr As Object 'Outlook.Folder

Set olApp = CreateObject("Outlook.Application")

'обрабатываем папку Отправленные
PrintInCell ("Адресаты из папки Отправленные")
Set fldr = olApp.Session.GetDefaultFolder(5) '5 = olFolderSentMail

For Each Item1 In fldr.Items
'Выписываем адресатов
If Item1.Class = 43 Then 'сообщения - Class = 43
str1 = Item1.To
PrintInCell (str1)
str1 = Item1.CC
PrintInCell (str1)
str1 = Item1.BCC
PrintInCell (str1)
End If
Next

End Sub

Sub PrintInCell(val1 As String)
'Пользовательская функция записи
ActiveCell.Value = val1
ActiveCell.Offset(1, 0).Range("A1").Select
End Sub

Автор - kiko
Дата добавления - 21.06.2019 в 16:21
sboy Дата: Пятница, 21.06.2019, 16:30 | Сообщение № 11
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2566
Репутация: 724 ±
Замечаний: 0% ±

Excel 2010
Добрый день.
В личку спамить не обязательно :)
Сейчас времени нет, исправьте пока свое сообщение, согласно правилам форума (тэги для VBA кода)


Яндекс: 410016850021169
 
Ответить
СообщениеДобрый день.
В личку спамить не обязательно :)
Сейчас времени нет, исправьте пока свое сообщение, согласно правилам форума (тэги для VBA кода)

Автор - sboy
Дата добавления - 21.06.2019 в 16:30
kiko Дата: Пятница, 21.06.2019, 16:41 | Сообщение № 12
Группа: Пользователи
Ранг: Прохожий
Сообщений: 3
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
sboy, Прошу прощения :(
[vba]
Код
Sub main2() 'запускаем эту процедуру из Excel

Dim olApp As Object 'Outlook.Application
Dim fldr As Object 'Outlook.Folder

Set olApp = CreateObject("Outlook.Application")

'обрабатываем папку Отправленные
PrintInCell ("Адресаты из папки Отправленные")
Set fldr = olApp.Session.GetDefaultFolder(5) '5 = olFolderSentMail

For Each Item1 In fldr.Items
'Выписываем адресатов
If Item1.Class = 43 Then 'сообщения - Class = 43
str1 = Item1.To
PrintInCell (str1)
str1 = Item1.CC
PrintInCell (str1)
str1 = Item1.BCC
PrintInCell (str1)
End If
Next

End Sub

Sub PrintInCell(val1 As String)
'Пользовательская функция записи
ActiveCell.Value = val1
ActiveCell.Offset(1, 0).Range("A1").Select
End Sub
[/vba]
 
Ответить
Сообщениеsboy, Прошу прощения :(
[vba]
Код
Sub main2() 'запускаем эту процедуру из Excel

Dim olApp As Object 'Outlook.Application
Dim fldr As Object 'Outlook.Folder

Set olApp = CreateObject("Outlook.Application")

'обрабатываем папку Отправленные
PrintInCell ("Адресаты из папки Отправленные")
Set fldr = olApp.Session.GetDefaultFolder(5) '5 = olFolderSentMail

For Each Item1 In fldr.Items
'Выписываем адресатов
If Item1.Class = 43 Then 'сообщения - Class = 43
str1 = Item1.To
PrintInCell (str1)
str1 = Item1.CC
PrintInCell (str1)
str1 = Item1.BCC
PrintInCell (str1)
End If
Next

End Sub

Sub PrintInCell(val1 As String)
'Пользовательская функция записи
ActiveCell.Value = val1
ActiveCell.Offset(1, 0).Range("A1").Select
End Sub
[/vba]

Автор - kiko
Дата добавления - 21.06.2019 в 16:41
kiko Дата: Понедельник, 24.06.2019, 09:54 | Сообщение № 13
Группа: Пользователи
Ранг: Прохожий
Сообщений: 3
Репутация: 0 ±
Замечаний: 0% ±

Excel 2016
sboy, Добрый день. Отбой тревоги, макрос допилил :)
 
Ответить
Сообщениеsboy, Добрый день. Отбой тревоги, макрос допилил :)

Автор - kiko
Дата добавления - 24.06.2019 в 09:54
Мир MS Excel » Вопросы и решения » Excel и другие приложения » Outlook » Макрос Outlook по сбору адресатов (Иное/Other)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!