Const ShiftX = 492
Const ShiftY = 387
Const Scal = 50

Sub draw()
    For Each Mycell In Range("c5:c10,f5:f10,i5:i10")
        If Mycell <> "" Then
            Call DrawFromBase(Mycell.Value, Mycell.Offset(, 1), Mycell.Offset(, 2), Getline(Left(Mycell, Len(Mycell) - 2)))
        End If
    Next
End Sub
Sub DrawFromBase(Name As String, Re As Double, Im As Double, ParrentLine As Shape)
Dim x0 As Double, y0 As Double
    If ParrentLine Is Nothing Then
        x0 = ShiftX: y0 = ShiftY
    Else
        With ParrentLine
            x0 = .Left + IIf(.HorizontalFlip, 0, .Width)
            y0 = .Top + IIf(.VerticalFlip, 0, .Height)
        End With
    End If
    Call DrawLine(Name, x0 - ShiftX, ShiftY - y0, Re, Im)
End Sub

Function Getline(LineName As String) As Shape
Dim MyShape As Shape
    For Each MyShape In ActiveSheet.Shapes
        If MyShape.Name = LineName Then
            Set Getline = MyShape
            Exit For
        End If
    Next
End Function

Sub DrawLine(Name As String, x0 As Double, y0 As Double, x1 As Double, Y1 As Double)
Dim DLine As Shape
    Set DLine = ActiveSheet.Shapes.AddConnector(msoConnectorStraight, _
        ShiftX + x0, ShiftY - y0, _
        ShiftX + x0 + x1 * Scal, ShiftY - y0 - Y1 * Scal)
    DLine.Name = Name
    With DLine.Line
        .Visible = msoTrue
        .Weight = 3
        .EndArrowheadStyle = msoArrowheadTriangle
        .EndArrowheadLength = msoArrowheadLong
        .EndArrowheadWidth = msoArrowheadWide
    End With
End Sub