Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Автоматическое заполнение столбца названиями групп - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Автоматическое заполнение столбца названиями групп (Формулы/Formulas)
Автоматическое заполнение столбца названиями групп
Maksimys07 Дата: Воскресенье, 08.12.2019, 00:23 | Сообщение № 1
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 20% ±

Excel 2016
ДВС!!!Помогите с формулой автоматического заполнения групп в столбце С по заполненным фамилиям столбца В. Условия в Листе "список сотрудников"
К сообщению приложен файл: 2763875.xlsx (12.0 Kb)
 
Ответить
СообщениеДВС!!!Помогите с формулой автоматического заполнения групп в столбце С по заполненным фамилиям столбца В. Условия в Листе "список сотрудников"

Автор - Maksimys07
Дата добавления - 08.12.2019 в 00:23
Michael_S Дата: Воскресенье, 08.12.2019, 02:48 | Сообщение № 2
Группа: Друзья
Ранг: Старожил
Сообщений: 2012
Репутация: 373 ±
Замечаний: 0% ±

Excel2016
такое извращение:
Код
="Группа "&(ПОИСКПОЗ(B2;'список сотрудников'!$A$1:$A$10;0)>ПОИСКПОЗ("Группа 1";'список сотрудников'!$A$1:$A$10;0))+(ПОИСКПОЗ(B2;'список сотрудников'!$A$1:$A$10;0)>ПОИСКПОЗ("Группа 2";'список сотрудников'!$A$1:$A$10;0))
К сообщению приложен файл: Maksimys07.xlsx (13.0 Kb)
 
Ответить
Сообщениетакое извращение:
Код
="Группа "&(ПОИСКПОЗ(B2;'список сотрудников'!$A$1:$A$10;0)>ПОИСКПОЗ("Группа 1";'список сотрудников'!$A$1:$A$10;0))+(ПОИСКПОЗ(B2;'список сотрудников'!$A$1:$A$10;0)>ПОИСКПОЗ("Группа 2";'список сотрудников'!$A$1:$A$10;0))

Автор - Michael_S
Дата добавления - 08.12.2019 в 02:48
Pelena Дата: Воскресенье, 08.12.2019, 08:13 | Сообщение № 3
Группа: Админы
Ранг: Местный житель
Сообщений: 19167
Репутация: 4412 ±
Замечаний: ±

Excel 365 & Mac Excel
Ещё вариант
Код
=ПРОСМОТР(;-1/ЕЧИСЛО(ПОИСК("Группа";'список сотрудников'!$A$1:ИНДЕКС('список сотрудников'!$A$1:$A$10;ПОИСКПОЗ(B2;'список сотрудников'!$A$1:$A$10;0))));'список сотрудников'!$A$1:$A$10)
К сообщению приложен файл: 2885367.xlsx (13.2 Kb)


"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
СообщениеЕщё вариант
Код
=ПРОСМОТР(;-1/ЕЧИСЛО(ПОИСК("Группа";'список сотрудников'!$A$1:ИНДЕКС('список сотрудников'!$A$1:$A$10;ПОИСКПОЗ(B2;'список сотрудников'!$A$1:$A$10;0))));'список сотрудников'!$A$1:$A$10)

Автор - Pelena
Дата добавления - 08.12.2019 в 08:13
Светлый Дата: Воскресенье, 08.12.2019, 11:41 | Сообщение № 4
Группа: Друзья
Ранг: Старожил
Сообщений: 1823
Репутация: 507 ±
Замечаний: 0% ±

Excel 2013, 2016
И ещё вариант:
Код
=ПРОСМОТР(9;ПОИСК("Группа";'список сотрудников'!A$1:A99)/(ПОИСКПОЗ(B2;'список сотрудников'!A$1:A99;)>СТРОКА($1:99));'список сотрудников'!A$1:A99)
*И для прикола:
Код
="Группа "&СЧЁТ(1/(ПОИСКПОЗ(B2;'список сотрудников'!A:A;)>ПОИСКПОЗ("Группа "&{1;2;3};'список сотрудников'!A:A;)))


Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Воскресенье, 08.12.2019, 14:22
 
Ответить
СообщениеИ ещё вариант:
Код
=ПРОСМОТР(9;ПОИСК("Группа";'список сотрудников'!A$1:A99)/(ПОИСКПОЗ(B2;'список сотрудников'!A$1:A99;)>СТРОКА($1:99));'список сотрудников'!A$1:A99)
*И для прикола:
Код
="Группа "&СЧЁТ(1/(ПОИСКПОЗ(B2;'список сотрудников'!A:A;)>ПОИСКПОЗ("Группа "&{1;2;3};'список сотрудников'!A:A;)))

Автор - Светлый
Дата добавления - 08.12.2019 в 11:41
gling Дата: Воскресенье, 08.12.2019, 21:51 | Сообщение № 5
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2519
Репутация: 674 ±
Замечаний: 0% ±

2010
Ещё вариант
Код
="Группа "&СЧЁТЕСЛИ('список сотрудников'!$A$1:ИНДЕКС('список сотрудников'!$A$1:$A$20;ПОИСКПОЗ(B2;'список сотрудников'!$A$1:$A$20;));"Группа*")


ЯД-41001506838083
 
Ответить
СообщениеЕщё вариант
Код
="Группа "&СЧЁТЕСЛИ('список сотрудников'!$A$1:ИНДЕКС('список сотрудников'!$A$1:$A$20;ПОИСКПОЗ(B2;'список сотрудников'!$A$1:$A$20;));"Группа*")

Автор - gling
Дата добавления - 08.12.2019 в 21:51
Maksimys07 Дата: Понедельник, 09.12.2019, 21:10 | Сообщение № 6
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 20% ±

Excel 2016
Если добавить группу фамилий с названием "Отдел" и т.д., как добавить название новых групп фамилий в формулы???
К сообщению приложен файл: V_2.xlsx (13.0 Kb)
 
Ответить
СообщениеЕсли добавить группу фамилий с названием "Отдел" и т.д., как добавить название новых групп фамилий в формулы???

Автор - Maksimys07
Дата добавления - 09.12.2019 в 21:10
_Boroda_ Дата: Понедельник, 09.12.2019, 22:35 | Сообщение № 7
Группа: Модераторы
Ранг: Местный житель
Сообщений: 16666
Репутация: 6478 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
Так нужно?
Код
=ПРОСМОТР(;-1/жир/(ПОИСКПОЗ(B2;'список сотрудников'!A$1:A$99;)>СТРОКА($1:$99));'список сотрудников'!A$1:A$99)
, где "жир" - именованный диапазон с формулой
Код
=ПОЛУЧИТЬ.ЯЧЕЙКУ(20;СМЕЩ('список сотрудников'!$A$1;Ч(ИНДЕКС(СТРОКА('список сотрудников'!$A$1:$A$20)-1;));))
К сообщению приложен файл: V_2_1.xlsm (18.3 Kb)


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеТак нужно?
Код
=ПРОСМОТР(;-1/жир/(ПОИСКПОЗ(B2;'список сотрудников'!A$1:A$99;)>СТРОКА($1:$99));'список сотрудников'!A$1:A$99)
, где "жир" - именованный диапазон с формулой
Код
=ПОЛУЧИТЬ.ЯЧЕЙКУ(20;СМЕЩ('список сотрудников'!$A$1;Ч(ИНДЕКС(СТРОКА('список сотрудников'!$A$1:$A$20)-1;));))

Автор - _Boroda_
Дата добавления - 09.12.2019 в 22:35
Светлый Дата: Среда, 11.12.2019, 10:10 | Сообщение № 8
Группа: Друзья
Ранг: Старожил
Сообщений: 1823
Репутация: 507 ±
Замечаний: 0% ±

Excel 2013, 2016
И простой формулой:
Код
=ИНДЕКС('список сотрудников'!A:A;АГРЕГАТ(14;6;ПОИСК({"Отдел";"Группа"};'список сотрудников'!A$1:A99)/(ПОИСКПОЗ(B2;'список сотрудников'!A$1:A99;)>СТРОКА($1:99))*СТРОКА($1:99);1))


Программировать проще, чем писать стихи.
 
Ответить
СообщениеИ простой формулой:
Код
=ИНДЕКС('список сотрудников'!A:A;АГРЕГАТ(14;6;ПОИСК({"Отдел";"Группа"};'список сотрудников'!A$1:A99)/(ПОИСКПОЗ(B2;'список сотрудников'!A$1:A99;)>СТРОКА($1:99))*СТРОКА($1:99);1))

Автор - Светлый
Дата добавления - 11.12.2019 в 10:10
Maksimys07 Дата: Вторник, 14.01.2020, 22:19 | Сообщение № 9
Группа: Пользователи
Ранг: Новичок
Сообщений: 44
Репутация: 0 ±
Замечаний: 20% ±

Excel 2016
всем большое спасибо!все варианты подошли
 
Ответить
Сообщениевсем большое спасибо!все варианты подошли

Автор - Maksimys07
Дата добавления - 14.01.2020 в 22:19
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Автоматическое заполнение столбца названиями групп (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!