Sub Свод()
Dim wS As Worksheet
Dim sN1 As String
Dim strEnd1 As Long, strEnd2 As Long

If ActiveWorkbook.Worksheets.Count < 2 Then Exit Sub
For Each wS In ActiveWorkbook.Worksheets
    If wS.Name = "Свод" Then
        MsgBox "Уже есть сводный лист!"
        Exit Sub
    End If
Next wS

sN1 = ActiveWorkbook.Worksheets(1).Name
ActiveWorkbook.Worksheets(1).Copy Before:=ActiveWorkbook.Sheets(1)
ActiveSheet.Name = "Свод"
strEnd1 = Sheets("Свод").Cells(Sheets("Свод").Rows.Count, 1).End(xlUp).Row

For Each wS In ActiveWorkbook.Worksheets
    If (wS.Name <> "Свод") And (wS.Name <> sN1) Then
        strEnd2 = wS.Cells(wS.Rows.Count, 1).End(xlUp).Row
        wS.Rows("1:" & strEnd2).Copy Sheets("Свод").Rows(strEnd1 + 1)
        strEnd1 = strEnd1 + strEnd2
    End If
Next wS

End Sub

Option Explicit

Public Sub main()
Dim wb As Workbook
Dim oDict As Object
Dim i As Long, rowLast&
Dim strPath As String
Dim unoSh
Const fName = "прайс.xlsx"

    Set oDict = CreateObject("Scripting.Dictionary")
    strPath = ThisWorkbook.Path & "\" & fName
    Workbooks.Open Filename:=strPath, ReadOnly:=True
    Set wb = Application.ActiveWorkbook
    ThisWorkbook.Activate
    With wb
        For Each unoSh In .Worksheets
            With unoSh
                Application.StatusBar = "Обрабатываем лист " & unoSh.Name
                rowLast = .Cells(Rows.Count, 1).End(xlUp).Row
                For i = 1 To rowLast
                    If .Cells(i, 1).Value <> "" Then
                        If Not oDict.exists(.Cells(i, 1).Value) Then
                            oDict(.Cells(i, 1).Value) = .Cells(i, 2).Value
                        End If
                    End If
                Next i
            End With
        Next
        wb.Close
    End With
    
    With ThisWorkbook.ActiveSheet
        rowLast = .Cells(Rows.Count, 1).End(xlUp).Row
        For i = 2 To rowLast
            If oDict.exists(.Cells(i, 1).Value) Then
                .Cells(i, 2).Value = oDict(.Cells(i, 1).Value)
            Else
                .Cells(i, 2).Value = "-||-"
            End If
        Next i
    End With
    
    Application.StatusBar = False

End Sub