Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/впр по 3 более критериям - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_, DrMini  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » впр по 3 более критериям (Формулы/Formulas)
впр по 3 более критериям
miha_ Дата: Среда, 15.03.2017, 21:35 | Сообщение № 1
Группа: Пользователи
Ранг: Участник
Сообщений: 87
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
Друзья, всем добрый вечер.
Просьба подсказать, решение следующей задачи: впр по 3 и более критериям. Известные мне способы не подходят. Такие как формула массива индекс,поискпоз; впр с дополнительным столбцом критериев, суммеслимн...Таблица у меня объемная свыше 100к ячеек с формулами.Спасибо за совет и помощь.Хорошего вечера.
 
Ответить
СообщениеДрузья, всем добрый вечер.
Просьба подсказать, решение следующей задачи: впр по 3 и более критериям. Известные мне способы не подходят. Такие как формула массива индекс,поискпоз; впр с дополнительным столбцом критериев, суммеслимн...Таблица у меня объемная свыше 100к ячеек с формулами.Спасибо за совет и помощь.Хорошего вечера.
Автор - miha_
Дата добавления - 15.03.2017 в 21:35
_Boroda_ Дата: Среда, 15.03.2017, 21:49 | Сообщение № 2
Группа: Админы
Ранг: Местный житель
Сообщений: 16885
Репутация: 6599 ±
Замечаний: ±

2003; 2007; 2010; 2013 RUS
Добрый!
Без кусочка Вашего файла можно сказать только то, что все варианты, которые ВЫ написали, должны подходить.

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеДобрый!
Без кусочка Вашего файла можно сказать только то, что все варианты, которые ВЫ написали, должны подходить.
Автор - _Boroda_
Дата добавления - 15.03.2017 в 21:49
miha_ Дата: Среда, 15.03.2017, 22:06 | Сообщение № 3
Группа: Пользователи
Ранг: Участник
Сообщений: 87
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
Добавил, пример.Спасибо.
К сообщению приложен файл: 6091436.xlsx (10.7 Kb)
 
Ответить
СообщениеДобавил, пример.Спасибо.
Автор - miha_
Дата добавления - 15.03.2017 в 22:06
gling Дата: Среда, 15.03.2017, 22:22 | Сообщение № 4
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2640
Репутация: 737 ±
Замечаний: 0% ±

2010
Здравствуйте. ВПР с Доп Столбцом в файле.
Код
=ВПР(J2&K2&L2;A:E;5;)
К сообщению приложен файл: 6348092.xlsx (12.0 Kb)

ЯД-41001506838083
 
Ответить
СообщениеЗдравствуйте. ВПР с Доп Столбцом в файле.
Код
=ВПР(J2&K2&L2;A:E;5;)
Автор - gling
Дата добавления - 15.03.2017 в 22:22
Perfect2You Дата: Среда, 15.03.2017, 22:25 | Сообщение № 5
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 237
Репутация: 59 ±
Замечаний: 0% ±

Excel 2010
Если Вы расстраиваетесь из-за первого условия, то дело в том, что в условии у Вас не "город", а "город " с пробелом на конце. EXCEL считает это разными словами.
Либо внимательнее надо следить за условиями и данными (лучше их не вводить вручную, а копировать), либо вставлять дополнительные манипуляции в формулы, например:
Код
=СУММПРОИЗВ((СЖПРОБЕЛЫ($I3)=СЖПРОБЕЛЫ($A:$A))*(СЖПРОБЕЛЫ($J3)=СЖПРОБЕЛЫ($B:$B))*(СЖПРОБЕЛЫ($K3)=СЖПРОБЕЛЫ($C:$C))*$D:$D)

У меня посчитала корректно.
 
Ответить
СообщениеЕсли Вы расстраиваетесь из-за первого условия, то дело в том, что в условии у Вас не "город", а "город " с пробелом на конце. EXCEL считает это разными словами.
Либо внимательнее надо следить за условиями и данными (лучше их не вводить вручную, а копировать), либо вставлять дополнительные манипуляции в формулы, например:
Код
=СУММПРОИЗВ((СЖПРОБЕЛЫ($I3)=СЖПРОБЕЛЫ($A:$A))*(СЖПРОБЕЛЫ($J3)=СЖПРОБЕЛЫ($B:$B))*(СЖПРОБЕЛЫ($K3)=СЖПРОБЕЛЫ($C:$C))*$D:$D)

У меня посчитала корректно.
Автор - Perfect2You
Дата добавления - 15.03.2017 в 22:25
miha_ Дата: Среда, 15.03.2017, 22:29 | Сообщение № 6
Группа: Пользователи
Ранг: Участник
Сообщений: 87
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
gling, Добрый вечер,Владимир.Спасибо.К сожалению,данный способ не подойдет.Исходная таблица должна остаться без изменений. Этот способ,и другие с формулой массива индекс поискпоз,суммеслимн не подходят для решения данного вопроса.
 
Ответить
Сообщениеgling, Добрый вечер,Владимир.Спасибо.К сожалению,данный способ не подойдет.Исходная таблица должна остаться без изменений. Этот способ,и другие с формулой массива индекс поискпоз,суммеслимн не подходят для решения данного вопроса.
Автор - miha_
Дата добавления - 15.03.2017 в 22:29
ZORRO2005 Дата: Среда, 15.03.2017, 22:31 | Сообщение № 7
Группа: Друзья
Ранг: Обитатель
Сообщений: 382
Репутация: 148 ±
Замечаний: 0% ±

Excel2010
если нужно первое значение сверху:
Код
=ИНДЕКС(D$1:D$33;МИН(ЕСЛИ((A$2:A$33=I2)*(B$2:B$33=J2)*(C$2:C$33=K2);СТРОКА(A$2:A$33))))

если нужна сумма:
Код
=СУММЕСЛИМН(D$2:D$33;A$2:A$33;I2;B$2:B$33;J2;C$2:C$33;K2)

если не нравится функция ИНДЕКС
Код
ДВССЫЛ(АДРЕС(МИН(ЕСЛИ((A$2:A$33=I2)*(B$2:B$33=J2)*(C$2:C$33=K2);СТРОКА(A$2:A$33)));4))

Код
=СМЕЩ(D$1;МИН(ЕСЛИ((A$2:A$33=I2)*(B$2:B$33=J2)*(C$2:C$33=K2);СТРОКА(A$2:A$33)))-1;)


Сообщение отредактировал ZORRO2005 - Среда, 15.03.2017, 22:55
 
Ответить
Сообщениеесли нужно первое значение сверху:
Код
=ИНДЕКС(D$1:D$33;МИН(ЕСЛИ((A$2:A$33=I2)*(B$2:B$33=J2)*(C$2:C$33=K2);СТРОКА(A$2:A$33))))

если нужна сумма:
Код
=СУММЕСЛИМН(D$2:D$33;A$2:A$33;I2;B$2:B$33;J2;C$2:C$33;K2)

если не нравится функция ИНДЕКС
Код
ДВССЫЛ(АДРЕС(МИН(ЕСЛИ((A$2:A$33=I2)*(B$2:B$33=J2)*(C$2:C$33=K2);СТРОКА(A$2:A$33)));4))

Код
=СМЕЩ(D$1;МИН(ЕСЛИ((A$2:A$33=I2)*(B$2:B$33=J2)*(C$2:C$33=K2);СТРОКА(A$2:A$33)))-1;)
Автор - ZORRO2005
Дата добавления - 15.03.2017 в 22:31
gling Дата: Среда, 15.03.2017, 22:41 | Сообщение № 8
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2640
Репутация: 737 ±
Замечаний: 0% ±

2010
Цитата miha_, 15.03.2017 в 22:29, в сообщении № 6 ()
данный способ не подойдет

А вариант с именованным диапазоном подходит?
Код
=ИНДЕКС($E$2:$E$33;ПОИСКПОЗ(J2&K2&L2;База;))
или формула массива
Код
=ИНДЕКС($E$2:$E$33;ПОИСКПОЗ(J2&K2&L2;$B$2:$B$33&$C$2:$C$33&$D$2:$D$33;))
К сообщению приложен файл: 6903321.xlsx (12.1 Kb)

ЯД-41001506838083

Сообщение отредактировал gling - Среда, 15.03.2017, 22:47
 
Ответить
Сообщение
Цитата miha_, 15.03.2017 в 22:29, в сообщении № 6 ()
данный способ не подойдет

А вариант с именованным диапазоном подходит?
Код
=ИНДЕКС($E$2:$E$33;ПОИСКПОЗ(J2&K2&L2;База;))
или формула массива
Код
=ИНДЕКС($E$2:$E$33;ПОИСКПОЗ(J2&K2&L2;$B$2:$B$33&$C$2:$C$33&$D$2:$D$33;))
Автор - gling
Дата добавления - 15.03.2017 в 22:41
miha_ Дата: Среда, 15.03.2017, 22:50 | Сообщение № 9
Группа: Пользователи
Ранг: Участник
Сообщений: 87
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
Друзья,спасибо!Вы мне помогли!Я разобрался с этим вопросом!Хорошего вечера!
 
Ответить
СообщениеДрузья,спасибо!Вы мне помогли!Я разобрался с этим вопросом!Хорошего вечера!
Автор - miha_
Дата добавления - 15.03.2017 в 22:50
miha_ Дата: Понедельник, 29.05.2017, 17:57 | Сообщение № 10
Группа: Пользователи
Ранг: Участник
Сообщений: 87
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
Код
=ВПР($I$2&$J$2&K2;ВЫБОР({1;2};$A:$A&$B:$B&C:C;$D:$D);2;)
вводиться как формула массива
 
Ответить
Сообщение
Код
=ВПР($I$2&$J$2&K2;ВЫБОР({1;2};$A:$A&$B:$B&C:C;$D:$D);2;)
вводиться как формула массива
Автор - miha_
Дата добавления - 29.05.2017 в 17:57
jakim Дата: Понедельник, 29.05.2017, 19:02 | Сообщение № 11
Группа: Друзья
Ранг: Старожил
Сообщений: 1218
Репутация: 316 ±
Замечаний: 0% ±

Excel 2010
Ещё одна формула

Код
=IFERROR(AGGREGATE(15;6;D$2:D$330/(A$2:A$330=I2)/(B$2:B$330=J2)/(D$2:D$330=L2);1);"")
 
Ответить
Сообщение
Ещё одна формула

Код
=IFERROR(AGGREGATE(15;6;D$2:D$330/(A$2:A$330=I2)/(B$2:B$330=J2)/(D$2:D$330=L2);1);"")
Автор - jakim
Дата добавления - 29.05.2017 в 19:02
Мир MS Excel » Вопросы и решения » Вопросы по Excel » впр по 3 более критериям (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2025 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!