Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Изменение окончания слова в зависимости от цифр - Мир MS Excel

Регистрация · Логин: · Пароль: · · Забыли пароль?
Страница 1 из 11
Модератор форума: _Boroda_, Pelena, Manyasha, SLAVICK 
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Изменение окончания слова в зависимости от цифр (Формулы/Formulas)
Изменение окончания слова в зависимости от цифр
TermiTe Дата: Вторник, 01.08.2017, 23:11 | Сообщение № 1
Группа: Пользователи
Ранг: Прохожий
Сообщений: 3
Репутация: 0 ±
Замечаний: 0% ±

Excel 2007
Приветствую. Подскажите как хитро можно изменить окончание слова в зависимости от получаемых цифр? Формула высчитывает сумму, к получаемой сумме добавляется слово "штук", в зависимости от получаемого количества необходимо верно указать окончание слова (0 штук, 1 штука, 2 штуки, 3 штуки, 4 штуки, 5-9 штук), при это определять надо по последней цифре, т.к. значение может получится любое, хоть несколько тысяч. Пример в файле. Надеюсь на помощь, ибо внутренний перфекционист страдает.
К сообщению приложен файл: 0395892.rar(56Kb)


Сообщение отредактировал TermiTe - Среда, 02.08.2017, 22:30
 
Ответить
СообщениеПриветствую. Подскажите как хитро можно изменить окончание слова в зависимости от получаемых цифр? Формула высчитывает сумму, к получаемой сумме добавляется слово "штук", в зависимости от получаемого количества необходимо верно указать окончание слова (0 штук, 1 штука, 2 штуки, 3 штуки, 4 штуки, 5-9 штук), при это определять надо по последней цифре, т.к. значение может получится любое, хоть несколько тысяч. Пример в файле. Надеюсь на помощь, ибо внутренний перфекционист страдает.

Автор - TermiTe
Дата добавления - 01.08.2017 в 23:11
ZORRO2005 Дата: Среда, 02.08.2017, 00:59 | Сообщение № 2
Группа: Друзья
Ранг: Обитатель
Сообщений: 380
Репутация: 146 ±
Замечаний: 0% ±

Excel2010
Код
=СЦЕПИТЬ("Всего ранее выдано ";СУММ(C3:C4);" штук"&ВПР(--ПРАВСИМВ(СУММ(C3:C4);1);{0;"":0,1;"а":1,1;"и":4,1;""};2))

или
Код
=СЦЕПИТЬ("Всего ранее выдано ";СУММ(C3:C4);" штук"&ПСТР("аиии";ЕСЛИ(ОСТАТ(СУММ(C3:C4);10);ОСТАТ(СУММ(C3:C4);10);9);1))


Сообщение отредактировал ZORRO2005 - Среда, 02.08.2017, 01:19
 
Ответить
Сообщение
Код
=СЦЕПИТЬ("Всего ранее выдано ";СУММ(C3:C4);" штук"&ВПР(--ПРАВСИМВ(СУММ(C3:C4);1);{0;"":0,1;"а":1,1;"и":4,1;""};2))

или
Код
=СЦЕПИТЬ("Всего ранее выдано ";СУММ(C3:C4);" штук"&ПСТР("аиии";ЕСЛИ(ОСТАТ(СУММ(C3:C4);10);ОСТАТ(СУММ(C3:C4);10);9);1))

Автор - ZORRO2005
Дата добавления - 02.08.2017 в 00:59
buchlotnik Дата: Среда, 02.08.2017, 02:07 | Сообщение № 3
Группа: Друзья
Ранг: Участник клуба
Сообщений: 3120
Репутация: 854 ±
Замечаний: 0% ±

2010, 2013, 2016 RUS / ENG
Вариант:
Код
="Всего ранее выдано "&СУММ(C3:C4)&" штук"&ЕСЛИ(--ПРАВБ(СУММ(C3:C4);2)<20;ПРОСМОТР(--ПРАВБ(СУММ(C3:C4);2);{0;1;2;5};{" ";"а";"и";" "});ПРОСМОТР(--ПРАВБ(СУММ(C3:C4));{0;1;2;5};{" ";"а";"и";" "}))
TermiTe, ZORRO2005, а как же значения до 20? (11 ведь "штук", а не "штука" - не?)
К сообщению приложен файл: 1074808.xlsb(68Kb)


каждому For - Next!
платная помощь:
ЯД: 410012595572239
buchlotnik@mail.ru


Сообщение отредактировал buchlotnik - Среда, 02.08.2017, 02:20
 
Ответить
СообщениеВариант:
Код
="Всего ранее выдано "&СУММ(C3:C4)&" штук"&ЕСЛИ(--ПРАВБ(СУММ(C3:C4);2)<20;ПРОСМОТР(--ПРАВБ(СУММ(C3:C4);2);{0;1;2;5};{" ";"а";"и";" "});ПРОСМОТР(--ПРАВБ(СУММ(C3:C4));{0;1;2;5};{" ";"а";"и";" "}))
TermiTe, ZORRO2005, а как же значения до 20? (11 ведь "штук", а не "штука" - не?)

Автор - buchlotnik
Дата добавления - 02.08.2017 в 02:07
Nic70y Дата: Среда, 02.08.2017, 08:04 | Сообщение № 4
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4126
Репутация: 882 ±
Замечаний: 0% ±

Excel 2013
еще, для разнообразия
Код
="Всего ранее выдано "&СУММ(C3:C4)&" штук"&ПРОСМОТР(((ОСТАТ(СУММ(C3:C4);100)<10)+(ОСТАТ(СУММ(C3:C4);100)>20))*ОСТАТ(СУММ(C3:C4);10);{0;1;2;5};{"";"а";"и";""})


ЯД(poison) 41001841029809
+7 978 049 98 74 (мтс)
 
Ответить
Сообщениееще, для разнообразия
Код
="Всего ранее выдано "&СУММ(C3:C4)&" штук"&ПРОСМОТР(((ОСТАТ(СУММ(C3:C4);100)<10)+(ОСТАТ(СУММ(C3:C4);100)>20))*ОСТАТ(СУММ(C3:C4);10);{0;1;2;5};{"";"а";"и";""})

Автор - Nic70y
Дата добавления - 02.08.2017 в 08:04
_Boroda_ Дата: Среда, 02.08.2017, 11:42 | Сообщение № 5
Группа: Модераторы
Ранг: Местный житель
Сообщений: 11547
Репутация: 4754 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Еще вариант, взять из откуда-то
Код
="Всего ранее выдано "&СУММ(C3:C4)&" штук"&ВПР(ОСТАТ(МАКС(ОСТАТ(ПРАВБ(СУММ(C3:C4);2)-11;100);9);10);{0;"а":1;"и":4;""};2)

*взял
К сообщению приложен файл: 1074808_1.xlsb(68Kb)


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995


Сообщение отредактировал _Boroda_ - Среда, 02.08.2017, 23:19
 
Ответить
СообщениеЕще вариант, взять из откуда-то
Код
="Всего ранее выдано "&СУММ(C3:C4)&" штук"&ВПР(ОСТАТ(МАКС(ОСТАТ(ПРАВБ(СУММ(C3:C4);2)-11;100);9);10);{0;"а":1;"и":4;""};2)

*взял

Автор - _Boroda_
Дата добавления - 02.08.2017 в 11:42
TermiTe Дата: Среда, 02.08.2017, 21:50 | Сообщение № 6
Группа: Пользователи
Ранг: Прохожий
Сообщений: 3
Репутация: 0 ±
Замечаний: 0% ±

Excel 2007
TermiTe, ZORRO2005, а как же значения до 20? (11 ведь "штук", а не "штука" - не?)

действительно, спасибо за замечание hands
 
Ответить
Сообщение
TermiTe, ZORRO2005, а как же значения до 20? (11 ведь "штук", а не "штука" - не?)

действительно, спасибо за замечание hands

Автор - TermiTe
Дата добавления - 02.08.2017 в 21:50
TermiTe Дата: Среда, 02.08.2017, 22:08 | Сообщение № 7
Группа: Пользователи
Ранг: Прохожий
Сообщений: 3
Репутация: 0 ±
Замечаний: 0% ±

Excel 2007
ZORRO2005, спасибо, но я действительно упустил значения до 20 :(
 
Ответить
СообщениеZORRO2005, спасибо, но я действительно упустил значения до 20 :(

Автор - TermiTe
Дата добавления - 02.08.2017 в 22:08
AlexM Дата: Четверг, 03.08.2017, 00:23 | Сообщение № 8
Группа: Друзья
Ранг: Участник клуба
Сообщений: 3585
Репутация: 902 ±
Замечаний: 0% ±

Excel 2003
_Boroda_, А зачем ПРАВБ()? Почему не так?
Код
="Всего ранее выдано "&СУММ(C3:C4)&" штук"&ВПР(ОСТАТ(МАКС(ОСТАТ(СУММ(C3:C4)-11;100);9);10);{0;"а":1;"и":4;""};2)



Номер мобильного модема (без голосовой связи)
9269171249 МегаФон, Московский регион.
 
Ответить
Сообщение_Boroda_, А зачем ПРАВБ()? Почему не так?
Код
="Всего ранее выдано "&СУММ(C3:C4)&" штук"&ВПР(ОСТАТ(МАКС(ОСТАТ(СУММ(C3:C4)-11;100);9);10);{0;"а":1;"и":4;""};2)

Автор - AlexM
Дата добавления - 03.08.2017 в 00:23
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Изменение окончания слова в зависимости от цифр (Формулы/Formulas)
Страница 1 из 11
Поиск:

Яндекс цитирования
© 2010-2017 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!