ActiveSheet.Cells(5, 2).End(xlDown).Address     ' последняя заполненная ячейка в столбце В, начиная с 5-й строки

ActiveSheet.Cells.SpecialCells(xlLastCell).Address

Private Sub LAST_CELL()   ' последняя ячейка используемого диапазона на листе
' http://msoffice.nm.ru/article/lastcell.htm - "Поиск последней заполненной ячейки"
' http://www.excel-vba.ru/chto-umeet-excel/kak-opredelit-poslednyuyu-yachejku-na-liste-cherez-vba/ - Как определить последнюю ячейку на листе через VBA?
   Dim sLastAddr$, lLastRow&, iLastCol%
   'With Sheets("Лист1")
   With ActiveSheet
      'МЕТОД 1: определяется последняя ячейка В ЗАДАННОМ СТОЛБЦЕ/СТРОКЕ
      'НО игнорируются скрытые строки/столбцы (шириной/высотой, группировкой, фильтром …)
      lLastRow = .Cells(.Rows.Count, 1).End(xlUp).Row
      'lLastRow = .Cells(.Rows.Count, "A").End(xlUp).Row
      'lLastRow = .Range("A" & Rows.Count).End(xlUp).Row
      iLastCol = .Cells(1, .Columns.Count).End(xlToLeft).Column
      sLastAddr = .Cells(.Rows.Count, 1).End(xlUp).Address
      'sLastAddr = .Cells(.Rows.Count, "A").End(xlUp).Address
      'Arr = Range("A1:A" & Cells(Rows.Count, "C").End(xlUp).Row).Value

      lLastRow = .Cells(5, 2).End(xlDown).Row     ' последняя заполненная ячейка в столбце В, начиная с 5-й строки

      'МЕТОД 2: МОЖЕТ СЧИТАТЬ НЕ ВЕРНО в файле, не сохранённом после удаления последней ячейки, _
       а также может учесть пустую, но форматированную ячейку (заливка, границы, УФ, …)
      'правильно работает в только что созданном документе, _
       в котором только добавляются данные в строки/столбцы
      lLastRow = .Cells.SpecialCells(xlLastCell).Row
      iLastCol = .Cells.SpecialCells(xlLastCell).Column
      sLastAddr = .Cells.SpecialCells(xlLastCell).Address

      'МЕТОД 3: те же недостатки, что и у метода 2… Но т.к. есть обращение к UsedRange, то считает верно!
      lLastRow = .UsedRange.Row + .UsedRange.Rows.Count - 1
      iLastCol = .UsedRange.Column + .UsedRange.Columns.Count - 1
      '!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
      ' Переопределить текущее положение последней ячейки можно просто обратившись к UsedRange:
      With .UsedRange: End With
      'или так:
      lLastRow = .UsedRange.Cells.SpecialCells(xlLastCell).Row
      iLastCol = .UsedRange.Cells.SpecialCells(xlLastCell).Column
      sLastAddr = .UsedRange.Cells.SpecialCells(xlLastCell).Address
   End With
End Sub

Set x = Cells.Find("*", [a1], xlFormulas, 1, 1, 2)