' Credits to AndreTM, 2015

' Credits to EducatedFool
' Код импортированных функций LoadArrayFromTextFile и SaveTXTfile взят с
' http://excelvba.ru/code/TextFile2Array,' http://excelvba.ru/code/txt

Set FSO = CreateObject("scripting.filesystemobject")
cPath = FSO.GetParentFolderName(WScript.ScriptFullName) & "\"

cPathIn = cPath & ".\In\"
cPathOut = cPath & ".\Out\"
cFileData = "Список.csv"

if not FSO.FileExists(cPath & cFileData) then
     msgbox "Нет файла " & cFileData
     wscript.quit
end if
arr = LoadArrayFromTextFile(cPath & cFileData, 2, ";", vbNewLine)
cLog = "Создание набора файлов" & vbCrLf & Date & " " & Time & " Начало работы" & vbCrLf
counter = 0
for i = 1 to ubound(arr, 1)
     cKod = arr(i, 2)
     cModel = arr(i, 3)
     cFileIn = cModel & ".jpg"
     if not FSO.FileExists(cPathIn & cFileIn) then
         cLog = cLog & "rec. " & i & "  " & cFileIn & " - не найден исходный файл" & vbCrLf
     else
         if len(cKod) = 0 then
             cLog = cLog & "rec. " & i & " - нет кода" & vbCrLf
         else
             cFileOut = cKod & ".jpg"
             FSO.CopyFile (cPathIn & cFileIn), (cPathOut & cFileOut), True
             counter = counter + 1
         end if
     end if
next
cLog = cLog & Date & " " & Time & " Завершено: скопировано " & counter
SaveTXTfile (cPath & cFileData) & ".log", cLog

msgbox "Работа завершена, смотрите файл '" &  cFileData & ".log'"