Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Условное форматирование. Выделить только первое значение. - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Условное форматирование. Выделить только первое значение. (Формулы/Formulas)
Условное форматирование. Выделить только первое значение.
i691198 Дата: Суббота, 07.01.2023, 13:53 | Сообщение № 1
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 210
Репутация: 84 ±
Замечаний: 0% ±

Доброго дня всем. С праздником вас!
Есть проблема, имеется таблица с числовыми значениями. Нужно с помощью УФ выделить только одно первое значение записанное в ячейке Q1. Просмотр должен быть по строкам слева направо и сверху вниз. Что-то получилось сделать, но выделяются лишние ячейки, если не трудно - толкните в нужную сторону.
P.S. Данные в таблице условные, кнопкой F9 можно менять.
К сообщению приложен файл: 9797824.xlsx (11.6 Kb)


Сообщение отредактировал i691198 - Суббота, 07.01.2023, 13:55
 
Ответить
СообщениеДоброго дня всем. С праздником вас!
Есть проблема, имеется таблица с числовыми значениями. Нужно с помощью УФ выделить только одно первое значение записанное в ячейке Q1. Просмотр должен быть по строкам слева направо и сверху вниз. Что-то получилось сделать, но выделяются лишние ячейки, если не трудно - толкните в нужную сторону.
P.S. Данные в таблице условные, кнопкой F9 можно менять.

Автор - i691198
Дата добавления - 07.01.2023 в 13:53
Arti Дата: Суббота, 07.01.2023, 14:10 | Сообщение № 2
Группа: Пользователи
Ранг: Новичок
Сообщений: 36
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
Доброго дня.

Может быть так
Код
=И(СЧЁТЕСЛИ(C$3:C3;$Q$1)=1;C3=$Q$1)


Я не я и суета не моя
 
Ответить
СообщениеДоброго дня.

Может быть так
Код
=И(СЧЁТЕСЛИ(C$3:C3;$Q$1)=1;C3=$Q$1)

Автор - Arti
Дата добавления - 07.01.2023 в 14:10
i691198 Дата: Суббота, 07.01.2023, 14:20 | Сообщение № 3
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 210
Репутация: 84 ±
Замечаний: 0% ±

Arti, Спасибо за ответ, но это совсем не то - выделена должна быть только одна ячейка.
 
Ответить
СообщениеArti, Спасибо за ответ, но это совсем не то - выделена должна быть только одна ячейка.

Автор - i691198
Дата добавления - 07.01.2023 в 14:20
Gustav Дата: Суббота, 07.01.2023, 16:39 | Сообщение № 4
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2703
Репутация: 1123 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
А если так:
Код
=И( C3=$Q$1; СЧЁТЕСЛИ($C$2:$N2;$Q$1)=0; СЧЁТЕСЛИ($C3:C3;$Q$1)=1 )

Т.е. ноль совпадений до текущей строки и первое в текущей. Понятное дело, что обязательно должна существовать одна строка (например, заголовков) перед областью данных. И хорошо, что заголовки не встречаются среди самих значений (иначе пришлось бы резервировать пустую строку).


МОИ: Ник, Tip box: 41001663842605
 
Ответить
СообщениеА если так:
Код
=И( C3=$Q$1; СЧЁТЕСЛИ($C$2:$N2;$Q$1)=0; СЧЁТЕСЛИ($C3:C3;$Q$1)=1 )

Т.е. ноль совпадений до текущей строки и первое в текущей. Понятное дело, что обязательно должна существовать одна строка (например, заголовков) перед областью данных. И хорошо, что заголовки не встречаются среди самих значений (иначе пришлось бы резервировать пустую строку).

Автор - Gustav
Дата добавления - 07.01.2023 в 16:39
i691198 Дата: Суббота, 07.01.2023, 16:51 | Сообщение № 5
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 210
Репутация: 84 ±
Замечаний: 0% ±

Gustav, Большое спасибо, все отлично работает. Вы мне спасли много нервов и времени. Еще раз с праздником Вас.
 
Ответить
СообщениеGustav, Большое спасибо, все отлично работает. Вы мне спасли много нервов и времени. Еще раз с праздником Вас.

Автор - i691198
Дата добавления - 07.01.2023 в 16:51
i691198 Дата: Суббота, 07.01.2023, 18:04 | Сообщение № 6
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 210
Репутация: 84 ±
Замечаний: 0% ±

Gustav, Благодаря вам сразу получилось сделать второй вариант выделения ячеек - при просмотре не по строкам, а по столбцам.
Код
=И(C3=$Q$1;СЧЁТЕСЛИ($C$3:C3;$Q$1)=1;СЧЁТЕСЛИ($B$3:B$27;$Q$1)=0)

Доступно только для пользователей


Сообщение отредактировал i691198 - Суббота, 07.01.2023, 18:05
 
Ответить
СообщениеGustav, Благодаря вам сразу получилось сделать второй вариант выделения ячеек - при просмотре не по строкам, а по столбцам.
Код
=И(C3=$Q$1;СЧЁТЕСЛИ($C$3:C3;$Q$1)=1;СЧЁТЕСЛИ($B$3:B$27;$Q$1)=0)

Доступно только для пользователей

Автор - i691198
Дата добавления - 07.01.2023 в 18:04
bmv98rus Дата: Суббота, 07.01.2023, 21:30 | Сообщение № 7
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4099
Репутация: 766 ±
Замечаний: 0% ±

Excel 2013/2016
Вариант на тот случай когда шапки нет
Код
=AGGREGATE(15;6;(ROW($C$3:$N3)+COLUMN($C$3:$N3)%)/($C$3:$N3=$Q$1);1)=ROW()+COLUMN()%


Замечательный Временно просто медведь , процентов на 20.

Сообщение отредактировал bmv98rus - Суббота, 07.01.2023, 21:31
 
Ответить
СообщениеВариант на тот случай когда шапки нет
Код
=AGGREGATE(15;6;(ROW($C$3:$N3)+COLUMN($C$3:$N3)%)/($C$3:$N3=$Q$1);1)=ROW()+COLUMN()%

Автор - bmv98rus
Дата добавления - 07.01.2023 в 21:30
Gustav Дата: Воскресенье, 08.01.2023, 04:36 | Сообщение № 8
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2703
Репутация: 1123 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
когда шапки нет

"Наш ответ Чемберлену Агрегату" :) :
Код
=И( C3=$Q$1; ЕСЛИ(СТРОКА()=СТРОКА($C$3); ИСТИНА; СЧЁТЕСЛИ(СМЕЩ($C$3:$N$3;;;СТРОКА()-СТРОКА($C$3)); $Q$1)=0); СЧЁТЕСЛИ($C3:C3;$Q$1)=1 )

Длинновато, конечно, но, как говорится, принципиально тоже возможно


МОИ: Ник, Tip box: 41001663842605
 
Ответить
Сообщение
когда шапки нет

"Наш ответ Чемберлену Агрегату" :) :
Код
=И( C3=$Q$1; ЕСЛИ(СТРОКА()=СТРОКА($C$3); ИСТИНА; СЧЁТЕСЛИ(СМЕЩ($C$3:$N$3;;;СТРОКА()-СТРОКА($C$3)); $Q$1)=0); СЧЁТЕСЛИ($C3:C3;$Q$1)=1 )

Длинновато, конечно, но, как говорится, принципиально тоже возможно

Автор - Gustav
Дата добавления - 08.01.2023 в 04:36
bmv98rus Дата: Воскресенье, 08.01.2023, 09:00 | Сообщение № 9
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4099
Репутация: 766 ±
Замечаний: 0% ±

Excel 2013/2016
"Наш ответ Чемберлену Агрегату"
ну его можно легко заменить на обычный MIN
Код
=MIN(IF($C$3:$N3=$Q$1;ROW($C$3:$N3)+COLUMN($C$3:$N3)%))=ROW()+COLUMN()%


Длинновато
тут больше проблем с тем что летуче.
уберем её, и укоротив и приземлив
Код
=AND(C3=$Q$1;COUNTIF($C$3:$N3;$Q$1)=COUNTIF(C3:$N3;$Q$1))


Замечательный Временно просто медведь , процентов на 20.

Сообщение отредактировал bmv98rus - Воскресенье, 08.01.2023, 09:10
 
Ответить
Сообщение
"Наш ответ Чемберлену Агрегату"
ну его можно легко заменить на обычный MIN
Код
=MIN(IF($C$3:$N3=$Q$1;ROW($C$3:$N3)+COLUMN($C$3:$N3)%))=ROW()+COLUMN()%


Длинновато
тут больше проблем с тем что летуче.
уберем её, и укоротив и приземлив
Код
=AND(C3=$Q$1;COUNTIF($C$3:$N3;$Q$1)=COUNTIF(C3:$N3;$Q$1))

Автор - bmv98rus
Дата добавления - 08.01.2023 в 09:00
Gustav Дата: Воскресенье, 08.01.2023, 15:13 | Сообщение № 10
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2703
Репутация: 1123 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
=И(C3=$Q$1;СЧЁТЕСЛИ($C$3:$N3;$Q$1)=СЧЁТЕСЛИ(C3:$N3;$Q$1))

А вот это шикардос! Эта мне нравится очень! И всего делов-то - поменять направление второго СЧЁТЕСЛИ, но какой эффект! Значит, выше не зря обсуждали и в итоге дописались до этого варианта - зачёт в карму!


МОИ: Ник, Tip box: 41001663842605
 
Ответить
Сообщение
=И(C3=$Q$1;СЧЁТЕСЛИ($C$3:$N3;$Q$1)=СЧЁТЕСЛИ(C3:$N3;$Q$1))

А вот это шикардос! Эта мне нравится очень! И всего делов-то - поменять направление второго СЧЁТЕСЛИ, но какой эффект! Значит, выше не зря обсуждали и в итоге дописались до этого варианта - зачёт в карму!

Автор - Gustav
Дата добавления - 08.01.2023 в 15:13
i691198 Дата: Воскресенье, 08.01.2023, 15:40 | Сообщение № 11
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 210
Репутация: 84 ±
Замечаний: 0% ±

А вот это шикардос!
Я конечно извиняюсь, но мне не очень понятна причина вашего восторга. Формула bmv98rus и Ваша дают одинаковый результат, а в чем преимущество? (Плюсик медвежонку я, конечно, поставил, но непонятки остались) Если Вас это не сильно затруднит прокомментируйте этот момент.
 
Ответить
Сообщение
А вот это шикардос!
Я конечно извиняюсь, но мне не очень понятна причина вашего восторга. Формула bmv98rus и Ваша дают одинаковый результат, а в чем преимущество? (Плюсик медвежонку я, конечно, поставил, но непонятки остались) Если Вас это не сильно затруднит прокомментируйте этот момент.

Автор - i691198
Дата добавления - 08.01.2023 в 15:40
Gustav Дата: Воскресенье, 08.01.2023, 15:48 | Сообщение № 12
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2703
Репутация: 1123 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
причина восторга

В формуле bmv98rus:
1. не надо захватывать (резервировать) дополнительную строку (заголовки) перед данными
2. количество условий в И изящно сокращено до двух


МОИ: Ник, Tip box: 41001663842605
 
Ответить
Сообщение
причина восторга

В формуле bmv98rus:
1. не надо захватывать (резервировать) дополнительную строку (заголовки) перед данными
2. количество условий в И изящно сокращено до двух

Автор - Gustav
Дата добавления - 08.01.2023 в 15:48
i691198 Дата: Воскресенье, 08.01.2023, 15:58 | Сообщение № 13
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 210
Репутация: 84 ±
Замечаний: 0% ±

Gustav, Спасибо за пояснение, понял. (надеюсь, что модераторы не воспримут это как флуд)
 
Ответить
СообщениеGustav, Спасибо за пояснение, понял. (надеюсь, что модераторы не воспримут это как флуд)

Автор - i691198
Дата добавления - 08.01.2023 в 15:58
Юрий_Ф Дата: Воскресенье, 08.01.2023, 18:34 | Сообщение № 14
Группа: Проверенные
Ранг: Ветеран
Сообщений: 769
Репутация: 1 ±
Замечаний: 60% ±

Excel 2010
i691198,

Интересны, конечно, и таблица, и задание!
А где всё это можно применять?


То, что мы делаем, завораживает!
Кстати! Я не могу всем нравиться! И это взаимно!
 
Ответить
Сообщениеi691198,

Интересны, конечно, и таблица, и задание!
А где всё это можно применять?

Автор - Юрий_Ф
Дата добавления - 08.01.2023 в 18:34
bmv98rus Дата: Воскресенье, 08.01.2023, 18:45 | Сообщение № 15
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4099
Репутация: 766 ±
Замечаний: 0% ±

Excel 2013/2016
А вот это шикардос!
а вишенка на торте это то, что краткость не равно скорость.
если сравнить, то самым быстрым вариантом будет
Код
=If(C3=$Q$1;COUNTIF($C$3:$N3;$Q$1)=COUNTIF(C3:$N3;$Q$1))
как не парадоксально, но ему не уступает по скорости
Код
=If(C3=$Q$1;MIN(IF($C$3:$N3=$Q$1;ROW($C$3:$N3)+COLUMN($C$3:$N3)%))=ROW()+COLUMN()%)
Возможно с ростом таблицы мин начнет проигрывать.


Замечательный Временно просто медведь , процентов на 20.

Сообщение отредактировал bmv98rus - Воскресенье, 08.01.2023, 19:05
 
Ответить
Сообщение
А вот это шикардос!
а вишенка на торте это то, что краткость не равно скорость.
если сравнить, то самым быстрым вариантом будет
Код
=If(C3=$Q$1;COUNTIF($C$3:$N3;$Q$1)=COUNTIF(C3:$N3;$Q$1))
как не парадоксально, но ему не уступает по скорости
Код
=If(C3=$Q$1;MIN(IF($C$3:$N3=$Q$1;ROW($C$3:$N3)+COLUMN($C$3:$N3)%))=ROW()+COLUMN()%)
Возможно с ростом таблицы мин начнет проигрывать.

Автор - bmv98rus
Дата добавления - 08.01.2023 в 18:45
Nic70y Дата: Воскресенье, 08.01.2023, 18:58 | Сообщение № 16
Группа: Друзья
Ранг: Экселист
Сообщений: 8710
Репутация: 2261 ±
Замечаний: 0% ±

Excel 2010
как не парадоксально
ваще не парадоксально
СЧЁТЕСЛИ(


ЮMoney 41001841029809
 
Ответить
Сообщение
как не парадоксально
ваще не парадоксально
СЧЁТЕСЛИ(

Автор - Nic70y
Дата добавления - 08.01.2023 в 18:58
bmv98rus Дата: Воскресенье, 08.01.2023, 19:08 | Сообщение № 17
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4099
Репутация: 766 ±
Замечаний: 0% ±

Excel 2013/2016
Nic70y, да нее, все на место встало. В УФ автоматом массивно считает, а когда проверку делал на скорость, забыл ввести тремя кнопками.


Замечательный Временно просто медведь , процентов на 20.
 
Ответить
СообщениеNic70y, да нее, все на место встало. В УФ автоматом массивно считает, а когда проверку делал на скорость, забыл ввести тремя кнопками.

Автор - bmv98rus
Дата добавления - 08.01.2023 в 19:08
Pharaon-MSK Дата: Среда, 11.01.2023, 13:13 | Сообщение № 18
Группа: Пользователи
Ранг: Прохожий
Сообщений: 4
Репутация: 0 ±
Замечаний: 0% ±

Здравствуйте! Подскажите не особо грамотному. Имеем дату выдачи документов, срок годности которых год с момента выдачи. Как правильно прописать правило, чтобы за 30 дней до окончания срока ячейка становилась красной, незаполненная ячейка датой выдачей - желтым. Но с привязкой с функцией СЕГОДНЯ. Помогите плз. Например: выдан документ 01.01.2021 года, срок действия по умолчанию 1 год, так вот чтобы например 1 декабря 2021, когда я открыл Эксель, ячейка бы светилась красным, а пустые не заполненные желтым цветом. Спасибо.
К сообщению приложен файл: 5580844.xlsx (10.5 Kb)
 
Ответить
СообщениеЗдравствуйте! Подскажите не особо грамотному. Имеем дату выдачи документов, срок годности которых год с момента выдачи. Как правильно прописать правило, чтобы за 30 дней до окончания срока ячейка становилась красной, незаполненная ячейка датой выдачей - желтым. Но с привязкой с функцией СЕГОДНЯ. Помогите плз. Например: выдан документ 01.01.2021 года, срок действия по умолчанию 1 год, так вот чтобы например 1 декабря 2021, когда я открыл Эксель, ячейка бы светилась красным, а пустые не заполненные желтым цветом. Спасибо.

Автор - Pharaon-MSK
Дата добавления - 11.01.2023 в 13:13
китин Дата: Среда, 11.01.2023, 13:28 | Сообщение № 19
Группа: Модераторы
Ранг: Экселист
Сообщений: 7013
Репутация: 1073 ±
Замечаний: 0% ±

Excel 2007;2010;2016
Pharaon-MSK, Прочитайте Правила форума и создайте свою тему


Не судите очень строго:я пытаюсь научиться
ЯД 41001877306852
 
Ответить
СообщениеPharaon-MSK, Прочитайте Правила форума и создайте свою тему

Автор - китин
Дата добавления - 11.01.2023 в 13:28
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Условное форматирование. Выделить только первое значение. (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!