Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Несколько критериев в СУММЕСЛИ - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_, DrMini  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Несколько критериев в СУММЕСЛИ (Формулы/Formulas)
Несколько критериев в СУММЕСЛИ
Taverik Дата: Среда, 27.05.2015, 11:56 | Сообщение № 1
Группа: Пользователи
Ранг: Новичок
Сообщений: 11
Репутация: 0 ±
Замечаний: 20% ±

Excel 2013
Добрый день!

Есть 2 строки, в одной строке буквенные сокращения, в другой значения. Необходимо суммировать в зависимости от буквенных значений, при этом нужно чтобы суммировались значения по нескольким буквенным значениям.

Если прописывать
Код
=СУММЕСЛИ(A1:T1;"Я";A2:T2)
, то формула работает. Хотел указать несколько критериев через ИЛИ:
Код
=СУММЕСЛИ(A1:T1;ИЛИ("Я";"Н";"РВ";"С";"ВМ";"ЛЧ";"НС");A2:T2)
, но формула не работает.

Подскажите, пожалуйста, решение
К сообщению приложен файл: sumif.xls (26.5 Kb)


Сообщение отредактировал Serge_007 - Среда, 27.05.2015, 20:22
 
Ответить
СообщениеДобрый день!

Есть 2 строки, в одной строке буквенные сокращения, в другой значения. Необходимо суммировать в зависимости от буквенных значений, при этом нужно чтобы суммировались значения по нескольким буквенным значениям.

Если прописывать
Код
=СУММЕСЛИ(A1:T1;"Я";A2:T2)
, то формула работает. Хотел указать несколько критериев через ИЛИ:
Код
=СУММЕСЛИ(A1:T1;ИЛИ("Я";"Н";"РВ";"С";"ВМ";"ЛЧ";"НС");A2:T2)
, но формула не работает.

Подскажите, пожалуйста, решение
Автор - Taverik
Дата добавления - 27.05.2015 в 11:56
Samaretz Дата: Среда, 27.05.2015, 12:02 | Сообщение № 2
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 223
Репутация: 63 ±
Замечаний: 0% ±

Excel 2010; 2013; 2016
Так надо?
Код
=SUMIF(A1:T1;"Я";A2:T2)+SUMIF(A1:T1;"Н";A2:T2)+SUMIF(A1:T1;"РВ";A2:T2)+SUMIF(A1:T1;"С";A2:T2)+SUMIF(A1:T1;"ВМ";A2:T2)+SUMIF(A1:T1;"ЛЧ";A2:T2)+SUMIF(A1:T1;"НС";A2:T2)
К сообщению приложен файл: 7263303.xls (27.0 Kb)
 
Ответить
СообщениеТак надо?
Код
=SUMIF(A1:T1;"Я";A2:T2)+SUMIF(A1:T1;"Н";A2:T2)+SUMIF(A1:T1;"РВ";A2:T2)+SUMIF(A1:T1;"С";A2:T2)+SUMIF(A1:T1;"ВМ";A2:T2)+SUMIF(A1:T1;"ЛЧ";A2:T2)+SUMIF(A1:T1;"НС";A2:T2)
Автор - Samaretz
Дата добавления - 27.05.2015 в 12:02
Taverik Дата: Среда, 27.05.2015, 12:07 | Сообщение № 3
Группа: Пользователи
Ранг: Новичок
Сообщений: 11
Репутация: 0 ±
Замечаний: 20% ±

Excel 2013
Samaretz, буквенных сокращений много, поэтому думал через ИЛИ сделать.
 
Ответить
СообщениеSamaretz, буквенных сокращений много, поэтому думал через ИЛИ сделать.
Автор - Taverik
Дата добавления - 27.05.2015 в 12:07
Manyasha Дата: Среда, 27.05.2015, 12:18 | Сообщение № 4
Группа: Модераторы
Ранг: Старожил
Сообщений: 2198
Репутация: 902 ±
Замечаний: 0% ±

Excel 2010, 2016
Taverik, можно так (с доп. столбцом):
Код
=СУММ(ЕСЛИ(A1:T1=W1:W7;A2:T2;0))
формула массива, вводить через ctrl+shift+enter.
К сообщению приложен файл: sumif_1.xls (41.5 Kb)

ЯД: 410013299366744 WM: R193491431804
 
Ответить
СообщениеTaverik, можно так (с доп. столбцом):
Код
=СУММ(ЕСЛИ(A1:T1=W1:W7;A2:T2;0))
формула массива, вводить через ctrl+shift+enter.
Автор - Manyasha
Дата добавления - 27.05.2015 в 12:18
SLAVICK Дата: Среда, 27.05.2015, 12:19 | Сообщение № 5
Группа: Модераторы
Ранг: Старожил
Сообщений: 2290
Репутация: 766 ±
Замечаний: 0% ±

2019
Так?
Код
=СУММПРОИЗВ(A2:T2;--НЕ(ЕОШИБКА(ПОИСК(A1:T1;"Я\Н\С\ВМ\ЛЧ\НС";1))))

Разделитель между нужными критериями можно сделать любой.
Можно критерии вынести в диапазон, тогда вместо ПОИСК нужно использовать поискпоз
К сообщению приложен файл: 1975683.xls (26.5 Kb)

Иногда все проще чем кажется с первого взгляда.

Сообщение отредактировал SLAVICK - Среда, 27.05.2015, 12:22
 
Ответить
СообщениеТак?
Код
=СУММПРОИЗВ(A2:T2;--НЕ(ЕОШИБКА(ПОИСК(A1:T1;"Я\Н\С\ВМ\ЛЧ\НС";1))))

Разделитель между нужными критериями можно сделать любой.
Можно критерии вынести в диапазон, тогда вместо ПОИСК нужно использовать поискпоз
Автор - SLAVICK
Дата добавления - 27.05.2015 в 12:19
buchlotnik Дата: Среда, 27.05.2015, 12:20 | Сообщение № 6
Группа: Заблокированные
Ранг: Участник клуба
Сообщений: 3442
Репутация: 929 ±
Замечаний: 20% ±

2010, 2013, 2016 RUS / ENG
можно так (с доп. столбцом)
Код
=СУММ(ЕСЛИ(СЧЁТЕСЛИ(E6:E12;A1:T1)>0;1;0)*(A2:T2))
К сообщению приложен файл: _sumif.xls (27.0 Kb)


Сообщение отредактировал buchlotnik - Среда, 27.05.2015, 12:23
 
Ответить
Сообщениеможно так (с доп. столбцом)
Код
=СУММ(ЕСЛИ(СЧЁТЕСЛИ(E6:E12;A1:T1)>0;1;0)*(A2:T2))
Автор - buchlotnik
Дата добавления - 27.05.2015 в 12:20
_Boroda_ Дата: Среда, 27.05.2015, 12:28 | Сообщение № 7
Группа: Админы
Ранг: Местный житель
Сообщений: 16888
Репутация: 6611 ±
Замечаний: ±

2003; 2007; 2010; 2013 RUS
Так нужно?
Код
=СУММПРОИЗВ(СУММЕСЛИ(A1:T1;{"Я";"Н";"РВ";"С";"ВМ";"ЛЧ";"НС"};A2:T2))

У Вас кусок ИЛИ("Я";"Н";"РВ";"С";"ВМ";"ЛЧ";"НС") немного некорректно написан. Внутри ИЛИ может быть логическое или приравненное к нему значение. А у Вас там текст
К сообщению приложен файл: 0167083.xls (26.5 Kb)

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеТак нужно?
Код
=СУММПРОИЗВ(СУММЕСЛИ(A1:T1;{"Я";"Н";"РВ";"С";"ВМ";"ЛЧ";"НС"};A2:T2))

У Вас кусок ИЛИ("Я";"Н";"РВ";"С";"ВМ";"ЛЧ";"НС") немного некорректно написан. Внутри ИЛИ может быть логическое или приравненное к нему значение. А у Вас там текст
Автор - _Boroda_
Дата добавления - 27.05.2015 в 12:28
gling Дата: Среда, 27.05.2015, 12:33 | Сообщение № 8
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2643
Репутация: 739 ±
Замечаний: 0% ±

2010
Здравствуйте. Можно использовать такую формулу
Код
=СУММПРОИЗВ((A2:T2)*({"Я":"Н":"В":"РВ":"С":"ЛЧ":"НС"}=$A$1:$T$1))
К сообщению приложен файл: 4473448.xls (27.5 Kb)

ЯД-41001506838083
 
Ответить
СообщениеЗдравствуйте. Можно использовать такую формулу
Код
=СУММПРОИЗВ((A2:T2)*({"Я":"Н":"В":"РВ":"С":"ЛЧ":"НС"}=$A$1:$T$1))
Автор - gling
Дата добавления - 27.05.2015 в 12:33
Taverik Дата: Среда, 27.05.2015, 12:58 | Сообщение № 9
Группа: Пользователи
Ранг: Новичок
Сообщений: 11
Репутация: 0 ±
Замечаний: 20% ±

Excel 2013
Manyasha, buchlotnik, спасибо за варианты с доп. столбцом. Понравился вариант Manyasha
SLAVICK, _Boroda_, gling, спасибо за варианты без доп.столбцов. Буду разбираться с новыми для меня функциями)

Спасибо за помощь!
 
Ответить
СообщениеManyasha, buchlotnik, спасибо за варианты с доп. столбцом. Понравился вариант Manyasha
SLAVICK, _Boroda_, gling, спасибо за варианты без доп.столбцов. Буду разбираться с новыми для меня функциями)

Спасибо за помощь!
Автор - Taverik
Дата добавления - 27.05.2015 в 12:58
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Несколько критериев в СУММЕСЛИ (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2025 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!