Function splitTo3parts(ByVal strSource)
    Dim objRegExp   As Object 'RegExp
    Dim colMatches  As Object 'MatchCollection
    Dim aMatch      As Object 'Match
    Dim sep         As String
       
    sep = vbTab
       
    Set objRegExp = CreateObject("VBScript.RegExp")
    objRegExp.Global = True
    
    'перенос строки как окончание предложения, чтобы точно так же, как предложение с точкой
    objRegExp.Pattern = "[^.?!]" & vbLf 'случай Alt+Enter в ячейке
    strSource = replaceEOL(objRegExp, strSource)
    
    objRegExp.Pattern = "[^.?!]" & vbCrLf
    strSource = replaceEOL(objRegExp, strSource)
    
    objRegExp.Pattern = "[^.?!]" & vbCr
    strSource = replaceEOL(objRegExp, strSource)
    
    'замена на пробел общепринятых пробельных символов
    strSource = Replace(strSource, vbTab, " ")
    strSource = Replace(strSource, vbCr, " ")
    strSource = Replace(strSource, vbLf, " ")
    
    'а также неразрывного пробела - символа с кодом 160
    strSource = Replace(strSource, Chr(160), " ")
    
    'дополнительно чистим ПЕЧСИМВ (вдруг что-то еще осталось)
    'и удаляем лишние пробелы
    With WorksheetFunction
        strSource = .Clean(strSource)
        strSource = .Trim(strSource) 'именно Trim табличной функцией
    End With
    'здесь между символами остался максимум ОДИН пробел
    
    'временно заменяем исключения - типа города г. и т.е., чтобы не мешались точками
    'а также сюда добавим другие, если еще найдутся
    strSource = Replace(strSource, " г. ", " г_| ", , , vbBinaryCompare) 'заменяем только строчную "г."
    strSource = Replace(strSource, " т.е. ", " т_|е_| ")
        
    objRegExp.Pattern = "[.?!]\s[A-ZА-Я0-9""]" 'добавил возможность начала предложения с цифры и двойной кавычки
    
    Set colMatches = objRegExp.Execute(strSource)
    
    For Each aMatch In colMatches 'меняем все совпадения (а не только первые два, как раньше)
        Mid(strSource, aMatch.FirstIndex + 2) = sep
    Next
    
    'восстанавливаем исключения - типа города и т.е.
    strSource = Replace(strSource, "г_|", "г.")
    strSource = Replace(strSource, "т_|е_|", "т.е.")

    'с защитой от #Н/Д и 0 на 100 ячеек (предложений), начиная со 101-й ячейки пойдут #Н/Д
    splitTo3parts = Split(strSource & String(100 - WorksheetFunction.Min(colMatches.Count, 100), sep), sep, 100)
End Function