Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Динамическая формула ТЕНДЕНЦИЯ на массив данных - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Динамическая формула ТЕНДЕНЦИЯ на массив данных
Динамическая формула ТЕНДЕНЦИЯ на массив данных
DJ_Marker_MC Дата: Вторник, 09.10.2012, 16:38 | Сообщение № 1
Группа: Друзья
Ранг: Ветеран
Сообщений: 991
Репутация: 213 ±
Замечаний: 0% ±

Excel 2019
Всем привет. Ребята, мне нужно как то сделать динамический диапазон в формуле массива.
В прикреплённой таблице интересует строка 18, там указана формула массива, точнее 2 формулы, первая по столбик AL
Code
{=ТЕНДЕНЦИЯ(F6:AL6;$F$2:$AL$2)}


вторая со столбика AM
Code
{=ТЕНДЕНЦИЯ(F6:AL6;$F$2:$AL$2;$AM$2:$BA$2)}


мне нужно сделать как то так, чтоб если я поставлю данные в AM6, то первая формула превратилась в
Code
{=ТЕНДЕНЦИЯ(F6:AM6;$F$2:$AM$2)}


а вторая в:
Code
{=ТЕНДЕНЦИЯ(F6:AM6;$F$2:$AM$2;$AN$2:$BA$2)}


тоесть, чтоб произошло смещение по всей строке вправо, но чтоб в ячейке AM18 уже стала не вторая формула, а первая.

Надеюсь кто то поможет с этим.
К сообщению приложен файл: _1.xlsx (24.9 Kb)


Сообщение отредактировал marker_mc - Вторник, 09.10.2012, 16:39
 
Ответить
СообщениеВсем привет. Ребята, мне нужно как то сделать динамический диапазон в формуле массива.
В прикреплённой таблице интересует строка 18, там указана формула массива, точнее 2 формулы, первая по столбик AL
Code
{=ТЕНДЕНЦИЯ(F6:AL6;$F$2:$AL$2)}


вторая со столбика AM
Code
{=ТЕНДЕНЦИЯ(F6:AL6;$F$2:$AL$2;$AM$2:$BA$2)}


мне нужно сделать как то так, чтоб если я поставлю данные в AM6, то первая формула превратилась в
Code
{=ТЕНДЕНЦИЯ(F6:AM6;$F$2:$AM$2)}


а вторая в:
Code
{=ТЕНДЕНЦИЯ(F6:AM6;$F$2:$AM$2;$AN$2:$BA$2)}


тоесть, чтоб произошло смещение по всей строке вправо, но чтоб в ячейке AM18 уже стала не вторая формула, а первая.

Надеюсь кто то поможет с этим.
Автор - DJ_Marker_MC
Дата добавления - 09.10.2012 в 16:38
Gustav Дата: Вторник, 09.10.2012, 18:38 | Сообщение № 2
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2748
Репутация: 1137 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
Для начала можно разрушить массив в F18:AL18 и вместо него ввести туда немассивные формулы, начиная с такой в F18:

[vba]
Code
=ИНДЕКС(ТЕНДЕНЦИЯ(
СМЕЩ($F$6;;;1;СЧЁТ($F$6:$BA$6));
СМЕЩ($F$2;;;1;СЧЁТ($F$6:$BA$6))
); СТОЛБЕЦ()-СТОЛБЕЦ($E:$E))
[/vba]
Дальше сопровождать Вас или общее направление уже понятно?

P.S. Полный формулоид на довольно скорую руку примерно такой (оптимизация Сообществом приветствуется!):

[vba]
Code
=ЕСЛИ(ЕПУСТО(F6)
;
ИНДЕКС(ТЕНДЕНЦИЯ(
СМЕЩ($F$6;;;1;СЧЁТ($F$6:$BA$6));
СМЕЩ($F$2;;;1;СЧЁТ($F$6:$BA$6));
СМЕЩ($BA$2;0;-(СТОЛБЕЦ($BA:$BA)-СТОЛБЕЦ($E:$E)-СЧЁТ($F$6:$BA$6)-1);1;СТОЛБЕЦ($BA:$BA)-СТОЛБЕЦ($E:$E)-СЧЁТ($F$6:$BA$6))
); СТОЛБЕЦ()-СЧЁТ($F$6:$BA$6)-СТОЛБЕЦ($E:$E))
;
ИНДЕКС(ТЕНДЕНЦИЯ(
СМЕЩ($F$6;;;1;СЧЁТ($F$6:$BA$6));
СМЕЩ($F$2;;;1;СЧЁТ($F$6:$BA$6))
); СТОЛБЕЦ()-СТОЛБЕЦ($E:$E))
)
[/vba]
Для F18 и дальше тянем до BA18, предварительно удалив массив в M18:BA18.

МОИ: Ник, Tip box: 41001663842605

Сообщение отредактировал Gustav - Вторник, 09.10.2012, 19:31
 
Ответить
СообщениеДля начала можно разрушить массив в F18:AL18 и вместо него ввести туда немассивные формулы, начиная с такой в F18:

[vba]
Code
=ИНДЕКС(ТЕНДЕНЦИЯ(
СМЕЩ($F$6;;;1;СЧЁТ($F$6:$BA$6));
СМЕЩ($F$2;;;1;СЧЁТ($F$6:$BA$6))
); СТОЛБЕЦ()-СТОЛБЕЦ($E:$E))
[/vba]
Дальше сопровождать Вас или общее направление уже понятно?

P.S. Полный формулоид на довольно скорую руку примерно такой (оптимизация Сообществом приветствуется!):

[vba]
Code
=ЕСЛИ(ЕПУСТО(F6)
;
ИНДЕКС(ТЕНДЕНЦИЯ(
СМЕЩ($F$6;;;1;СЧЁТ($F$6:$BA$6));
СМЕЩ($F$2;;;1;СЧЁТ($F$6:$BA$6));
СМЕЩ($BA$2;0;-(СТОЛБЕЦ($BA:$BA)-СТОЛБЕЦ($E:$E)-СЧЁТ($F$6:$BA$6)-1);1;СТОЛБЕЦ($BA:$BA)-СТОЛБЕЦ($E:$E)-СЧЁТ($F$6:$BA$6))
); СТОЛБЕЦ()-СЧЁТ($F$6:$BA$6)-СТОЛБЕЦ($E:$E))
;
ИНДЕКС(ТЕНДЕНЦИЯ(
СМЕЩ($F$6;;;1;СЧЁТ($F$6:$BA$6));
СМЕЩ($F$2;;;1;СЧЁТ($F$6:$BA$6))
); СТОЛБЕЦ()-СТОЛБЕЦ($E:$E))
)
[/vba]
Для F18 и дальше тянем до BA18, предварительно удалив массив в M18:BA18.
Автор - Gustav
Дата добавления - 09.10.2012 в 18:38
DJ_Marker_MC Дата: Вторник, 09.10.2012, 19:31 | Сообщение № 3
Группа: Друзья
Ранг: Ветеран
Сообщений: 991
Репутация: 213 ±
Замечаний: 0% ±

Excel 2019
спасибо за ответ, я идею примерно понял, завтра уже с нового рабочего дня попробую рассмотреть это более подробно. Я просто не понимал как можно обойтись без массива, если это и правда заработает так же как массив и даст те же результат, то буду колупать далее. Но мне нужно как то без ручного фактора
я про:
Для F18 и дальше тянем до BA18, предварительно удалив массив в M18:BA18.


Сообщение отредактировал marker_mc - Вторник, 09.10.2012, 19:33
 
Ответить
Сообщениеспасибо за ответ, я идею примерно понял, завтра уже с нового рабочего дня попробую рассмотреть это более подробно. Я просто не понимал как можно обойтись без массива, если это и правда заработает так же как массив и даст те же результат, то буду колупать далее. Но мне нужно как то без ручного фактора
я про:
Для F18 и дальше тянем до BA18, предварительно удалив массив в M18:BA18.
Автор - DJ_Marker_MC
Дата добавления - 09.10.2012 в 19:31
Gustav Дата: Вторник, 09.10.2012, 19:42 | Сообщение № 4
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2748
Репутация: 1137 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
Quote (marker_mc)
Но мне нужно как то без ручного фактора я про: Для F18 и дальше тянем до BA18, предварительно удалив массив в M18:BA18.

???
Ввести один раз формулу в F18 и потом скопировать F18 в F18:BA18 - проблема?? Не очень понимаю, что ж тогда надо...

P.S. Прикладываю файл для сравнительного анализа.
К сообщению приложен файл: marker_mc_03.xlsx (26.0 Kb)

МОИ: Ник, Tip box: 41001663842605

Сообщение отредактировал Gustav - Вторник, 09.10.2012, 20:02
 
Ответить
Сообщение
Quote (marker_mc)
Но мне нужно как то без ручного фактора я про: Для F18 и дальше тянем до BA18, предварительно удалив массив в M18:BA18.

???
Ввести один раз формулу в F18 и потом скопировать F18 в F18:BA18 - проблема?? Не очень понимаю, что ж тогда надо...

P.S. Прикладываю файл для сравнительного анализа.
Автор - Gustav
Дата добавления - 09.10.2012 в 19:42
vikttur Дата: Вторник, 09.10.2012, 19:51 | Сообщение № 5
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2941
Репутация: 526 ±
Замечаний: 0% ±

Quote (Gustav)
оптимизация Сообществом приветствуется!

предупреждаю - не вникал.
Я бы заменил летучую СМЕЩ() на ИНДЕКС()

Quote (Gustav)
-(СТОЛБЕЦ($BA:$BA)-СТОЛБЕЦ($E:$E)

Если столбцы закреплены, почему не записать константой?
 
Ответить
Сообщение
Quote (Gustav)
оптимизация Сообществом приветствуется!

предупреждаю - не вникал.
Я бы заменил летучую СМЕЩ() на ИНДЕКС()

Quote (Gustav)
-(СТОЛБЕЦ($BA:$BA)-СТОЛБЕЦ($E:$E)

Если столбцы закреплены, почему не записать константой?
Автор - vikttur
Дата добавления - 09.10.2012 в 19:51
DJ_Marker_MC Дата: Вторник, 09.10.2012, 23:31 | Сообщение № 6
Группа: Друзья
Ранг: Ветеран
Сообщений: 991
Репутация: 213 ±
Замечаний: 0% ±

Excel 2019
Gustav, прошу прощение, я просто написал без проверки Вашей формулы, так как уже уходил с работы. Сейчас проверил и всё реально правильно раотает, и при перестроении в моё файле массива, тоесть смещение вправо обох массивов, результат выходит тот же что и по Вашей формуле... Другими словами вё работает))) но какое оно большоеееее.... в сравнеии с формулой массива "тенденция".
 
Ответить
СообщениеGustav, прошу прощение, я просто написал без проверки Вашей формулы, так как уже уходил с работы. Сейчас проверил и всё реально правильно раотает, и при перестроении в моё файле массива, тоесть смещение вправо обох массивов, результат выходит тот же что и по Вашей формуле... Другими словами вё работает))) но какое оно большоеееее.... в сравнеии с формулой массива "тенденция".
Автор - DJ_Marker_MC
Дата добавления - 09.10.2012 в 23:31
Gustav Дата: Среда, 10.10.2012, 01:19 | Сообщение № 7
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2748
Репутация: 1137 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
Quote (marker_mc)
но какое оно большоеееее.... в сравнеии с формулой массива "тенденция"

Вы будете смеяться, но я прилично подсократился - оказывается, нужно было просто сесть и подумать. Вот единая формула МАССИВА для F18:BA18:
[vba]
Code
=ТЕНДЕНЦИЯ(
СМЕЩ($F$6;;;1;СЧЁТ($F$6:$BA$6));
СМЕЩ($F$2;;;1;СЧЁТ($F$6:$BA$6));
$F$2:$BA$2)
[/vba]

Quote (vikttur)
Я бы заменил летучую СМЕЩ() на ИНДЕКС()

Или с учетом замечания vikttur'а - тоже массивная:
[vba]
Code
=ТЕНДЕНЦИЯ(
$F$6:ИНДЕКС($F$6:$BA$6;СЧЁТ($F$6:$BA$6));
$F$2:ИНДЕКС($F$2:$BA$2;СЧЁТ($F$6:$BA$6));
$F$2:$BA$2)
[/vba]

МОИ: Ник, Tip box: 41001663842605

Сообщение отредактировал Gustav - Среда, 10.10.2012, 01:29
 
Ответить
Сообщение
Quote (marker_mc)
но какое оно большоеееее.... в сравнеии с формулой массива "тенденция"

Вы будете смеяться, но я прилично подсократился - оказывается, нужно было просто сесть и подумать. Вот единая формула МАССИВА для F18:BA18:
[vba]
Code
=ТЕНДЕНЦИЯ(
СМЕЩ($F$6;;;1;СЧЁТ($F$6:$BA$6));
СМЕЩ($F$2;;;1;СЧЁТ($F$6:$BA$6));
$F$2:$BA$2)
[/vba]

Quote (vikttur)
Я бы заменил летучую СМЕЩ() на ИНДЕКС()

Или с учетом замечания vikttur'а - тоже массивная:
[vba]
Code
=ТЕНДЕНЦИЯ(
$F$6:ИНДЕКС($F$6:$BA$6;СЧЁТ($F$6:$BA$6));
$F$2:ИНДЕКС($F$2:$BA$2;СЧЁТ($F$6:$BA$6));
$F$2:$BA$2)
[/vba]
Автор - Gustav
Дата добавления - 10.10.2012 в 01:19
DJ_Marker_MC Дата: Среда, 10.10.2012, 10:20 | Сообщение № 8
Группа: Друзья
Ранг: Ветеран
Сообщений: 991
Репутация: 213 ±
Замечаний: 0% ±

Excel 2019
Ребята, большое спасибо... только начинаю осваивать прогнозирование (точнее в принудительном порядке)))) раньше занимался только отчетностью продаж, теперь привязали еще к закупке)))) так что думаю еще много что буду спрашивать так как с прогнозами дела никогда не имел.
vikttur, Gustav спасибо за помощь.
 
Ответить
СообщениеРебята, большое спасибо... только начинаю осваивать прогнозирование (точнее в принудительном порядке)))) раньше занимался только отчетностью продаж, теперь привязали еще к закупке)))) так что думаю еще много что буду спрашивать так как с прогнозами дела никогда не имел.
vikttur, Gustav спасибо за помощь.
Автор - DJ_Marker_MC
Дата добавления - 10.10.2012 в 10:20
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Динамическая формула ТЕНДЕНЦИЯ на массив данных
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!