Option Explicit

'Public RET_Val   ' переменная для возврата данных из временной UserForm

Sub test_LstBox()   ' тестирование LstBox
On Error Resume Next
Dim x
Set x = ActiveWorkbook.VBProject   ' проверка доступности .VBProject
If Err Then MsgBox "Настройки безопасности не позволяют выполнить макрос", vbCritical: Exit Sub
On Error GoTo 0

MsgBox LstBox(GetListItems, "Select Item")

'If VarType(RET_Val) = vbBoolean Then MsgBox "Item Not Selected!", vbCritical: Exit Sub  ' если нажали "Отмена", то Ret_Val = False
End Sub

Private Function GetListItems()   ' получить массив значений для заполнения ListBox
Dim xVal
With CreateObject("Scripting.Dictionary"): .CompareMode = vbTextCompare   ' Создаем словарь
    .Add ">> " & ActiveSheet.Name & " <<", ""  ' текущий документ первый в списке
    For Each xVal In ActiveWorkbook.Worksheets
        .Add xVal.Name, ""
    Next xVal   ' другие открытые документы
    .Add "<< " & "New Document" & " >>", ""
    GetListItems = .Keys   ' массив ключей копируем в массив (напрямую читать из .Keys нельзя)
End With
End Function

Private Function LstBox(Arr, Title$) As String   ' создание, вывод и удаление временной UserForm с ListBox
Dim oFrm, oListBox
Dim oDoc: Set oDoc = ThisWorkbook   ' в других объектных моделях необходимо назначить соответствующие объекты (в Visio - ThisDocument)
Dim sCodeStr$
sCodeStr = "Private Sub UserForm_Initialize()" & vbCrLf & _
           "   With Me.ListBox1" & vbCrLf & _
           "      .Top = Me.Top: .Left = Me.Left" & vbCrLf & _
           "      .Height = Me.Height: .Width = Me.Width" & vbCrLf & _
           "      .List = Split(.Tag, ""||""): .Tag = """" ' заполнить списком, переданным в ListBox1.Tag" & vbCrLf & _
           "   End With" & vbCrLf & _
           "End Sub" & vbCrLf & _
           vbCrLf & _
           "Private Sub ListBox1_DblClick(ByVal Cancel As MSForms.ReturnBoolean)" & vbCrLf & _
           "   Me.Tag = Me.ListBox1.Text: Me.Hide ' Unload Me" & vbCrLf & _
           "End Sub"
Set oFrm = oDoc.VBProject.VBComponents.Add(3)   ' vbext_ct_StdModule == 1 , vbext_ct_ClassModule == 2 , vbext_ct_MSForm == 3
With oFrm
    .Properties("Width") = 350   ' или .Properties(42)
    .Properties("Height") = 150   ' или .Properties(43)
    Set oListBox = .Designer.Controls.Add("Forms.Listbox.1")
    oListBox.Tag = Join(Arr, "||")      'передача списка в форму через параметр ListBox.Tag
    
    With .CodeModule
        .InsertLines .CountOfDeclarationLines + 1, sCodeStr
    End With   ' без With … End With, почему-то не работает
    VBA.UserForms.Add(.Name).Show
    
    LstBox = VBA.UserForms(VBA.UserForms.Count - 1).Tag '****

End With
oDoc.VBProject.VBComponents.Remove VBComponent:=oFrm   ' удаление созданной временной формы
End Function