Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Удаление текста из строк по условию - Мир MS Excel

Регистрация · Логин: · Пароль: · · Забыли пароль?
Страница 1 из 212»
Модератор форума: _Boroda_, Pelena, Manyasha, SLAVICK 
Мир MS Excel » Вопросы и решения » Вопросы по VBA » Удаление текста из строк по условию (Макросы/Sub)
Удаление текста из строк по условию
force Дата: Четверг, 18.02.2016, 20:11 | Сообщение № 1
Группа: Пользователи
Ранг: Новичок
Сообщений: 42
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
Всем доброго времени суток!

Нужна Ваша помощь с написанием макроса обработки прайса:

1. Во всех строках удалять все, что встретиться после первой запятой, удалять до тех пор, пока не встретится любое из условий, например текст: Dual, или 4G, или 32GB и тд...

Как удалить все после первой запятой нашел, а дальше тупик :)

[vba]
Код

Sub Macro1()
Columns("A:A").Select
Selection.Replace What:=",*", Replacement:="", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False
End Sub
[/vba]

Исходник (файл с наименованием start) и пример (файл с наименованием finish) прилагаю.
Надеюсь и рассчитываю на Вашу помощь в решении такой сложной задачи.
К сообщению приложен файл: satrt.xlsx(14Kb) · finish.xlsx(14Kb)


Сообщение отредактировал force - Четверг, 18.02.2016, 20:12
 
Ответить
СообщениеВсем доброго времени суток!

Нужна Ваша помощь с написанием макроса обработки прайса:

1. Во всех строках удалять все, что встретиться после первой запятой, удалять до тех пор, пока не встретится любое из условий, например текст: Dual, или 4G, или 32GB и тд...

Как удалить все после первой запятой нашел, а дальше тупик :)

[vba]
Код

Sub Macro1()
Columns("A:A").Select
Selection.Replace What:=",*", Replacement:="", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False
End Sub
[/vba]

Исходник (файл с наименованием start) и пример (файл с наименованием finish) прилагаю.
Надеюсь и рассчитываю на Вашу помощь в решении такой сложной задачи.

Автор - force
Дата добавления - 18.02.2016 в 20:11
МВТ Дата: Четверг, 18.02.2016, 20:27 | Сообщение № 2
Группа: Проверенные
Ранг: Обитатель
Сообщений: 475
Репутация: 135 ±
Замечаний: 0% ±

Excel 2007
Попробуйте так [vba]
Код
Function tt(Text As String) As String
    With CreateObject("VBScript.RegExp")
        .Pattern = ",.+?(Dual|4G|32GB)"
        tt = .Replace(Text, " $1")
    End With
End Function
[/vba]
 
Ответить
СообщениеПопробуйте так [vba]
Код
Function tt(Text As String) As String
    With CreateObject("VBScript.RegExp")
        .Pattern = ",.+?(Dual|4G|32GB)"
        tt = .Replace(Text, " $1")
    End With
End Function
[/vba]

Автор - МВТ
Дата добавления - 18.02.2016 в 20:27
force Дата: Четверг, 18.02.2016, 21:10 | Сообщение № 3
Группа: Пользователи
Ранг: Новичок
Сообщений: 42
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
МВТ,

Спасибо за оперативный ответ. Может подскажете, Ваш вариант можно реализовать не через функцию?
 
Ответить
СообщениеМВТ,

Спасибо за оперативный ответ. Может подскажете, Ваш вариант можно реализовать не через функцию?

Автор - force
Дата добавления - 18.02.2016 в 21:10
МВТ Дата: Четверг, 18.02.2016, 21:20 | Сообщение № 4
Группа: Проверенные
Ранг: Обитатель
Сообщений: 475
Репутация: 135 ±
Замечаний: 0% ±

Excel 2007
Можно процедурой (макросом) [vba]
Код
Sub tt()
    'Обрабатывает все выделенные ячейки
    Dim Cell As Range
    With CreateObject("VBScript.RegExp")
        .Pattern = ",.+?(Dual|4G|32GB)"
        For Each Cell In Selection
            Cell.Value = .Replace(Cell.Value, " $1")
        Next
    End With
End Sub
[/vba]
 
Ответить
СообщениеМожно процедурой (макросом) [vba]
Код
Sub tt()
    'Обрабатывает все выделенные ячейки
    Dim Cell As Range
    With CreateObject("VBScript.RegExp")
        .Pattern = ",.+?(Dual|4G|32GB)"
        For Each Cell In Selection
            Cell.Value = .Replace(Cell.Value, " $1")
        Next
    End With
End Sub
[/vba]

Автор - МВТ
Дата добавления - 18.02.2016 в 21:20
force Дата: Четверг, 18.02.2016, 21:24 | Сообщение № 5
Группа: Пользователи
Ранг: Новичок
Сообщений: 42
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
МВТ,

К сожалению не работает макрос :( , а в функции не все удаляет, например:


Т.е. если не встречаются исключения из условий, ничего не удаляется :(


Сообщение отредактировал force - Четверг, 18.02.2016, 22:27
 
Ответить
СообщениеМВТ,

К сожалению не работает макрос :( , а в функции не все удаляет, например:


Т.е. если не встречаются исключения из условий, ничего не удаляется :(

Автор - force
Дата добавления - 18.02.2016 в 21:24
Kuzmich Дата: Четверг, 18.02.2016, 23:14 | Сообщение № 6
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 210
Репутация: 39 ±
Замечаний: 0% ±

Excel 2003
В исходник (файл с наименованием start) в модуль листа Телефоны
[vba]
Код

Sub Telefon()
Dim i As Long
Dim j As Integer
Dim iLastRow As Long
Dim MyArr
iLastRow = Cells(Rows.Count, 1).End(xlUp).Row
For i = 2 To iLastRow
  If InStr(1, Cells(i, 1), ",") <> 0 Then
   MyArr = Split(Cells(i, 1), ",", 2)
   If InStr(1, MyArr(1), "Dual") = 0 And InStr(1, MyArr(1), "4G") = 0 _
         And InStr(1, MyArr(1), "32GB") = 0 Then
       Cells(i, 3) = MyArr(0) & " " & MyArr(1)
   Else
     If InStr(1, MyArr(1), "Dual") <> 0 Then
       j = InStr(1, MyArr(1), "Dual")
       Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), 1, j - 1)
     End If
     If InStr(1, MyArr(1), "4G") <> 0 Then
       j = InStr(1, MyArr(1), "4G")
       Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), 1, j - 1)
     End If
     If InStr(1, MyArr(1), "32GB") <> 0 Then
       j = InStr(1, MyArr(1), "32GB")
       Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), 1, j - 1)
     End If
   End If
  Else
      Cells(i, 3) = Cells(i, 1)
  End If
Next
End Sub
[/vba]
 
Ответить
СообщениеВ исходник (файл с наименованием start) в модуль листа Телефоны
[vba]
Код

Sub Telefon()
Dim i As Long
Dim j As Integer
Dim iLastRow As Long
Dim MyArr
iLastRow = Cells(Rows.Count, 1).End(xlUp).Row
For i = 2 To iLastRow
  If InStr(1, Cells(i, 1), ",") <> 0 Then
   MyArr = Split(Cells(i, 1), ",", 2)
   If InStr(1, MyArr(1), "Dual") = 0 And InStr(1, MyArr(1), "4G") = 0 _
         And InStr(1, MyArr(1), "32GB") = 0 Then
       Cells(i, 3) = MyArr(0) & " " & MyArr(1)
   Else
     If InStr(1, MyArr(1), "Dual") <> 0 Then
       j = InStr(1, MyArr(1), "Dual")
       Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), 1, j - 1)
     End If
     If InStr(1, MyArr(1), "4G") <> 0 Then
       j = InStr(1, MyArr(1), "4G")
       Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), 1, j - 1)
     End If
     If InStr(1, MyArr(1), "32GB") <> 0 Then
       j = InStr(1, MyArr(1), "32GB")
       Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), 1, j - 1)
     End If
   End If
  Else
      Cells(i, 3) = Cells(i, 1)
  End If
Next
End Sub
[/vba]

Автор - Kuzmich
Дата добавления - 18.02.2016 в 23:14
force Дата: Пятница, 19.02.2016, 10:30 | Сообщение № 7
Группа: Пользователи
Ранг: Новичок
Сообщений: 42
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
Kuzmich,

Спасибо за помощь, но Ваш вариант, к сожалению, не работает.



Может Ваш вариант можно немного доработать, что бы он не удалял сами слова с условиями, а только удалял все после первой запятой, пока не встретит любое слово из массива условий?
 
Ответить
СообщениеKuzmich,

Спасибо за помощь, но Ваш вариант, к сожалению, не работает.



Может Ваш вариант можно немного доработать, что бы он не удалял сами слова с условиями, а только удалял все после первой запятой, пока не встретит любое слово из массива условий?

Автор - force
Дата добавления - 19.02.2016 в 10:30
Kuzmich Дата: Пятница, 19.02.2016, 11:54 | Сообщение № 8
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 210
Репутация: 39 ±
Замечаний: 0% ±

Excel 2003
Цитата
Может Ваш вариант можно немного доработать

Немного не так понял ваше условие, попробуйте заменить три строчки в коде, я их закомментировал
на строчки , что расположены ниже
[vba]
Код

    If InStr(1, MyArr(1), "Dual") <> 0 Then
    j = InStr(1, MyArr(1), "Dual")
    'Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), 1, j - 1)
    Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), j)
    End If
    If InStr(1, MyArr(1), "4G") <> 0 Then
    j = InStr(1, MyArr(1), "4G")
    'Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), 1, j - 1)
    Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), j)
    End If
    If InStr(1, MyArr(1), "32GB") <> 0 Then
    j = InStr(1, MyArr(1), "32GB")
    'Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), 1, j - 1)
    Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), j)
    End If
[/vba]
 
Ответить
Сообщение
Цитата
Может Ваш вариант можно немного доработать

Немного не так понял ваше условие, попробуйте заменить три строчки в коде, я их закомментировал
на строчки , что расположены ниже
[vba]
Код

    If InStr(1, MyArr(1), "Dual") <> 0 Then
    j = InStr(1, MyArr(1), "Dual")
    'Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), 1, j - 1)
    Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), j)
    End If
    If InStr(1, MyArr(1), "4G") <> 0 Then
    j = InStr(1, MyArr(1), "4G")
    'Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), 1, j - 1)
    Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), j)
    End If
    If InStr(1, MyArr(1), "32GB") <> 0 Then
    j = InStr(1, MyArr(1), "32GB")
    'Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), 1, j - 1)
    Cells(i, 3) = MyArr(0) & " " & Mid(MyArr(1), j)
    End If
[/vba]

Автор - Kuzmich
Дата добавления - 19.02.2016 в 11:54
RAN Дата: Пятница, 19.02.2016, 11:55 | Сообщение № 9
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4277
Репутация: 829 ±
Замечаний: 0% ±

2010
Чуть поправил макрос МВТ,
[vba]
Код
Sub tt()
'Обрабатывает все выделенные ячейки
    Dim Cell As Range
    With CreateObject("VBScript.RegExp")
        .Pattern = ",.+?(Dual|4G|32GB)"
        On Error Resume Next
        For Each Cell In Selection
            If .Test(Cell.Value) Then
                Cell.Value = .Replace(Cell.Value, " $1")
            Else
                Cell.Value = Left(Cell.Value, InStr(Cell.Value, ",") - 1)
            End If
        Next
    End With
End Sub
[/vba]


Быть или не быть, вот в чем загвоздка!
 
Ответить
СообщениеЧуть поправил макрос МВТ,
[vba]
Код
Sub tt()
'Обрабатывает все выделенные ячейки
    Dim Cell As Range
    With CreateObject("VBScript.RegExp")
        .Pattern = ",.+?(Dual|4G|32GB)"
        On Error Resume Next
        For Each Cell In Selection
            If .Test(Cell.Value) Then
                Cell.Value = .Replace(Cell.Value, " $1")
            Else
                Cell.Value = Left(Cell.Value, InStr(Cell.Value, ",") - 1)
            End If
        Next
    End With
End Sub
[/vba]

Автор - RAN
Дата добавления - 19.02.2016 в 11:55
force Дата: Пятница, 19.02.2016, 12:17 | Сообщение № 10
Группа: Пользователи
Ранг: Новичок
Сообщений: 42
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
Kuzmich,

Ваш вариант почти заработал, но попадаются строки, в которых удалилась только запятая:



И как можно доработать так, чтоб данные менялись в исходных столбцах, а не добавлялись в новый?
 
Ответить
СообщениеKuzmich,

Ваш вариант почти заработал, но попадаются строки, в которых удалилась только запятая:



И как можно доработать так, чтоб данные менялись в исходных столбцах, а не добавлялись в новый?

Автор - force
Дата добавления - 19.02.2016 в 12:17
force Дата: Пятница, 19.02.2016, 12:32 | Сообщение № 11
Группа: Пользователи
Ранг: Новичок
Сообщений: 42
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
RAN,

Спасибо за помощь, Ваш вариант отлично работает!

Я немного допилил Ваш вариант, посмотрите плиз, я добавил выделение столбцов до последнего заполненного:

[vba]
Код
Sub tt()
'Обрабатывает все выделенные ячейки
    Dim Cell As Range
    Dim lLastRow As Long

    lLastRow = Cells(Rows.Count, 1).End(xlUp).Row
    Range("A1:A" & lLastRow).Select
    With CreateObject("VBScript.RegExp")
        .Pattern = ",.+?(Dual|Single|4G|3G|32GB|16GB|2GB|8GB|PCT|EAC|8G|ЕВРОПА)"
        On Error Resume Next
        For Each Cell In Selection
            If .Test(Cell.Value) Then
                Cell.Value = .Replace(Cell.Value, " $1")
            Else
                Cell.Value = Left(Cell.Value, InStr(Cell.Value, ",") - 1)
            End If
        Next
    End With
End Sub
[/vba]


Сообщение отредактировал force - Пятница, 19.02.2016, 12:34
 
Ответить
СообщениеRAN,

Спасибо за помощь, Ваш вариант отлично работает!

Я немного допилил Ваш вариант, посмотрите плиз, я добавил выделение столбцов до последнего заполненного:

[vba]
Код
Sub tt()
'Обрабатывает все выделенные ячейки
    Dim Cell As Range
    Dim lLastRow As Long

    lLastRow = Cells(Rows.Count, 1).End(xlUp).Row
    Range("A1:A" & lLastRow).Select
    With CreateObject("VBScript.RegExp")
        .Pattern = ",.+?(Dual|Single|4G|3G|32GB|16GB|2GB|8GB|PCT|EAC|8G|ЕВРОПА)"
        On Error Resume Next
        For Each Cell In Selection
            If .Test(Cell.Value) Then
                Cell.Value = .Replace(Cell.Value, " $1")
            Else
                Cell.Value = Left(Cell.Value, InStr(Cell.Value, ",") - 1)
            End If
        Next
    End With
End Sub
[/vba]

Автор - force
Дата добавления - 19.02.2016 в 12:32
Kuzmich Дата: Пятница, 19.02.2016, 13:24 | Сообщение № 12
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 210
Репутация: 39 ±
Замечаний: 0% ±

Excel 2003
Цитата
но попадаются строки, в которых удалилась только запятая

Тогда измените еще одну строчку
[vba]
Код

If InStr(1, MyArr(1), "Dual") = 0 And InStr(1, MyArr(1), "4G") = 0 _
        And InStr(1, MyArr(1), "32GB") = 0 Then
'    Cells(i, 3) = MyArr(0) & " " & MyArr(1)
    Cells(i, 3) = MyArr(0)
[/vba]
 
Ответить
Сообщение
Цитата
но попадаются строки, в которых удалилась только запятая

Тогда измените еще одну строчку
[vba]
Код

If InStr(1, MyArr(1), "Dual") = 0 And InStr(1, MyArr(1), "4G") = 0 _
        And InStr(1, MyArr(1), "32GB") = 0 Then
'    Cells(i, 3) = MyArr(0) & " " & MyArr(1)
    Cells(i, 3) = MyArr(0)
[/vba]

Автор - Kuzmich
Дата добавления - 19.02.2016 в 13:24
Wasilich Дата: Пятница, 19.02.2016, 13:56 | Сообщение № 13
Группа: Друзья
Ранг: Ветеран
Сообщений: 857
Репутация: 220 ±
Замечаний: 0% ±

2003
Может так пойдет
чтоб данные менялись в исходных столбцах,
Cells(i, 4) = y заменить на Cells(i, 1) = y
К сообщению приложен файл: force.xls(62Kb)


Сообщение отредактировал Wasilic - Пятница, 19.02.2016, 13:57
 
Ответить
СообщениеМожет так пойдет
чтоб данные менялись в исходных столбцах,
Cells(i, 4) = y заменить на Cells(i, 1) = y

Автор - Wasilich
Дата добавления - 19.02.2016 в 13:56
force Дата: Пятница, 19.02.2016, 21:37 | Сообщение № 14
Группа: Пользователи
Ранг: Новичок
Сообщений: 42
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
Kuzmich, и Wasilic,

Спасибо Вам за помощь! Буду рад, если подскажете как все это дело применить ко всем листам в книге!!!

Пытался сделать так:
[vba]
Код
Sheets(Array(1, 2, 3)).Select
[/vba]
Но так не работает, только если по отдельности прописать код к каждому листу...



Такая "схема" работает, но может можно все сделать более красиво?


Сообщение отредактировал force - Пятница, 19.02.2016, 21:42
 
Ответить
СообщениеKuzmich, и Wasilic,

Спасибо Вам за помощь! Буду рад, если подскажете как все это дело применить ко всем листам в книге!!!

Пытался сделать так:
[vba]
Код
Sheets(Array(1, 2, 3)).Select
[/vba]
Но так не работает, только если по отдельности прописать код к каждому листу...



Такая "схема" работает, но может можно все сделать более красиво?

Автор - force
Дата добавления - 19.02.2016 в 21:37
RAN Дата: Пятница, 19.02.2016, 22:19 | Сообщение № 15
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4277
Репутация: 829 ±
Замечаний: 0% ±

2010
[vba]
Код
Sub ttt()
    Dim Cell As Range, sh As Worksheet
    With CreateObject("VBScript.RegExp")
        .Pattern = ",.+?(Dual|Single|4G|3G|32GB|16GB|2GB|8GB|PCT|EAC|8G|ЕВРОПА)"
        On Error Resume Next
        For Each sh In Worksheets
            For Each Cell In sh.Range(sh.Cells(1, 1), sh.Cells(sh.Rows.Count, 1).End(xlUp))
                If .Test(Cell.Value) Then
                    Cell.Value = .Replace(Cell.Value, " $1")
                Else
                    Cell.Value = Left(Cell.Value, InStr(Cell.Value, ",") - 1)
                End If
            Next
        Next
    End With
End Sub
[/vba]


Быть или не быть, вот в чем загвоздка!

Сообщение отредактировал RAN - Пятница, 19.02.2016, 22:19
 
Ответить
Сообщение[vba]
Код
Sub ttt()
    Dim Cell As Range, sh As Worksheet
    With CreateObject("VBScript.RegExp")
        .Pattern = ",.+?(Dual|Single|4G|3G|32GB|16GB|2GB|8GB|PCT|EAC|8G|ЕВРОПА)"
        On Error Resume Next
        For Each sh In Worksheets
            For Each Cell In sh.Range(sh.Cells(1, 1), sh.Cells(sh.Rows.Count, 1).End(xlUp))
                If .Test(Cell.Value) Then
                    Cell.Value = .Replace(Cell.Value, " $1")
                Else
                    Cell.Value = Left(Cell.Value, InStr(Cell.Value, ",") - 1)
                End If
            Next
        Next
    End With
End Sub
[/vba]

Автор - RAN
Дата добавления - 19.02.2016 в 22:19
force Дата: Суббота, 20.02.2016, 00:33 | Сообщение № 16
Группа: Пользователи
Ранг: Новичок
Сообщений: 42
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
RAN,

Спасибо, отличный вариант! Но, когда в условия добавляю |), макрос не работает.
[vba]
Код
.Pattern = ",.+?(Dual|Single|4G|3G|32GB|16GB|2GB|8GB|PCT|EAC|8G|ЕВРОПА|))"
[/vba]
Это условие нужно для такого случая:


Сообщение отредактировал force - Суббота, 20.02.2016, 00:35
 
Ответить
СообщениеRAN,

Спасибо, отличный вариант! Но, когда в условия добавляю |), макрос не работает.
[vba]
Код
.Pattern = ",.+?(Dual|Single|4G|3G|32GB|16GB|2GB|8GB|PCT|EAC|8G|ЕВРОПА|))"
[/vba]
Это условие нужно для такого случая:

Автор - force
Дата добавления - 20.02.2016 в 00:33
Kuzmich Дата: Суббота, 20.02.2016, 10:17 | Сообщение № 17
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 210
Репутация: 39 ±
Замечаний: 0% ±

Excel 2003
[vba]
Код

        .Pattern = ",.+?(Dual|Single|4G|3G|32GB|16GB|2GB|8GB|PCT|EAC|8G|ЕВРОПА|\))"
[/vba]
 
Ответить
Сообщение[vba]
Код

        .Pattern = ",.+?(Dual|Single|4G|3G|32GB|16GB|2GB|8GB|PCT|EAC|8G|ЕВРОПА|\))"
[/vba]

Автор - Kuzmich
Дата добавления - 20.02.2016 в 10:17
RAN Дата: Суббота, 20.02.2016, 11:32 | Сообщение № 18
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4277
Репутация: 829 ±
Замечаний: 0% ±

2010
[vba]
Код
.Pattern = ",.+?(Dual|Single|PCT|EAC|ЕВРОПА|\d|\))"
[/vba]


Быть или не быть, вот в чем загвоздка!
 
Ответить
Сообщение[vba]
Код
.Pattern = ",.+?(Dual|Single|PCT|EAC|ЕВРОПА|\d|\))"
[/vba]

Автор - RAN
Дата добавления - 20.02.2016 в 11:32
force Дата: Суббота, 20.02.2016, 13:05 | Сообщение № 19
Группа: Пользователи
Ранг: Новичок
Сообщений: 42
Репутация: 1 ±
Замечаний: 0% ±

Excel 2010
RAN,

Спасибо огромное за помощь!
Тему можно закрывать, вопрос решен! respect
 
Ответить
СообщениеRAN,

Спасибо огромное за помощь!
Тему можно закрывать, вопрос решен! respect

Автор - force
Дата добавления - 20.02.2016 в 13:05
RAN Дата: Суббота, 20.02.2016, 13:33 | Сообщение № 20
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4277
Репутация: 829 ±
Замечаний: 0% ±

2010
Спасибо надо МВТ говорить. Это его код.
А все остальное так, фантики.


Быть или не быть, вот в чем загвоздка!
 
Ответить
СообщениеСпасибо надо МВТ говорить. Это его код.
А все остальное так, фантики.

Автор - RAN
Дата добавления - 20.02.2016 в 13:33
Мир MS Excel » Вопросы и решения » Вопросы по VBA » Удаление текста из строк по условию (Макросы/Sub)
Страница 1 из 212»
Поиск:

Яндекс цитирования
© 2010-2016 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!