Private Sub Worksheet_Deactivate() 'если активируется другой лист и есть подсветка, то подсветка убирается
    Call restoreFill
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim dataRng As Range ' диапазон данных таблицы
Dim rowRng As Range ' диапазон ячеек в строке таблицы для подсветки
Dim celRng As Range ' ячейки в диапазоне подсветки rowRng
Dim n As Integer
    Call restoreFill
    If Range("A1").Interior.ColorIndex = xlNone Then Exit Sub 'если подсветка отключена, то выход
    If Target.Count > 1 Then Exit Sub 'если выделено больше одной ячейки
    Set dataRng = Range(Cells(7, 2), Cells(ActiveSheet.UsedRange.Row + ActiveSheet.UsedRange.Rows.Count - 1, _
    ActiveSheet.UsedRange.Column + ActiveSheet.UsedRange.Columns.Count - 1)) ' диапазон данных таблицы, Cells(7, 2) - адрес (начало) диапазона данных таблицы
    If Not Intersect(Target, dataRng) Is Nothing Then 'если ячейка выделена в диапазоне данных таблицы
        Set rowRng = Intersect(dataRng, Target.EntireRow) 'строка таблицы с выделенной ячейкой в диапазоне данных таблицы
        ReDim saveColor(rowRng.Cells.Count) 'размерность массива = ширина таблицы + нулевой элемент массива для адреса диапазона подсветки
        n = 0
        saveColor(n) = rowRng.Address 'адрес диапазона подсветки в нулевой элемент массива
        For Each celRng In rowRng 'перебор ячеек в диапазоне подсветки
            n = n + 1 'номер следующего элемента массива
            saveColor(n) = celRng.Interior.ColorIndex 'индекс заливки текущей ячейки в массив
        Next celRng
        rowRng.Interior.ColorIndex = Range("A1").Interior.ColorIndex 'заливка диапазона подсветки цветом заливки ячейки А1
        Target.Interior.ColorIndex = xlNone 'выделенная ячейка без заливки
    End If
    End Sub

Sub restoreFill() 'проверка включения подсветки, если подсветка была включена, то восстановление первоначальной (до подсветки) заливки в этой строке
Dim c As Integer
Dim cel_InRng As Range ' ячейки в диапазоне подсветки rowRng
    If (Not Not saveColor) <> 0 Then 'если массив не пустой (так проверяется массив, объявленный как Dim saveColor() ), т.е. диапазон подсветки был определен ранее
        c = 0
        For Each cel_InRng In Range(saveColor(0)) 'перебор ячеек в диапазоне, указанном в нулевом элементе массива
            c = c + 1 'номер следующего элемента массива
            cel_InRng.Interior.ColorIndex = saveColor(c) 'заливка ячеек цветами, сохраненными в массиве
        Next cel_InRng
        Erase saveColor 'удаление массива
    Else
        Exit Sub
    End If
End Sub

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
    If ActiveSheet.Name = "Имя листа с таблицей" Then Call Sheets("Имя листа с таблицей").restoreFill  
End Sub

Public saveColor() ' адрес подсвечиваемого диапазона и сохраненные цвета заливки подсвечиваемых ячеек таблицы до подсветки