Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Удаление символов после цифр - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Удаление символов после цифр (Формулы/Formulas)
Удаление символов после цифр
Valet Дата: Воскресенье, 11.04.2021, 22:14 | Сообщение № 1
Группа: Пользователи
Ранг: Новичок
Сообщений: 12
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
Добрый вечер.
 
Ответить
СообщениеДобрый вечер.

Автор - Valet
Дата добавления - 11.04.2021 в 22:14
Valet Дата: Воскресенье, 11.04.2021, 22:19 | Сообщение № 2
Группа: Пользователи
Ранг: Новичок
Сообщений: 12
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
Столкнулся с проблемой, есть ряд адресов, их необходимо немного причесать. Т.е в адресной строке после указания дома или корпуса и т.д. дополнены наименования объекта, они как раз и не нужны. Возможно ли при помощи формул, удалить с конца ячейки все символы до первой попадающей цифры? с вба не дружу, поэтому чем проще тем лучше) Заранее спасибо!
К сообщению приложен файл: 2128492.xlsx (9.6 Kb)
 
Ответить
СообщениеСтолкнулся с проблемой, есть ряд адресов, их необходимо немного причесать. Т.е в адресной строке после указания дома или корпуса и т.д. дополнены наименования объекта, они как раз и не нужны. Возможно ли при помощи формул, удалить с конца ячейки все символы до первой попадающей цифры? с вба не дружу, поэтому чем проще тем лучше) Заранее спасибо!

Автор - Valet
Дата добавления - 11.04.2021 в 22:19
прохожий2019 Дата: Воскресенье, 11.04.2021, 22:45 | Сообщение № 3
Группа: Проверенные
Ранг: Старожил
Сообщений: 1241
Репутация: 317 ±
Замечаний: 0% ±

365 Beta Channel
с вба не дружу
ну и зря...
Код
=ЛЕВБ(A2;МАКС(СТРОКА($A$1:ИНДЕКС(A:A;ДЛСТР(A2)))*(ABS(КОДСИМВ(ПСТР(A2;СТРОКА($A$1:ИНДЕКС(A:A;ДЛСТР(A2)));1))-52,5)<=4,5)))
Код
=ЛЕВБ(A2;МАКС(ЕСЛИОШИБКА(СТРОКА($1:$99)*(ABS(КОДСИМВ(ПСТР(A2;СТРОКА($1:$99);1))-52,5)<=4,5);0)))
К сообщению приложен файл: 2802828.xlsx (10.9 Kb)


Сообщение отредактировал прохожий2019 - Воскресенье, 11.04.2021, 22:49
 
Ответить
Сообщение
с вба не дружу
ну и зря...
Код
=ЛЕВБ(A2;МАКС(СТРОКА($A$1:ИНДЕКС(A:A;ДЛСТР(A2)))*(ABS(КОДСИМВ(ПСТР(A2;СТРОКА($A$1:ИНДЕКС(A:A;ДЛСТР(A2)));1))-52,5)<=4,5)))
Код
=ЛЕВБ(A2;МАКС(ЕСЛИОШИБКА(СТРОКА($1:$99)*(ABS(КОДСИМВ(ПСТР(A2;СТРОКА($1:$99);1))-52,5)<=4,5);0)))

Автор - прохожий2019
Дата добавления - 11.04.2021 в 22:45
Valet Дата: Воскресенье, 11.04.2021, 23:10 | Сообщение № 4
Группа: Пользователи
Ранг: Новичок
Сообщений: 12
Репутация: 0 ±
Замечаний: 0% ±

Excel 2013
прохожий2019, Благодарен за помощь, а можете описать как это работает? и почему диапазон выбран - все столбцы?
 
Ответить
Сообщениепрохожий2019, Благодарен за помощь, а можете описать как это работает? и почему диапазон выбран - все столбцы?

Автор - Valet
Дата добавления - 11.04.2021 в 23:10
прохожий2019 Дата: Понедельник, 12.04.2021, 09:23 | Сообщение № 5
Группа: Проверенные
Ранг: Старожил
Сообщений: 1241
Репутация: 317 ±
Замечаний: 0% ±

365 Beta Channel
как это работает?

Код
СТРОКА($A$1:ИНДЕКС(A:A;ДЛСТР(A2)))
получаем последовательность чисел от 1 до числа символов в строке
Код
ABS(КОДСИМВ(ПСТР(A2;...);1))-52,5)<=4,5
проверяем находится ли код символа в диапазоне 48-57 (диапазон кодов цифр)
Код
МАКС(СТРОКА($A$1:ИНДЕКС(A:A;ДЛСТР(A2)))*(ABS(...)))
определяем максимальный номер, соответствующий условию
Код
ЛЕВБ(A2;МАКС(...))
вынимаем всё слева, включая последнюю цифру
как-то так
 
Ответить
Сообщение
как это работает?

Код
СТРОКА($A$1:ИНДЕКС(A:A;ДЛСТР(A2)))
получаем последовательность чисел от 1 до числа символов в строке
Код
ABS(КОДСИМВ(ПСТР(A2;...);1))-52,5)<=4,5
проверяем находится ли код символа в диапазоне 48-57 (диапазон кодов цифр)
Код
МАКС(СТРОКА($A$1:ИНДЕКС(A:A;ДЛСТР(A2)))*(ABS(...)))
определяем максимальный номер, соответствующий условию
Код
ЛЕВБ(A2;МАКС(...))
вынимаем всё слева, включая последнюю цифру
как-то так

Автор - прохожий2019
Дата добавления - 12.04.2021 в 09:23
китин Дата: Понедельник, 12.04.2021, 09:59 | Сообщение № 6
Группа: Модераторы
Ранг: Экселист
Сообщений: 7013
Репутация: 1073 ±
Замечаний: 0% ±

Excel 2007;2010;2016
можно так:
Код
=ПСТР($A2;1;ПРОСМОТР(2;1/ЕЧИСЛО(--ПСТР($A2;СТРОКА($1:$99);1));СТРОКА($1:$99)))
К сообщению приложен файл: 8592383.xlsx (9.9 Kb)


Не судите очень строго:я пытаюсь научиться
ЯД 41001877306852
 
Ответить
Сообщениеможно так:
Код
=ПСТР($A2;1;ПРОСМОТР(2;1/ЕЧИСЛО(--ПСТР($A2;СТРОКА($1:$99);1));СТРОКА($1:$99)))

Автор - китин
Дата добавления - 12.04.2021 в 09:59
Светлый Дата: Понедельник, 12.04.2021, 11:12 | Сообщение № 7
Группа: Друзья
Ранг: Старожил
Сообщений: 1823
Репутация: 507 ±
Замечаний: 0% ±

Excel 2013, 2016
Такая формула тоже работает:
Код
=ЛЕВБ(A2;ПРОСМОТР(;-ПСТР(A2;СТРОКА($1:99);1);СТРОКА($1:99)))


Программировать проще, чем писать стихи.
 
Ответить
СообщениеТакая формула тоже работает:
Код
=ЛЕВБ(A2;ПРОСМОТР(;-ПСТР(A2;СТРОКА($1:99);1);СТРОКА($1:99)))

Автор - Светлый
Дата добавления - 12.04.2021 в 11:12
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Удаление символов после цифр (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!