Перенос значений которые соответствуют определенному условию - Мир MS Excel

Регистрация

Напомнить пароль

= Мир MS Excel/Перенос значений которые соответствуют определенному условию - Мир MS Excel

Страница 1 из 1 1
Модератор форума: китин, _Boroda_, DrMini

Перенос значений которые соответствуют определенному условию (Формулы/Formulas)

Перенос значений которые соответствуют определенному условию

Дата: Вторник, 30.04.2019, 12:15 | Сообщение № 1

Группа: Пользователи

Ранг: Новичок

Сообщений: 20

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

Как можно автоматически заполнить ячейку "C" из "D", чтобы каждому направлению ветра соответствовало точное условие - в нашем случае градусы? Направление ветра на круге обозначают градусами.
Условие "Ветер, дующий с востока" - чтобы значение для заполнения было всегда 90
Условие "Ветер, дующий с юга" - всегда 180
И так далее.

К сообщению приложен файл: wind.xlsx (10.7 Kb)

Ответить

Дата: Вторник, 30.04.2019, 12:22 | Сообщение № 2

Группа: Друзья

Ранг: Экселист

Сообщений: 9260

Репутация: 2495 ±

Замечаний: 0% ±

Excel 2010

вдруг правильно

Код

=ВПР(B3;B:D;3;)

Ответить

Дата: Вторник, 30.04.2019, 12:41 | Сообщение № 3

Группа: Пользователи

Ранг: Новичок

Сообщений: 20

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

Там будет продолжение, чтобы были учтены все направления.

По часовой стрелке: условие = значение. Наверно для этого нужен макрос

"Ветер, дующий с севера" = 0
"Ветер, дующий с северо-северо-востока" = 22.5
"Ветер, дующий с северо-востока" = 45
"Ветер, дующий с востока-северо-востока" = 67.5
"Ветер, дующий с востока" = 90
"Ветер, дующий с востока-юго-востока" = 112.5
"Ветер, дующий с юго-востока" = 135
"Ветер, дующий с юго-юго-востока" = 157.5
"Ветер, дующий с юга" = 180
"Ветер, дующий с юго-юго-запада" = 202.5
"Ветер, дующий с юго-запада" = 225
"Ветер, дующий с западо-юго-запада" = 247.5
"Ветер, дующий с запада" = 270
"Ветер, дующий с западо-северо-запада" = 292.5
"Ветер, дующий с северо-запада" = 315
"Ветер, дующий с северо-северо-запада" = 337.5

Сообщение отредактировал evgeny22 - Вторник, 30.04.2019, 15:49

Ответить

Дата: Вторник, 30.04.2019, 12:45 | Сообщение № 4

Группа: Друзья

Ранг: Экселист

Сообщений: 9260

Репутация: 2495 ±

Замечаний: 0% ±

Excel 2010

ну тогда не правильно.
ни чего не понял.

Ответить

Дата: Вторник, 30.04.2019, 15:12 | Сообщение № 5

Группа: Пользователи

Ранг: Новичок

Сообщений: 20

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

В экселе (ячейка "B") в произвольном порядке будет указываться направление ветра, далеко не всегда по часовой стрелке. Надо каждому направлению присвоить определенное значение, и допустим второй вариант - автопреобразование направления в градусы

Ответить

Дата: Вторник, 30.04.2019, 15:23 | Сообщение № 6

Группа: Пользователи

Ранг: Новичок

Сообщений: 34

Репутация: 4 ±

Замечаний: 0% ±

Excel 2016

evgeny22, Покажите в файле реальный формат данных как есть в произвольном порядке, а на соседнем листе или рядом с исходной таблицей как надо только сделайте руками строк 10-15.....

Цитата evgeny22, 30.04.2019 в 12:41, в сообщении № 3 ()

"Ветер, дующий с востока" = 0

Тут вы пишите 0 а в файле 90????

Ответить

Дата: Вторник, 30.04.2019, 15:57 | Сообщение № 7

Группа: Пользователи

Ранг: Новичок

Сообщений: 20

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

Цитата WildGodlike, 30.04.2019 в 15:23, в сообщении № 6 ()

Тут вы пишите 0 а в файле 90?

Это у меня в одном месте ошибка, сейчас перепроверил и уже всё правильно.

В ячейке "B" будут более 5 тысяч направлений и хотелось бы их преобразовать в градусы.
То есть когда в строке указано "Ветер, дующий с юга" надо всегда заменять на число: 180

К сообщению приложен файл: 8555920.png (29.4 Kb) · wind-2.xlsx (10.7 Kb)

Сообщение отредактировал evgeny22 - Вторник, 30.04.2019, 15:57

Ответить

Дата: Вторник, 30.04.2019, 16:01 | Сообщение № 8

Группа: Пользователи

Ранг: Новичок

Сообщений: 34

Репутация: 4 ±

Замечаний: 0% ±

Excel 2016

evgeny22, пойдём по другому) правильно? или не так?

Код

=ВПР(RC[-2];R3C2:R10C4;3;ЛОЖЬ)

К сообщению приложен файл: _wind-2.xlsx (11.7 Kb)

Сообщение отредактировал WildGodlike - Вторник, 30.04.2019, 16:36

Ответить

Дата: Вторник, 30.04.2019, 16:15 | Сообщение № 9

Группа: Друзья

Ранг: Экселист

Сообщений: 9260

Репутация: 2495 ±

Замечаний: 0% ±

Excel 2010

WildGodlike, просьба, выкладывайте формулу в тело поста

Ответить

Дата: Вторник, 30.04.2019, 16:58 | Сообщение № 10

Группа: Пользователи

Ранг: Новичок

Сообщений: 20

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

Цитата WildGodlike, 30.04.2019 в 16:01, в сообщении № 8 ()

правильно?

WildGodlike, да. Большое спасибо.

Ответить

Дата: Вторник, 30.04.2019, 17:14 | Сообщение № 11

Группа: Друзья

Ранг: Экселист

Сообщений: 9260

Репутация: 2495 ±

Замечаний: 0% ±

Excel 2010

Однако

Цитата evgeny22, 30.04.2019 в 16:58, в сообщении № 10 ()

да

Цитата evgeny22, 30.04.2019 в 12:15, в сообщении № 1 ()

заполнить ячейку "C" из "D"

Цитата Nic70y, 30.04.2019 в 12:22, в сообщении № 2 ()

ВПР

Цитата WildGodlike, 30.04.2019 в 16:01, в сообщении № 8 ()

ВПР

Ответить

Дата: Вторник, 30.04.2019, 19:31 | Сообщение № 12

Группа: Друзья

Ранг: Старожил

Сообщений: 1881

Репутация: 544 ±

Замечаний: 0% ±

Excel 2013, 2016

Без оптимизации. Первое, что пришло в голову. Массивная формула:

Код

=ВЫБОР(ДЛСТР(B11)-ДЛСТР(ПОДСТАВИТЬ(B11;"-";))+1;ПРОСМОТР(99;ПОИСК({" сев";" вос";" юг";" зап"};B11);{0;1;2;3}*2);ПРОСМОТР(99;ПОИСК({" сев";" вос";" юг";" зап"};B11);{0;1;2;3})+ПРОСМОТР(99;ПОИСК({"-сев";"-вос";"-юг";"-зап"};B11);{0;1;2;3})+СЧЁТ(ПОИСК({"сев*зап";"зап*сев"};B11))*4;(МАКС(ЕЧИСЛО(ПОИСК({"сев";"вос";"юг";"зап"};B11))*ЕСЛИ(СЧЁТ(ПОИСК({"сев*зап";"зап*сев"};B11));{4;1;2;3};{0;1;2;3}))+МИН(ЕСЛИ(ЕЧИСЛО(ПОИСК({"сев";"вос";"юг";"зап"};B11));ЕСЛИ(СЧЁТ(ПОИСК({"сев*зап";"зап*сев"};B11));{4;1;2;3};{0;1;2;3})))+НАИБОЛЬШИЙ(ЕСЛИ(ЕЧИСЛО(ПОИСК({" ":"-":"-*-"}&{"сев";"вос";"юг";"зап"}&{"":"*-":""};B11));ЕСЛИ(СЧЁТ(ПОИСК({"сев*зап";"зап*сев"};B11));{4;1;2;3};{0;1;2;3})*2);2))/2)*45

*Немного упростил. Формула немассивная:

Код

=ВЫБОР(ДЛСТР(B11)-ДЛСТР(ПОДСТАВИТЬ(B11;"-";))+1;ПРОСМОТР(99;ПОИСК({" сев";" вос";" юг";" зап"};B11);{0;1;2;3}*2);ПРОСМОТР(99;ПОИСК({" сев";" вос";" юг";" зап"};B11);{0;1;2;3})+ПРОСМОТР(99;ПОИСК({"-сев";"-вос";"-юг";"-зап"};B11);{0;1;2;3})+СЧЁТ(ПОИСК({"сев*зап";"зап*сев"};B11))*4;СУММ(НАИБОЛЬШИЙ(ЕСЛИ(ЕЧИСЛО(ПОИСК({" ":"-":"-*-"}&{"сев";"вос";"юг";"зап"}&{"":"*-":""};B11));ЕСЛИ(СЧЁТ(ПОИСК({"сев*зап";"зап*сев"};B11));{4;1;2;3};{0;1;2;3}));{1;2;2;3}))/2)*45

**

Код

=ВЫБОР(ДЛСТР(B11)-ДЛСТР(ПОДСТАВИТЬ(B11;"-";))+1;ПРОСМОТР(99;ПОИСК({" сев";" вос";" юг";" зап"};B11);{0;2;4;6});СУММ(ЕЧИСЛО(ПОИСК({" ":"-"}&{"сев";"вос";"юг";"зап"};B11))*{0;1;2;3})+СЧЁТ(ПОИСК({"сев*зап";"зап*сев"};B11))*4;СУММ(НАИБОЛЬШИЙ(ЕСЛИ(ЕЧИСЛО(ПОИСК({" ":"-":"-*-"}&{"сев";"вос";"юг";"зап"}&{"":"*-":""};B11));ЕСЛИ(СЧЁТ(ПОИСК({"сев*зап";"зап*сев"};B11));{4;1;2;3};{0;1;2;3}));{1;2;2;3}))/2)*45

***Код
=ВЫБОР(ДЛСТР(B11)-ДЛСТР(ПОДСТАВИТЬ(B11;"-";))+1;ПРОСМОТР(99;ПОИСК({" сев";" вос";" юг";" зап"};B11);{0;2;4;6});СУММ(ЕЧИСЛО(ПОИСК({" ":"-"}&{"сев";"вос";"юг";"зап"};B11))*{0;1;2;3})+СЧЁТ(ПОИСК({"сев*зап";"зап*сев"};B11))*4;СУММ(НАИБОЛЬШИЙ(ЕСЛИ(ЕЧИСЛО(ПОИСК({" ":"-":"-*-"}&{"сев";"вос";"юг";"зап"}&{"":"*-":""};B11));ЕСЛИ(СЧЁТ(ПОИСК({"сев";"зап"};B11))>2;{4;1;2;3};{0;1;2;3}));{1;2;2;3}))/2)*45

Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Вторник, 30.04.2019, 21:33

Ответить

Дата: Вторник, 30.04.2019, 21:20 | Сообщение № 13

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4149

Репутация: 772 ±

Замечаний: 0% ±

Excel 2013/2016

Код

=360*(MATCH(SUM(((LEN(K3)-LEN(SUBSTITUTE(K3;{"се";"во";"юг";"за"};" ")))*10^{0;1;2;3}));{1;12;11;21;10;120;110;210;100;1200;1100;2100;1000;2001;1001;1002};)-1)/16

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Ответить

Дата: Среда, 01.05.2019, 11:57 | Сообщение № 14

Группа: Друзья

Ранг: Старожил

Сообщений: 1881

Репутация: 544 ±

Замечаний: 0% ±

Excel 2013, 2016

Воспользовался крутой идеей bmv98rus. Заменил основание и большую константу вычисляю:

Код

=(ПОИСКПОЗ(СУММ(((ДЛСТР(B11)-ДЛСТР(ПОДСТАВИТЬ(B11;{"се";"во";"юг";"за"};0)))*4^{0;1;2;3}));МУМНОЖ(4^ОТБР(ОСТАТ(СТРОКА($16:$31)+{0;1;4};16)/4)*(ОСТАТ(СТРОКА($1:$16);{1;2;4})<>1);{1:1:1});)-1)*45/2

*

Код

=(ПОИСКПОЗ(СУММ(((ДЛСТР(B11)-ДЛСТР(ПОДСТАВИТЬ(B11;{"се";"во";"юг";"за"};0)))*4^{0;1;2;3}));{1:6:5:9:4:24:20:36:16:96:80:144:64:129:65:66};)-1)*45/2

Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Среда, 01.05.2019, 15:18

Ответить

Дата: Четверг, 19.09.2019, 16:13 | Сообщение № 15

Группа: Пользователи

Ранг: Новичок

Сообщений: 22

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

Цитата Светлый, 01.05.2019 в 11:57, в сообщении № 14 ()

Заменил основание и большую константу вычисляю:

Интересно, почему я не могу продолжить это ряд? Где там ошибка?

К сообщению приложен файл: wind-12.xlsx (14.7 Kb)

Ответить

Дата: Четверг, 19.09.2019, 16:28 | Сообщение № 16

Группа: Админы

Ранг: Местный житель

Сообщений: 19612

Репутация: 4671 ±

Замечаний: ±

Excel 365 & Mac Excel

У Вас обозначения другие
[vba]

Код

=(ПОИСКПОЗ(СУММ(((ДЛСТР(B19)-ДЛСТР(ПОДСТАВИТЬ(B19;{"N";"E";"S";"W"};)))*4^{0;1;2;3}));МУМНОЖ(4^ОТБР(ОСТАТ(СТРОКА($16:$31)+{0;1;4};16)/4)*(ОСТАТ(СТРОКА($1:$16);{1;2;4})<>1);{1:1:1});)-1)*45/2

[/vba]

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816

Ответить

Дата: Пятница, 20.09.2019, 13:10 | Сообщение № 17

Группа: Пользователи

Ранг: Новичок

Сообщений: 22

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

Pelena, спасибо

Ответить

Перенос значений которые соответствуют определенному условию (Формулы/Formulas)

Страница 1 из 1
1

© 2010-2026 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!