Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Подсчёт наибольшего количества значений между двумя заданным - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Подсчёт наибольшего количества значений между двумя заданным (Формулы/Formulas)
Подсчёт наибольшего количества значений между двумя заданным
olenka1990 Дата: Четверг, 27.04.2017, 14:48 | Сообщение № 1
Группа: Пользователи
Ранг: Новичок
Сообщений: 20
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
Здравствуйте уважаемые форумчане. Подскажите, возможно ли при помощи excel решить такую задачу. Для примера набросала один столбец значений, необходимо подсчитать наибольшее количество меньших значений, которое встречается в столбце А между двумя,заданным в условии В1. Остальное в примере. Спасибо.
К сообщению приложен файл: 2755828.xls (32.5 Kb)
 
Ответить
СообщениеЗдравствуйте уважаемые форумчане. Подскажите, возможно ли при помощи excel решить такую задачу. Для примера набросала один столбец значений, необходимо подсчитать наибольшее количество меньших значений, которое встречается в столбце А между двумя,заданным в условии В1. Остальное в примере. Спасибо.

Автор - olenka1990
Дата добавления - 27.04.2017 в 14:48
Nic70y Дата: Четверг, 27.04.2017, 15:20 | Сообщение № 2
Группа: Друзья
Ранг: Экселист
Сообщений: 8709
Репутация: 2261 ±
Замечаний: 0% ±

Excel 2010
формула массива
Код
=МАКС(НАИБОЛЬШИЙ(ЕСЛИ(A1:A23>=B1;СТРОКА(A1:A23));СТРОКА(ДВССЫЛ("1:"&СЧЁТЕСЛИ(A1:A23;">="&B1)-1)))-НАИБОЛЬШИЙ(ЕСЛИ(A1:A23>=B1;СТРОКА(A1:A23));СТРОКА(ДВССЫЛ("2:"&СЧЁТЕСЛИ(A1:A23;">="&B1)))))-1
К сообщению приложен файл: 9707420.xls (33.5 Kb)


ЮMoney 41001841029809
 
Ответить
Сообщениеформула массива
Код
=МАКС(НАИБОЛЬШИЙ(ЕСЛИ(A1:A23>=B1;СТРОКА(A1:A23));СТРОКА(ДВССЫЛ("1:"&СЧЁТЕСЛИ(A1:A23;">="&B1)-1)))-НАИБОЛЬШИЙ(ЕСЛИ(A1:A23>=B1;СТРОКА(A1:A23));СТРОКА(ДВССЫЛ("2:"&СЧЁТЕСЛИ(A1:A23;">="&B1)))))-1

Автор - Nic70y
Дата добавления - 27.04.2017 в 15:20
olenka1990 Дата: Четверг, 27.04.2017, 15:28 | Сообщение № 3
Группа: Пользователи
Ранг: Новичок
Сообщений: 20
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
Nic70y, спасибо за быстрый ответ, попробую разобраться, хотя формула выглядит страшновато. :)
 
Ответить
СообщениеNic70y, спасибо за быстрый ответ, попробую разобраться, хотя формула выглядит страшновато. :)

Автор - olenka1990
Дата добавления - 27.04.2017 в 15:28
sboy Дата: Четверг, 27.04.2017, 15:32 | Сообщение № 4
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2566
Репутация: 724 ±
Замечаний: 0% ±

Excel 2010
Добрый день.
Вариант практически такой же как у Nic70y
не требует массивного ввода
Код
=МАКС(АГРЕГАТ(14;6;(A1:A23>=10)*СТРОКА(A1:A23);СТРОКА(ДВССЫЛ("1:"&СЧЁТЕСЛИ(A1:A23;">="&B1))))-АГРЕГАТ(14;6;(A1:A23>=10)*СТРОКА(A1:A23);СТРОКА(ДВССЫЛ("2:"&СЧЁТЕСЛИ(A1:A23;">="&B1)))))-1
К сообщению приложен файл: 4025896.xls (33.5 Kb)


Яндекс: 410016850021169
 
Ответить
СообщениеДобрый день.
Вариант практически такой же как у Nic70y
не требует массивного ввода
Код
=МАКС(АГРЕГАТ(14;6;(A1:A23>=10)*СТРОКА(A1:A23);СТРОКА(ДВССЫЛ("1:"&СЧЁТЕСЛИ(A1:A23;">="&B1))))-АГРЕГАТ(14;6;(A1:A23>=10)*СТРОКА(A1:A23);СТРОКА(ДВССЫЛ("2:"&СЧЁТЕСЛИ(A1:A23;">="&B1)))))-1

Автор - sboy
Дата добавления - 27.04.2017 в 15:32
sboy Дата: Четверг, 27.04.2017, 15:36 | Сообщение № 5
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2566
Репутация: 724 ±
Замечаний: 0% ±

Excel 2010
Nic70y, Вашу формулу чуток сократил, убрал Если
Код
=МАКС(НАИБОЛЬШИЙ((A1:A23>=B1)*СТРОКА(A1:A23);СТРОКА(ДВССЫЛ("1:"&СЧЁТЕСЛИ(A1:A23;">="&B1)-1)))-НАИБОЛЬШИЙ((A1:A23>=B1)*СТРОКА(A1:A23);СТРОКА(ДВССЫЛ("2:"&СЧЁТЕСЛИ(A1:A23;">="&B1)))))-1


Яндекс: 410016850021169
 
Ответить
СообщениеNic70y, Вашу формулу чуток сократил, убрал Если
Код
=МАКС(НАИБОЛЬШИЙ((A1:A23>=B1)*СТРОКА(A1:A23);СТРОКА(ДВССЫЛ("1:"&СЧЁТЕСЛИ(A1:A23;">="&B1)-1)))-НАИБОЛЬШИЙ((A1:A23>=B1)*СТРОКА(A1:A23);СТРОКА(ДВССЫЛ("2:"&СЧЁТЕСЛИ(A1:A23;">="&B1)))))-1

Автор - sboy
Дата добавления - 27.04.2017 в 15:36
olenka1990 Дата: Четверг, 27.04.2017, 15:40 | Сообщение № 6
Группа: Пользователи
Ранг: Новичок
Сообщений: 20
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
sboy, вам тоже спасибо :)
 
Ответить
Сообщениеsboy, вам тоже спасибо :)

Автор - olenka1990
Дата добавления - 27.04.2017 в 15:40
jakim Дата: Четверг, 27.04.2017, 16:45 | Сообщение № 7
Группа: Друзья
Ранг: Старожил
Сообщений: 1197
Репутация: 313 ±
Замечаний: 0% ±

Excel 2010
Может так?

Код
=MAX(COUNTIF(INDEX(A1:A100;AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:5))):INDEX(A1:A100;AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:6)));"<10");COUNTIF(INDEX(A2:A100;AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:6))):INDEX(A2:A100;AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:7)));"<10"))

Код
=MAX(AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:6))-AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:5))-1;AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:7))-AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:6))-1)
К сообщению приложен файл: max.xlsx (10.6 Kb)
 
Ответить
Сообщение
Может так?

Код
=MAX(COUNTIF(INDEX(A1:A100;AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:5))):INDEX(A1:A100;AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:6)));"<10");COUNTIF(INDEX(A2:A100;AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:6))):INDEX(A2:A100;AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:7)));"<10"))

Код
=MAX(AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:6))-AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:5))-1;AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:7))-AGGREGATE(15;6;ROW($1:$100)/(A$1:A$100>=10);ROWS($5:6))-1)

Автор - jakim
Дата добавления - 27.04.2017 в 16:45
sboy Дата: Четверг, 27.04.2017, 17:43 | Сообщение № 8
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2566
Репутация: 724 ±
Замечаний: 0% ±

Excel 2010
Чуть изменил данные, предложенные формулы неправильный ответ выдают, моя так вообще неправильная)))
будем думать дальше, но уже завтра :(
К сообщению приложен файл: 2168225.xlsx (11.0 Kb)


Яндекс: 410016850021169
 
Ответить
СообщениеЧуть изменил данные, предложенные формулы неправильный ответ выдают, моя так вообще неправильная)))
будем думать дальше, но уже завтра :(

Автор - sboy
Дата добавления - 27.04.2017 в 17:43
sboy Дата: Четверг, 27.04.2017, 20:49 | Сообщение № 9
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2566
Репутация: 724 ±
Замечаний: 0% ±

Excel 2010
Не дотерпел до завтра)))
Вот так вроде все правильно считает (формула массива)
Код
=МАКС(ПОИСКПОЗ(1;--(A1:A34>=B1););АГРЕГАТ(14;6;(A1:A34>=10)*СТРОКА(A1:A34);СТРОКА(ДВССЫЛ("1:"&СЧЁТЕСЛИ(A1:A34;">="&B1)-1)))-АГРЕГАТ(14;6;(A1:A34>=10)*СТРОКА(A1:A34);СТРОКА(ДВССЫЛ("2:"&СЧЁТЕСЛИ(A1:A34;">="&B1)))))-1

или
Код
=МАКС(ПОИСКПОЗ(1;--(A1:A34>=B1););НАИБОЛЬШИЙ((A1:A34>=B1)*СТРОКА(A1:A34);СТРОКА(ДВССЫЛ("1:"&СЧЁТЕСЛИ(A1:A34;">="&B1)-1)))-НАИБОЛЬШИЙ((A1:A34>=B1)*СТРОКА(A1:A34);СТРОКА(ДВССЫЛ("2:"&СЧЁТЕСЛИ(A1:A34;">="&B1)))))-1
К сообщению приложен файл: 8531973.xlsx (10.9 Kb)


Яндекс: 410016850021169
 
Ответить
СообщениеНе дотерпел до завтра)))
Вот так вроде все правильно считает (формула массива)
Код
=МАКС(ПОИСКПОЗ(1;--(A1:A34>=B1););АГРЕГАТ(14;6;(A1:A34>=10)*СТРОКА(A1:A34);СТРОКА(ДВССЫЛ("1:"&СЧЁТЕСЛИ(A1:A34;">="&B1)-1)))-АГРЕГАТ(14;6;(A1:A34>=10)*СТРОКА(A1:A34);СТРОКА(ДВССЫЛ("2:"&СЧЁТЕСЛИ(A1:A34;">="&B1)))))-1

или
Код
=МАКС(ПОИСКПОЗ(1;--(A1:A34>=B1););НАИБОЛЬШИЙ((A1:A34>=B1)*СТРОКА(A1:A34);СТРОКА(ДВССЫЛ("1:"&СЧЁТЕСЛИ(A1:A34;">="&B1)-1)))-НАИБОЛЬШИЙ((A1:A34>=B1)*СТРОКА(A1:A34);СТРОКА(ДВССЫЛ("2:"&СЧЁТЕСЛИ(A1:A34;">="&B1)))))-1

Автор - sboy
Дата добавления - 27.04.2017 в 20:49
olenka1990 Дата: Четверг, 27.04.2017, 21:01 | Сообщение № 10
Группа: Пользователи
Ранг: Новичок
Сообщений: 20
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
Спасибо за ваши труды, но первая формула предложенная Nic70y считает правильно, проверила на 1000 данных, остальные нет. При увеличении значений больше 10000 начинает дольше думать, а так вроде всё нормально :)
 
Ответить
СообщениеСпасибо за ваши труды, но первая формула предложенная Nic70y считает правильно, проверила на 1000 данных, остальные нет. При увеличении значений больше 10000 начинает дольше думать, а так вроде всё нормально :)

Автор - olenka1990
Дата добавления - 27.04.2017 в 21:01
olenka1990 Дата: Четверг, 27.04.2017, 21:03 | Сообщение № 11
Группа: Пользователи
Ранг: Новичок
Сообщений: 20
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
sboy, сейчас подставлю и отпишусь :)
 
Ответить
Сообщениеsboy, сейчас подставлю и отпишусь :)

Автор - olenka1990
Дата добавления - 27.04.2017 в 21:03
olenka1990 Дата: Четверг, 27.04.2017, 21:11 | Сообщение № 12
Группа: Пользователи
Ранг: Новичок
Сообщений: 20
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
sboy, у вас тоже получилось, спасибо hands
 
Ответить
Сообщениеsboy, у вас тоже получилось, спасибо hands

Автор - olenka1990
Дата добавления - 27.04.2017 в 21:11
sboy Дата: Четверг, 27.04.2017, 21:43 | Сообщение № 13
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2566
Репутация: 724 ±
Замечаний: 0% ±

Excel 2010
olenka1990, в формуле от Nic70y неверно выдавался правильный результат, если наибольший диапазон самый первый от 1 строки до значения >=10, а у моей (помимо этой ошибки) еще было то, что все-таки вводить ее надо массивно


Яндекс: 410016850021169
 
Ответить
Сообщениеolenka1990, в формуле от Nic70y неверно выдавался правильный результат, если наибольший диапазон самый первый от 1 строки до значения >=10, а у моей (помимо этой ошибки) еще было то, что все-таки вводить ее надо массивно

Автор - sboy
Дата добавления - 27.04.2017 в 21:43
olenka1990 Дата: Четверг, 27.04.2017, 22:27 | Сообщение № 14
Группа: Пользователи
Ранг: Новичок
Сообщений: 20
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
sboy, у меня результат был не первый, поэтому я на это не обратила внимания
 
Ответить
Сообщениеsboy, у меня результат был не первый, поэтому я на это не обратила внимания

Автор - olenka1990
Дата добавления - 27.04.2017 в 22:27
vikttur Дата: Суббота, 29.04.2017, 15:36 | Сообщение № 15
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2941
Репутация: 526 ±
Замечаний: 0% ±

Код
=МАКС(ЧАСТОТА(ЕСЛИ(A1:A23<B1;СТРОКА(A1:A23));ЕСЛИ(A1:A23>=B1;СТРОКА(A1:A23))))

Формула массива, ввод тремя клавишами
 
Ответить
Сообщение
Код
=МАКС(ЧАСТОТА(ЕСЛИ(A1:A23<B1;СТРОКА(A1:A23));ЕСЛИ(A1:A23>=B1;СТРОКА(A1:A23))))

Формула массива, ввод тремя клавишами

Автор - vikttur
Дата добавления - 29.04.2017 в 15:36
olenka1990 Дата: Суббота, 29.04.2017, 21:24 | Сообщение № 16
Группа: Пользователи
Ранг: Новичок
Сообщений: 20
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
vikttur, здравствуйте. Проверила вашу формулу, работает отлично, что интересно, даже при большом кол-ве данных и формула не такая страшная. Спасибо. hands
 
Ответить
Сообщениеvikttur, здравствуйте. Проверила вашу формулу, работает отлично, что интересно, даже при большом кол-ве данных и формула не такая страшная. Спасибо. hands

Автор - olenka1990
Дата добавления - 29.04.2017 в 21:24
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Подсчёт наибольшего количества значений между двумя заданным (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!