Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Подсчет значений по двум критериям (данные на двух листах) - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Подсчет значений по двум критериям (данные на двух листах) (Формулы/Formulas)
Подсчет значений по двум критериям (данные на двух листах)
ChuCha Дата: Понедельник, 09.11.2015, 17:14 | Сообщение № 1
Группа: Пользователи
Ранг: Прохожий
Сообщений: 4
Репутация: 0 ±
Замечаний: 0% ±

Excel 2007
Добрый день. Пожалуйста, натолкните на правильное решение.
Есть таблица. В ней столбцы:Книга, количество страниц, ...... Обложка. Есть вторая таблица: обложка, цена.
Необходимо рассчитать стоимость обложки в зависимости от количества страниц. Если меньше 40 - цена обложки на 10% меньше, если больше 60, цена обложки на 10% больше.
На самом деле список огромен, выдернула кусок. Никак индексом ничего не получается сделать.
К сообщению приложен файл: 0625470.xls (21.5 Kb)
 
Ответить
СообщениеДобрый день. Пожалуйста, натолкните на правильное решение.
Есть таблица. В ней столбцы:Книга, количество страниц, ...... Обложка. Есть вторая таблица: обложка, цена.
Необходимо рассчитать стоимость обложки в зависимости от количества страниц. Если меньше 40 - цена обложки на 10% меньше, если больше 60, цена обложки на 10% больше.
На самом деле список огромен, выдернула кусок. Никак индексом ничего не получается сделать.
Автор - ChuCha
Дата добавления - 09.11.2015 в 17:14
buchlotnik Дата: Понедельник, 09.11.2015, 17:25 | Сообщение № 2
Группа: Заблокированные
Ранг: Участник клуба
Сообщений: 3442
Репутация: 929 ±
Замечаний: 20% ±

2010, 2013, 2016 RUS / ENG
так нужно?
Код
=ИНДЕКС(Лист2!$D$7:$D$9;ПОИСКПОЗ(Лист1!H5;Лист2!$C$7:$C$9;0))*ПРОСМОТР(D5;{0;40;61};{0,9;1;1,1})
К сообщению приложен файл: 1629604.xls (27.5 Kb)


Сообщение отредактировал buchlotnik - Понедельник, 09.11.2015, 17:27
 
Ответить
Сообщениетак нужно?
Код
=ИНДЕКС(Лист2!$D$7:$D$9;ПОИСКПОЗ(Лист1!H5;Лист2!$C$7:$C$9;0))*ПРОСМОТР(D5;{0;40;61};{0,9;1;1,1})
Автор - buchlotnik
Дата добавления - 09.11.2015 в 17:25
pabchek Дата: Понедельник, 09.11.2015, 17:25 | Сообщение № 3
Группа: Проверенные
Ранг: Ветеран
Сообщений: 931
Репутация: 218 ±
Замечаний: 0% ±

Excel 2007
Если по быстрому
Код
=ЕСЛИ(D5<40;ВПР(H5;Лист2!$C$7:$D$9;2;0)*0,9;ЕСЛИ(D5>60;ВПР(H5;Лист2!$C$7:$D$9;2;0)*1,1;ВПР(H5;Лист2!$C$7:$D$9;2;0)))

и да, если подумав, модифицируя формулу buchlotnik,
Код
=ВПР(H5;Лист2!$C$7:$D$9;2;0)*ПРОСМОТР(D5;{0;41;61};{0,9;1;1,1})

"Учиться, учиться и еще раз учиться!"
WM: R399923528092

Сообщение отредактировал pabchek - Понедельник, 09.11.2015, 17:29
 
Ответить
СообщениеЕсли по быстрому
Код
=ЕСЛИ(D5<40;ВПР(H5;Лист2!$C$7:$D$9;2;0)*0,9;ЕСЛИ(D5>60;ВПР(H5;Лист2!$C$7:$D$9;2;0)*1,1;ВПР(H5;Лист2!$C$7:$D$9;2;0)))

и да, если подумав, модифицируя формулу buchlotnik,
Код
=ВПР(H5;Лист2!$C$7:$D$9;2;0)*ПРОСМОТР(D5;{0;41;61};{0,9;1;1,1})
Автор - pabchek
Дата добавления - 09.11.2015 в 17:25
YouGreed Дата: Понедельник, 09.11.2015, 17:26 | Сообщение № 4
Группа: Проверенные
Ранг: Ветеран
Сообщений: 589
Репутация: 123 ±
Замечаний: 0% ±

Excel 2010
ChuCha, Попробуйте
Код
=ЕСЛИ($D5>60;ИНДЕКС(Лист2!$D$7:$D$9;ПОИСКПОЗ(Лист1!$H5;Лист2!$C$7:$C$9;);)*1,1;ЕСЛИ(Лист1!D5<40;ИНДЕКС(Лист2!$D$7:$D$9;ПОИСКПОЗ(Лист1!$H5;Лист2!$C$7:$C$9;);)*0,9;ИНДЕКС(Лист2!$D$7:$D$9;ПОИСКПОЗ(Лист1!$H5;Лист2!$C$7:$C$9;);)))
К сообщению приложен файл: 4450337.xls (22.5 Kb)
 
Ответить
СообщениеChuCha, Попробуйте
Код
=ЕСЛИ($D5>60;ИНДЕКС(Лист2!$D$7:$D$9;ПОИСКПОЗ(Лист1!$H5;Лист2!$C$7:$C$9;);)*1,1;ЕСЛИ(Лист1!D5<40;ИНДЕКС(Лист2!$D$7:$D$9;ПОИСКПОЗ(Лист1!$H5;Лист2!$C$7:$C$9;);)*0,9;ИНДЕКС(Лист2!$D$7:$D$9;ПОИСКПОЗ(Лист1!$H5;Лист2!$C$7:$C$9;);)))
Автор - YouGreed
Дата добавления - 09.11.2015 в 17:26
Anton1013 Дата: Понедельник, 09.11.2015, 17:26 | Сообщение № 5
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 203
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
Так?

Код
=ВПР(ПОИСКПОЗ(D5;$N$5:$N$7);$M$5:$O$7;3;0)*ВПР(H5;Лист2!$C$7:$D$9;2;0)


В файле добавил 2 столбца и небольшую табличку с условиями
К сообщению приложен файл: 6906577.xls (28.0 Kb)

Никогда не поздно научиться!

Сообщение отредактировал Anton1013 - Понедельник, 09.11.2015, 17:27
 
Ответить
СообщениеТак?

Код
=ВПР(ПОИСКПОЗ(D5;$N$5:$N$7);$M$5:$O$7;3;0)*ВПР(H5;Лист2!$C$7:$D$9;2;0)


В файле добавил 2 столбца и небольшую табличку с условиями
Автор - Anton1013
Дата добавления - 09.11.2015 в 17:26
SLAVICK Дата: Понедельник, 09.11.2015, 17:28 | Сообщение № 6
Группа: Модераторы
Ранг: Старожил
Сообщений: 2290
Репутация: 766 ±
Замечаний: 0% ±

2019
Код
=ВПР(H5;Лист2!$C$6:$D$9;2;0)*ПРОСМОТР(D5;{0;40;60};{0,9;1;1,1})
К сообщению приложен файл: 7074250.xls (27.0 Kb)

Иногда все проще чем кажется с первого взгляда.
 
Ответить
Сообщение
Код
=ВПР(H5;Лист2!$C$6:$D$9;2;0)*ПРОСМОТР(D5;{0;40;60};{0,9;1;1,1})
Автор - SLAVICK
Дата добавления - 09.11.2015 в 17:28
_Boroda_ Дата: Понедельник, 09.11.2015, 19:12 | Сообщение № 7
Группа: Модераторы
Ранг: Местный житель
Сообщений: 16675
Репутация: 6481 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
И мой любимый ТЕКСТ
Код
=ВПР(H5;Лист2!C$6:D$9;2;)*ТЕКСТ(D5;"[<40]\,9;[>60]1\,1;1")
К сообщению приложен файл: 0625470_1.xls (31.0 Kb)

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеИ мой любимый ТЕКСТ
Код
=ВПР(H5;Лист2!C$6:D$9;2;)*ТЕКСТ(D5;"[<40]\,9;[>60]1\,1;1")
Автор - _Boroda_
Дата добавления - 09.11.2015 в 19:12
ChuCha Дата: Понедельник, 09.11.2015, 19:42 | Сообщение № 8
Группа: Пользователи
Ранг: Прохожий
Сообщений: 4
Репутация: 0 ±
Замечаний: 0% ±

Excel 2007
Спасибо всем огромное!!!!! Попробовала разными способами и взяла их на заметку!
 
Ответить
СообщениеСпасибо всем огромное!!!!! Попробовала разными способами и взяла их на заметку!
Автор - ChuCha
Дата добавления - 09.11.2015 в 19:42
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Подсчет значений по двум критериям (данные на двух листах) (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!