Sub Кнопка2_Щелчок()
     Dim x As String
     With ActiveCell
         x = .Value
         If (.Column = 2) And Len(x) Then                     ' проверяет активную ячейку пустая ли она
             ThisWorkbook.Worksheets("Шаблон").Copy , .Parent ' копирует лист "Шаблон" и вставляет после листа "Общий перечень обозначений"
             ActiveSheet.Name = x                             ' присваивает имя новому листу по выделенной ячейке
             .Hyperlinks.Add .Item(1), "", x & "!A1", , x     ' присваивает гиперссылку
         End If
     End With
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
     If Target.Column <> 2 Then Exit Sub
     Dim x As String
     With Target(1)
         x = .Value
         If Len(x) Then                    ' проверяет активную ячейку пустая ли она
             If .Hyperlinks.Count Then                        ' если в ячейке уже есть гиперссылка
                 With .Hyperlinks(1)
                     If .Name <> x Then                       ' и значение ячейки изменилось
                         Application.EnableEvents = False
                         Worksheets(.Name).Name = x           ' переименовываем лист
                         .TextToDisplay = x
                         .SubAddress = x & "!A1"              ' исправляем гиперссылку
                         Application.EnableEvents = True
                     End If
                 End With
             Else                    ' если гиперссылки в ячейке нет
                 Worksheets("Шаблон").Copy , .Parent          ' копирует лист "Шаблон" и вставляет после листа "Общий перечень обозначений"
                 ActiveSheet.Name = x                         ' присваивает новому листу имя, равное значению выделенной ячейки
                 .Hyperlinks.Add .Item(1), "", x & "!A1", , x ' присваивает гиперссылку
             End If
         End If
     End With
End Sub