Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Выборка по контрагентам: формула - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Выборка по контрагентам: формула (Формулы/Formulas)
Выборка по контрагентам: формула
ShellarK Дата: Понедельник, 07.12.2015, 10:02 | Сообщение № 1
Группа: Пользователи
Ранг: Новичок
Сообщений: 10
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
Добрый день! Помогите, пожалуйста, составить формулу в рамках задания:

В Таблице №1 приведен список документов по трем Контрагентам (используется сортировка по номеру документа). В первых строках таблиц № 2 и 3 необходимо написать формулы, при копировании которых в остальные строки таблиц, произойдет заполнение их документами по Контрагентам 1 и 2 из таблицы №1. При использовании формулы, Таблицы №2 и 3 должны заполниться документами последовательно и без пробелов между документами. Результат должен выглядеть как в Таблице №4 (заполнена для примера без формул)
К сообщению приложен файл: _Excel3.xlsx (10.3 Kb)
 
Ответить
СообщениеДобрый день! Помогите, пожалуйста, составить формулу в рамках задания:

В Таблице №1 приведен список документов по трем Контрагентам (используется сортировка по номеру документа). В первых строках таблиц № 2 и 3 необходимо написать формулы, при копировании которых в остальные строки таблиц, произойдет заполнение их документами по Контрагентам 1 и 2 из таблицы №1. При использовании формулы, Таблицы №2 и 3 должны заполниться документами последовательно и без пробелов между документами. Результат должен выглядеть как в Таблице №4 (заполнена для примера без формул)
Автор - ShellarK
Дата добавления - 07.12.2015 в 10:02
Pelena Дата: Понедельник, 07.12.2015, 10:20 | Сообщение № 2
Группа: Админы
Ранг: Местный житель
Сообщений: 19188
Репутация: 4421 ±
Замечаний: ±

Excel 365 & Mac Excel
Здравствуйте.
Так подойдёт? Формула массива
Код
=ЕСЛИОШИБКА(ИНДЕКС($B$5:$E$14;НАИМЕНЬШИЙ(ЕСЛИ($D$5:$D$14=$G$3;СТРОКА($B$5:$B$14)-4);СТРОКА(1:1));ПОИСКПОЗ(G$4;$B$4:$E$4;0));"")
К сообщению приложен файл: 9313707.xlsx (12.1 Kb)

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
СообщениеЗдравствуйте.
Так подойдёт? Формула массива
Код
=ЕСЛИОШИБКА(ИНДЕКС($B$5:$E$14;НАИМЕНЬШИЙ(ЕСЛИ($D$5:$D$14=$G$3;СТРОКА($B$5:$B$14)-4);СТРОКА(1:1));ПОИСКПОЗ(G$4;$B$4:$E$4;0));"")
Автор - Pelena
Дата добавления - 07.12.2015 в 10:20
pabchek Дата: Понедельник, 07.12.2015, 10:41 | Сообщение № 3
Группа: Проверенные
Ранг: Ветеран
Сообщений: 931
Репутация: 218 ±
Замечаний: 0% ±

Excel 2007
мой вариант с разными формулами для столбцов
(первый столбец
Код
=ЕСЛИОШИБКА(1/НАИБОЛЬШИЙ(ЕСЛИОШИБКА(1/(($D$5:$D$14=G$3)*СТРОКА(A$1:A$10));0);СТРОКА(A1));"")

второй и третий
Код
=ЕСЛИОШИБКА(ВПР(G5;$B$5:$E$14;2;0);"")
К сообщению приложен файл: 6471104.xlsx (11.6 Kb)

"Учиться, учиться и еще раз учиться!"
WM: R399923528092

Сообщение отредактировал pabchek - Понедельник, 07.12.2015, 10:44
 
Ответить
Сообщениемой вариант с разными формулами для столбцов
(первый столбец
Код
=ЕСЛИОШИБКА(1/НАИБОЛЬШИЙ(ЕСЛИОШИБКА(1/(($D$5:$D$14=G$3)*СТРОКА(A$1:A$10));0);СТРОКА(A1));"")

второй и третий
Код
=ЕСЛИОШИБКА(ВПР(G5;$B$5:$E$14;2;0);"")
Автор - pabchek
Дата добавления - 07.12.2015 в 10:41
AlexM Дата: Понедельник, 07.12.2015, 10:46 | Сообщение № 4
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4502
Репутация: 1117 ±
Замечаний: 0% ±

Excel 2003
И мой вариант. Адаптирован под Excel 2003
Формула для номеров
Код
=ЕСЛИ(СЧЁТЕСЛИ($D$5:$D$99;G$3)<СТРОКА(A1);"";ИНДЕКС($B$5:$B$99;НАИМЕНЬШИЙ(ЕСЛИ($D$5:$D$99=G$3;$B$5:$B$99);СТРОКА(A1))))
или
Код
=ЕСЛИ(СЧЁТЕСЛИ($D$5:$D$99;G$3)<СТРОКА(A1);"";НАИМЕНЬШИЙ(ЕСЛИ($D$5:$D$99=G$3;$B$5:$B$99);СТРОКА(A1)))
и для даты
Код
=ЕСЛИ(G5<>"";ИНДЕКС($C$5:$C$99;НАИМЕНЬШИЙ(ЕСЛИ($D$5:$D$99=G$3;$B$5:$B$99);СТРОКА(A1)));"")

PS. А об ВПР() не вспомнил. :-)
К сообщению приложен файл: _Excel3.xls (39.5 Kb)


Номер мобильного модема (без голосовой связи)
9269171249 МегаФон, Московский регион.

Сообщение отредактировал AlexM - Понедельник, 07.12.2015, 11:48
 
Ответить
СообщениеИ мой вариант. Адаптирован под Excel 2003
Формула для номеров
Код
=ЕСЛИ(СЧЁТЕСЛИ($D$5:$D$99;G$3)<СТРОКА(A1);"";ИНДЕКС($B$5:$B$99;НАИМЕНЬШИЙ(ЕСЛИ($D$5:$D$99=G$3;$B$5:$B$99);СТРОКА(A1))))
или
Код
=ЕСЛИ(СЧЁТЕСЛИ($D$5:$D$99;G$3)<СТРОКА(A1);"";НАИМЕНЬШИЙ(ЕСЛИ($D$5:$D$99=G$3;$B$5:$B$99);СТРОКА(A1)))
и для даты
Код
=ЕСЛИ(G5<>"";ИНДЕКС($C$5:$C$99;НАИМЕНЬШИЙ(ЕСЛИ($D$5:$D$99=G$3;$B$5:$B$99);СТРОКА(A1)));"")

PS. А об ВПР() не вспомнил. :-)
Автор - AlexM
Дата добавления - 07.12.2015 в 10:46
ShellarK Дата: Понедельник, 07.12.2015, 11:29 | Сообщение № 5
Группа: Пользователи
Ранг: Новичок
Сообщений: 10
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
pabchek, спасибо огромное! hands
 
Ответить
Сообщениеpabchek, спасибо огромное! hands
Автор - ShellarK
Дата добавления - 07.12.2015 в 11:29
ShellarK Дата: Понедельник, 07.12.2015, 11:29 | Сообщение № 6
Группа: Пользователи
Ранг: Новичок
Сообщений: 10
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
AlexM, спасибо за помощь! hands
 
Ответить
СообщениеAlexM, спасибо за помощь! hands
Автор - ShellarK
Дата добавления - 07.12.2015 в 11:29
AlexM Дата: Понедельник, 07.12.2015, 12:15 | Сообщение № 7
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4502
Репутация: 1117 ±
Замечаний: 0% ±

Excel 2003
Еще вариант, вдруг пригодится. Использованы идеи Виктора (pabchek)
Для столбца № применен формат ячеек тип 0;;
Массивная формула для номера
Код
=1/НАИБОЛЬШИЙ(1/ЕСЛИ($D$5:$D$99=G$3;$B$5:$B$99;-1);СТРОКА(A1))
обычная для даты
Код
=ЕСЛИ(G5>0;ВПР(G5;$B$5:$E$99;2;);"")
К сообщению приложен файл: _Excel3_4.xls (32.0 Kb)


Номер мобильного модема (без голосовой связи)
9269171249 МегаФон, Московский регион.
 
Ответить
СообщениеЕще вариант, вдруг пригодится. Использованы идеи Виктора (pabchek)
Для столбца № применен формат ячеек тип 0;;
Массивная формула для номера
Код
=1/НАИБОЛЬШИЙ(1/ЕСЛИ($D$5:$D$99=G$3;$B$5:$B$99;-1);СТРОКА(A1))
обычная для даты
Код
=ЕСЛИ(G5>0;ВПР(G5;$B$5:$E$99;2;);"")
Автор - AlexM
Дата добавления - 07.12.2015 в 12:15
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Выборка по контрагентам: формула (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!