перенос значений из одной страницы в другую

Страница 1 из 1 1
Модератор форума: китин, _Boroda_, DrMini

перенос значений из одной страницы в другую (Формулы/Formulas)

alexzg

Дата: Среда, 20.04.2016, 17:43 | Сообщение № 1

Группа: Пользователи

Ранг: Прохожий

Сообщений: 9

Репутация: 0 ±

Замечаний: 0% ±

Excel 2013

Дорогие друзья, помогайте "Старому".
Есть таблица с двумя листами. Первый лист База Данных, в которую каждый месяц заносятся определенные показания.
Второй лист некая таблица, в которую при помощи ВПР подставляются данные из первого листа, причем на первом листе в горизонтальной строке достаточно проставить определенный символ, в данном случае "Х".
Если есть возможность оказать помощь, буду признателен.

К сообщению приложен файл: 1135052.xlsx (9.9 Kb)

Ответить

pabchek

Дата: Среда, 20.04.2016, 17:53 | Сообщение № 2

Группа: Проверенные

Ранг: Ветеран

Сообщений: 931

Репутация: 218 ±

Замечаний: 0% ±

Excel 2007

Здравствуйте. Вариант (формула массива)

Код

=ИНДЕКС(БазаДанных!$C$3:$M$10;СТРОКА(A1);ПОИСКПОЗ(1;--(БазаДанных!C$1:M$1<>0);0))

Код

=ИНДЕКС(БазаДанных!$C$3:$M$10;СТРОКА(A1);ПОИСКПОЗ(1;--ЕОШ(1-БазаДанных!$C$1:$M$1);0))

если знак определен, то можно

Код

=ГПР("х";БазаДанных!$C$1:$M$10;СТРОКА(A3))

"Учиться, учиться и еще раз учиться!"
WM: R399923528092

Сообщение отредактировал pabchek - Среда, 20.04.2016, 18:01

Ответить

buchlotnik

Дата: Среда, 20.04.2016, 17:53 | Сообщение № 3

Группа: Заблокированные

Ранг: Участник клуба

Сообщений: 3442

Репутация: 929 ±

Замечаний: 20% ±

2010, 2013, 2016 RUS / ENG

так нужно? (массивка сразу на столбец)

Код

=ИНДЕКС(БазаДанных!C3:M10;;ПОИСКПОЗ("х";БазаДанных!C1:M1;0))

(нули форматом убрал)

К сообщению приложен файл: 2402284.xlsx (10.0 Kb)

Сообщение отредактировал buchlotnik - Среда, 20.04.2016, 17:54

Ответить

Manyasha

Дата: Среда, 20.04.2016, 17:55 | Сообщение № 4

Группа: Модераторы

Ранг: Старожил

Сообщений: 2198

Репутация: 902 ±

Замечаний: 0% ±

Excel 2010, 2016

и еще вариант:

Код

=ВПР(B4;БазаДанных!$B$2:$M$100;ПОИСКПОЗ("х";БазаДанных!$B$1:$M$1;0);0)

ЯД: 410013299366744 WM: R193491431804

Ответить

_Boroda_

Дата: Среда, 20.04.2016, 18:02 | Сообщение № 5

Группа: Админы

Ранг: Местный житель

Сообщений: 16911

Репутация: 6616 ±

Замечаний: ±

2003; 2007; 2010; 2013 RUS

И еще (почти как у Михаила, только немассивка и без ;)

Код

=ИНДЕКС(БазаДанных!C3:M3;ПОИСКПОЗ("х";БазаДанных!C$1:M$1;))

Если только числовые значения, то вот такой еще варианты

Код

=СУММПРОИЗВ(БазаДанных!D3:M3*(БазаДанных!D$1:M$1="х"))

Код

=СУММЕСЛИ(БазаДанных!D$1:M$1;"х";БазаДанных!D3:M3)

Добавлено на мотивы формулы Виктора из поста ниже

Код

=ПРОСМОТР(;-ПОИСК(;БазаДанных!C$1:M$1);БазаДанных!C3:M3)

К сообщению приложен файл: 1135052_2.xlsx (10.5 Kb)

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995