Сложные формулы функции ЕСЛИ

Дата: Вторник, 29.05.2012, 19:13 | Сообщение № 1

Группа: Пользователи

Ранг: Прохожий

Сообщений: 7

Репутация: 0 ±

Замечаний: 0% ±

Добрый день. Прошу помочь со сложными формулами функции ЕСЛИ. Описание проблемы во вложении.

К сообщению приложен файл: 8646033.xls (22.5 Kb)

Дата: Вторник, 29.05.2012, 19:27 | Сообщение № 2

Группа: Друзья

Ранг: Старожил

Сообщений: 2012

Репутация: 373 ±

Замечаний: 0% ±

Excel2016

Quote

Если среди чисел ABCDEFG есть пять чисел равных 0

-А если больше 5 чисел равно нулю?
-а если есть меньше нуля?

Code

=ВЫБОР(СЧЁТЕСЛИ(A4:G4;0)+1;(A4/2+B4+C4+D4+E4+F4+G4/2)/6; (A4/2+B4+C4+D4+E4+F4+G4/2)/5; (A4/2+B4+C4+D4+E4+F4+G4/2)/4; (A4/2+B4+C4+D4+E4+F4+G4/2)/2;(A4/2+B4+C4+D4+E4+F4+G4/2)/1)

Дата: Вторник, 29.05.2012, 19:34 | Сообщение № 3

Группа: Пользователи

Ранг: Прохожий

Сообщений: 7

Репутация: 0 ±

Замечаний: 0% ±

более пяти значений равных нулю не рассматриваются.
значения только равные нулю и более...
Спасибо БОЛЬШОЕ за решение.....

Pelena

Дата: Вторник, 29.05.2012, 19:36 | Сообщение № 4

Группа: Админы

Ранг: Местный житель

Сообщений: 19184

Репутация: 4420 ±

Замечаний: ±

Excel 365 & Mac Excel

Вариант:

Code

=(A4/2+B4+C4+D4+E4+F4+G4/2)/ВЫБОР(СЧЁТЕСЛИ(A4:G4;0)+1;6;5;4;3;2;1)

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816

Дата: Вторник, 29.05.2012, 20:21 | Сообщение № 5

Группа: Друзья

Ранг: Старожил

Сообщений: 2012

Репутация: 373 ±

Замечаний: 0% ±

Excel2016

Quote (Pelena)

Вариант: Формула:

Code

=(A4/2+B4+C4+D4+E4+F4+G4/2)/ВЫБОР(СЧЁТЕСЛИ(A4:G4;0)+1;6;5;4;3;2;1)

тогда уж

Quote

(A4/2+B4+C4+D4+E4+F4+G4/2)/(6-СЧЁТЕСЛИ(A4:G4;0))

зы. я просто копировал формулы, не анализируя их...

Дата: Среда, 30.05.2012, 07:45 | Сообщение № 6

Группа: Пользователи

Ранг: Прохожий

Сообщений: 7

Репутация: 0 ±

Замечаний: 0% ±

Подскажите, пожалуйста, такой момент: можно ли прописать в данной формуле условие, что если A4 будет равным 0, то формула изменилась на (B4/2+C4+D4+E4+F4+G4/2)/(6-СЧЁТЕСЛИ(A4:G4;0)) и если А4 и В4 ,будут равным 0, то формула изменилась на (C4/2+D4+E4+F4+G4/2)/(6-СЧЁТЕСЛИ(A4:G4;0)), если А4, В4, С4 будут равны 0, то формула (D4/2+E4+F4+G4/2)/(6-СЧЁТЕСЛИ(A4:G4;0)), если А4, В4, С4, D4 будут равны 0, то формула (E4/2+F4+G4/2)/(6-СЧЁТЕСЛИ(A4:G4;0)), если А4, В4, С4, D4, Е4 будут равны 0, то формула (F4/2+G4/2)/(6-СЧЁТЕСЛИ(A4:G4;0))

если G4 будет равным 0, то формула изменилась на (A4/2+B4+C4+D4+E4+F4/2)/(6-СЧЁТЕСЛИ(A4:G4;0))

Дата: Среда, 30.05.2012, 08:57 | Сообщение № 7

Группа: Друзья

Ранг: Старожил

Сообщений: 2012

Репутация: 373 ±

Замечаний: 0% ±

Excel2016

Code

=СУММ(A4:G4;-ИНДЕКС(A4:G4;МИН(ЕСЛИ(A4:G4;СТОЛБЕЦ(A4:G4))))/2;-ЕСЛИ(G4;G4/2;F4/2))/(6-СЧЁТЕСЛИ(A4:G4;0))

Формула массива. вводится одновременным нажатием Ctrl+Shift+Enter

или не массивная

Code

=СУММ(A4:G4;-ЕСЛИ(A4;A4;ЕСЛИ(B4;B4;ЕСЛИ(C4;C4;ЕСЛИ(E4;E4))))/2;-ЕСЛИ(G4;G4;F4)/2)/(6-СЧЁТЕСЛИ(A4:G4;0))

Сообщение отредактировал Michael_S - Среда, 30.05.2012, 09:09

Дата: Среда, 30.05.2012, 09:27 | Сообщение № 8

Группа: Пользователи

Ранг: Прохожий

Сообщений: 7

Репутация: 0 ±

Замечаний: 0% ±

Спасибо, сейчас попробую подставить.

Pelena

Дата: Среда, 30.05.2012, 09:34 | Сообщение № 9

Группа: Админы

Ранг: Местный житель

Сообщений: 19184

Репутация: 4420 ±

Замечаний: ±

Excel 365 & Mac Excel

Michael_S, можете мне объяснить вот это чудо: ЕСЛИ(G4;G4;F4)
Во всех книжках написано, что первый аргумент ЕСЛИ - это логическое выражение

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816

Serge_007

Дата: Среда, 30.05.2012, 09:39 | Сообщение № 10

Группа: Админы

Ранг: Местный житель

Сообщений: 16475

Репутация: 2749 ±

Замечаний: ±

Excel 2016

Quote (Pelena)

Во всех книжках написано, что первый аргумент ЕСЛИ - это логическое выражение

Так и есть smile

Напишите в А1 единицу, а потом ноль и посмотрите что возвращает формула
[vba]

Code

=ЕСЛИ(A1;"ок";"не ок")

[/vba]

ЮMoney:41001419691823 | WMR:126292472390

Дата: Среда, 30.05.2012, 09:44 | Сообщение № 11

Группа: Друзья

Ранг: Старожил

Сообщений: 2012

Репутация: 373 ±

Замечаний: 0% ±

Excel2016

Все, что равно нулю - логическая ЛОЖЬ, все остальное - ИСТИНА.
Верно только для чисел и пустых ячеек.
Неверно, если в ячейке ="" (в этом случае ячейка не пустая)

Pelena

Дата: Среда, 30.05.2012, 09:46 | Сообщение № 12

Группа: Админы

Ранг: Местный житель

Сообщений: 19184

Репутация: 4420 ±

Замечаний: ±

Excel 365 & Mac Excel

Вот как об этом можно догадаться?! blink

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816

Дата: Среда, 30.05.2012, 09:49 | Сообщение № 13

Группа: Пользователи

Ранг: Прохожий

Сообщений: 7

Репутация: 0 ±

Замечаний: 0% ±

В формуле отсутствует условие при D4=0. Или так и должно быть?

Дата: Среда, 30.05.2012, 10:01 | Сообщение № 14

Группа: Друзья

Ранг: Старожил

Сообщений: 2012

Репутация: 373 ±

Замечаний: 0% ±

Excel2016

Quote (profit)

В формуле отсутствует условие при D4=0. Или так и должно быть?

пропустил

Code

=СУММ(A4:G4;-ЕСЛИ(A4;A4;ЕСЛИ(B4;B4;ЕСЛИ(C4;C4;ЕСЛИ(d4;d4;ЕСЛИ(E4;E4)))))/2;-ЕСЛИ(G4;G4;F4)/2)/(6-СЧЁТЕСЛИ(A4:G4;0))

только надо проверить, будет ли работать в 2003... не слишком ли много ЕСЛИ

Сообщение отредактировал Michael_S - Среда, 30.05.2012, 10:04

Дата: Среда, 30.05.2012, 10:10 | Сообщение № 15

Группа: Пользователи

Ранг: Прохожий

Сообщений: 7

Репутация: 0 ±

Замечаний: 0% ±

EXEL пишет, что слишком много аргументов

Serge_007

Дата: Среда, 30.05.2012, 10:39 | Сообщение № 16

Группа: Админы

Ранг: Местный житель

Сообщений: 16475

Репутация: 2749 ±

Замечаний: ±

Excel 2016

Особо в задачу не вникал, но попробуйте так пойдёт?
[vba]

Code

=(A4/2+СУММ(B4:F4)+G4/2)/(СЧЁТЕСЛИ(A4:G4;">0")-1)

[/vba]

ЮMoney:41001419691823 | WMR:126292472390

Дата: Среда, 30.05.2012, 11:00 | Сообщение № 17

Группа: Друзья

Ранг: Старожил

Сообщений: 2012

Репутация: 373 ±

Замечаний: 0% ±

Excel2016

Quote (profit)

EXEL пишет, что слишком много аргументов

Это на исправленной? а то я сразу ошибся, - не там скобки поставил.

Счас попробовал в режиме совместимости - вроде пропускает...

Дата: Среда, 30.05.2012, 11:16 | Сообщение № 18

Группа: Пользователи

Ранг: Прохожий

Сообщений: 7

Репутация: 0 ±

Замечаний: 0% ±

Quote (Michael_S)

Да, наконец-то все заработало. БОЛЬШОЕ СПАСИБО. Даже не знаю как вас отблагодарить.

tiestok

Дата: Вторник, 23.10.2012, 17:49 | Сообщение № 19

Группа: Пользователи

Ранг: Прохожий

Сообщений: 1

Репутация: 0 ±

Замечаний: 0% ±

Всем привет! Ни очень разбираюсь в Ексель. Решил создать накладную на работе, с формулами ЕСЛИ. Что делать если пишет слишком много аргументов? Как можно будет решить данную задачу? Может есть какие либо другие формулы.

К сообщению приложен файл: 5337422.xlsx (12.7 Kb)

Serge_007

Дата: Вторник, 23.10.2012, 17:50 | Сообщение № 20

Группа: Админы

Ранг: Местный житель

Сообщений: 16475

Репутация: 2749 ±

Замечаний: ±

Excel 2016

Quote (tiestok)

Что делать?

Читать справку по функции и не постить в чужих темах

ЮMoney:41001419691823 | WMR:126292472390