Sub formOnDialogSheet()

      Dim ds As DialogSheet
      Dim df As DialogFrame
      Dim lb As ListBox
      Dim x, i&, s, sel, str
      Dim bSaved As Boolean
      Dim rst As Object
        
      'подготовка к созданию отсортированного списка
      Set rst = CreateObject("ADODB.Recordset")
      rst.Fields.Append "F1", 200, 100
      rst.Open
       
      With Worksheets("ШТАТ")
          If .FilterMode Then .ShowAllData
          x = .Range("A5:F" & .Cells(.Rows.Count, 1).End(xlUp).Row).Value
      End With
        
      For i = 1 To UBound(x)
          If x(i, 6) = "пв" Then rst.AddNew "F1", x(i, 1)
      Next i
      rst.Sort = "F1 ASC"
        
      'фиксируем состояние "сохранности" книги перед созданием диалога
      bSaved = ThisWorkbook.saved
        
      'создаем невидимый лист диалога (привет из Excel 5)
      Set ds = DialogSheets.Add(before:=ActiveSheet)
      ds.Visible = xlSheetHidden
        
      Set df = ds.DialogFrame
      df.Caption = "Множественный выбор из списка"
      df.Height = 2 * df.Height
        
      Set lb = ds.ListBoxes.Add(df.Left + 10, df.Top + 20, 180, 270)
      lb.MultiSelect = xlSimple
        
      'наполняем список
      With rst
          .MoveFirst
          While Not .EOF
              lb.List(.AbsolutePosition) = !F1
              .MoveNext
          Wend
      End With
           
      'отображаем диалог (выполнение останавливается до закрытия)
      ds.Show

      'после закрытия диалога
      'обрабатываем выбор пользователя (например, отображаем)
      sel = lb.Selected
      For i = LBound(sel) To UBound(sel)
          If sel(i) Then str = str & ", " & lb.List(i)
      Next i
        
      MsgBox Mid(str, 3), vbOKOnly, "Выбранные элементы списка"
        
      'удаляем невидимый лист диалога
      Application.DisplayAlerts = False
      ds.Delete
      Application.DisplayAlerts = True
        
      'восстанавливаем состояние "сохранности" до манипуляций с диалогом
      If bSaved Then ThisWorkbook.saved = True
        
End Sub