Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Формула СУММЕСЛИМН в диапазоне - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_, DrMini  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Формула СУММЕСЛИМН в диапазоне (Формулы/Formulas)
Формула СУММЕСЛИМН в диапазоне
Liof78 Дата: Среда, 05.04.2017, 11:42 | Сообщение № 1
Группа: Пользователи
Ранг: Новичок
Сообщений: 37
Репутация: 0 ±
Замечаний: 0% ±

Excel 2007
Добрый день!

Суть такая, что хочу применить 2 условия в формуле (При выборе "Орск" в С2 и при выборе "Маты МП 50 мм" в H2 и I2 нужно чтобы ячейки суммировались в диапазоне J:K), не могу понять что не дает посчитать.

Если же выбирать по одному столбцу к примеру только C2, Н2 и сумм в диапазоне J, то формула работает.

Формулу забиваю в С58

Заранее благодарен!
К сообщению приложен файл: 3782059.xlsx (27.6 Kb)
 
Ответить
СообщениеДобрый день!

Суть такая, что хочу применить 2 условия в формуле (При выборе "Орск" в С2 и при выборе "Маты МП 50 мм" в H2 и I2 нужно чтобы ячейки суммировались в диапазоне J:K), не могу понять что не дает посчитать.

Если же выбирать по одному столбцу к примеру только C2, Н2 и сумм в диапазоне J, то формула работает.

Формулу забиваю в С58

Заранее благодарен!
Автор - Liof78
Дата добавления - 05.04.2017 в 11:42
sboy Дата: Среда, 05.04.2017, 11:59 | Сообщение № 2
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2566
Репутация: 724 ±
Замечаний: 0% ±

Excel 2010
Добрый день.
так
Код
=СУММЕСЛИМН($K$2:$K$51;$C$2:$C$51;A58;$I$2:$I$51;B58)+СУММЕСЛИМН($J$2:$J$51;$C$2:$C$51;A58;$H$2:$H$51;B58)

или так
Код
=СУММПРОИЗВ(($C$2:$C$51=A58)*($H$2:$H$51=B58)*$J$2:$J$51+($C$2:$C$51=A58)*($I$2:$I$51=B58)*$K$2:$K$51)
К сообщению приложен файл: 1821920.xlsx (28.6 Kb)

Яндекс: 410016850021169
 
Ответить
СообщениеДобрый день.
так
Код
=СУММЕСЛИМН($K$2:$K$51;$C$2:$C$51;A58;$I$2:$I$51;B58)+СУММЕСЛИМН($J$2:$J$51;$C$2:$C$51;A58;$H$2:$H$51;B58)

или так
Код
=СУММПРОИЗВ(($C$2:$C$51=A58)*($H$2:$H$51=B58)*$J$2:$J$51+($C$2:$C$51=A58)*($I$2:$I$51=B58)*$K$2:$K$51)
Автор - sboy
Дата добавления - 05.04.2017 в 11:59
ZORRO2005 Дата: Среда, 05.04.2017, 12:06 | Сообщение № 3
Группа: Друзья
Ранг: Обитатель
Сообщений: 382
Репутация: 148 ±
Замечаний: 0% ±

Excel2010
или так:
Код
=СУММПРОИЗВ((C$2:C$51="Орск")*(H$2:I$51="Маты МП 50 мм")*J$2:K$51)
 
Ответить
Сообщениеили так:
Код
=СУММПРОИЗВ((C$2:C$51="Орск")*(H$2:I$51="Маты МП 50 мм")*J$2:K$51)
Автор - ZORRO2005
Дата добавления - 05.04.2017 в 12:06
Perfect2You Дата: Среда, 05.04.2017, 12:08 | Сообщение № 4
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 237
Репутация: 59 ±
Замечаний: 0% ±

Excel 2010
Да, СУММЕСЛИМН работает только по одномерному массиву (столбцу, либо строке). Выходов 2. Если удобно работать именно с СУММЕСЛИМН, то спасет такая конструкция:
Код
=СУММ(СУММЕСЛИМН(J:J;H:H;"Маты МП 50 мм";C:C;"Орск");СУММЕСЛИМН(K:K;I:I;"Маты МП 50 мм";C:C;"Орск"))

т.е. по каждому материалу посчитать отдельно.
С "квадратным" же массивом умеет работать СУММПРОИЗВ, хитрости которой позволяют суммировать по условию не хуже СУММЕСЛИМН.
Например, так:
Код
=СУММПРОИЗВ((C2:C52=A58)*(H2:I52=B58)*J2:K52)

или для столбцов целиком, но формула массива (вместо Enter одновременно Ctrl+Shift+Enter):
Код
=СУММПРОИЗВ((C:C=A58)*(H:I=B58)*ЕСЛИ(ЕЧИСЛО(J:K);J:K;0))


И не вводите формулу в C58 и вообще в столбец C, если проверку осуществляете по всему столбцу C - получите циклическую ссылку!!!
 
Ответить
СообщениеДа, СУММЕСЛИМН работает только по одномерному массиву (столбцу, либо строке). Выходов 2. Если удобно работать именно с СУММЕСЛИМН, то спасет такая конструкция:
Код
=СУММ(СУММЕСЛИМН(J:J;H:H;"Маты МП 50 мм";C:C;"Орск");СУММЕСЛИМН(K:K;I:I;"Маты МП 50 мм";C:C;"Орск"))

т.е. по каждому материалу посчитать отдельно.
С "квадратным" же массивом умеет работать СУММПРОИЗВ, хитрости которой позволяют суммировать по условию не хуже СУММЕСЛИМН.
Например, так:
Код
=СУММПРОИЗВ((C2:C52=A58)*(H2:I52=B58)*J2:K52)

или для столбцов целиком, но формула массива (вместо Enter одновременно Ctrl+Shift+Enter):
Код
=СУММПРОИЗВ((C:C=A58)*(H:I=B58)*ЕСЛИ(ЕЧИСЛО(J:K);J:K;0))


И не вводите формулу в C58 и вообще в столбец C, если проверку осуществляете по всему столбцу C - получите циклическую ссылку!!!
Автор - Perfect2You
Дата добавления - 05.04.2017 в 12:08
китин Дата: Среда, 05.04.2017, 12:08 | Сообщение № 5
Группа: Модераторы
Ранг: Экселист
Сообщений: 7034
Репутация: 1079 ±
Замечаний: 0% ±

Excel 2007;2010;2016
СУММЕСЛИМН считает только в диапазоне 1 строки или1 столбца. если хотите использовать СУММЕСЛИМН то так
Код
=СУММЕСЛИМН(K1:K50;C1:C50;"Орск";H1:H50;"Маты МП 50 мм";I1:I50;"Маты МП 50 мм")+СУММЕСЛИМН(J1:J50;C1:C50;"Орск";H1:H50;"Маты МП 50 мм";I1:I50;"Маты МП 50 мм")
но так покороче будет
Код
=СУММПРОИЗВ($J$2:$K$51*($C$2:$C$51="Орск")*(H2:H51="Маты МП 50 мм")*($I$2:$I$51="Маты МП 50 мм"))

[p.s.]и не надо использовать столбцы целиком: тормоза это раз и два: вы считаете столбец С:С в котором находится формула, где столбец С:С используется. а это циклическая ссылка

Не судите очень строго:я пытаюсь научиться
ЯД 41001877306852
 
Ответить
СообщениеСУММЕСЛИМН считает только в диапазоне 1 строки или1 столбца. если хотите использовать СУММЕСЛИМН то так
Код
=СУММЕСЛИМН(K1:K50;C1:C50;"Орск";H1:H50;"Маты МП 50 мм";I1:I50;"Маты МП 50 мм")+СУММЕСЛИМН(J1:J50;C1:C50;"Орск";H1:H50;"Маты МП 50 мм";I1:I50;"Маты МП 50 мм")
но так покороче будет
Код
=СУММПРОИЗВ($J$2:$K$51*($C$2:$C$51="Орск")*(H2:H51="Маты МП 50 мм")*($I$2:$I$51="Маты МП 50 мм"))

[p.s.]и не надо использовать столбцы целиком: тормоза это раз и два: вы считаете столбец С:С в котором находится формула, где столбец С:С используется. а это циклическая ссылка
Автор - китин
Дата добавления - 05.04.2017 в 12:08
Liof78 Дата: Среда, 05.04.2017, 13:14 | Сообщение № 6
Группа: Пользователи
Ранг: Новичок
Сообщений: 37
Репутация: 0 ±
Замечаний: 0% ±

Excel 2007
Всем спасибо за ответы!
 
Ответить
СообщениеВсем спасибо за ответы!
Автор - Liof78
Дата добавления - 05.04.2017 в 13:14
ZORRO2005 Дата: Среда, 05.04.2017, 15:22 | Сообщение № 7
Группа: Друзья
Ранг: Обитатель
Сообщений: 382
Репутация: 148 ±
Замечаний: 0% ±

Excel2010
Не соглашусь, что СУММЕСЛИМН() работает только с одномерными массивами.
Если продублировать Прибытие то формула будет:
Код
=СУММЕСЛИМН(J2:K51;C2:D51;"Орск";H2:I51;"Маты МП 50 мм")

[offtop]К сожалению, нет способа превращения массива в диапазон, подходящий для таких функций как СУММЕСЛИ, СУММЕСЛИМН...
Но это уже другая тема[/offtop]
К сообщению приложен файл: 2017_04_05_2.xlsx (28.3 Kb)
 
Ответить
СообщениеНе соглашусь, что СУММЕСЛИМН() работает только с одномерными массивами.
Если продублировать Прибытие то формула будет:
Код
=СУММЕСЛИМН(J2:K51;C2:D51;"Орск";H2:I51;"Маты МП 50 мм")

[offtop]К сожалению, нет способа превращения массива в диапазон, подходящий для таких функций как СУММЕСЛИ, СУММЕСЛИМН...
Но это уже другая тема[/offtop]
Автор - ZORRO2005
Дата добавления - 05.04.2017 в 15:22
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Формула СУММЕСЛИМН в диапазоне (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2025 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!