Sub Procedure_1()

     Dim tblA() As Variant
     Dim myLastRow As Long
     Dim i As Long
      
      
     Application.ScreenUpdating = False
      
'---------------------------------------------------------------------------------------------
     'ГРУППИРОВКА ПО ПЕРВОМУ СТОЛБЦУ.
      
     myLastRow = Cells(Rows.Count, ActiveCell.Column).End(xlUp).Row
      
     'Берём в VBA-таблицу "tblA" данные из первого столбца.
     tblA() = Cells(1, ActiveCell.Column).Resize(myLastRow, 1).Value
      
     For i = UBound(tblA, 1) To 2 Step -1
      
         If tblA(i, 1) <> tblA(i - 1, 1) Then
          
             Rows(i).Resize(2).Insert Shift:=xlShiftDown, CopyOrigin:=xlFormatFromRightOrBelow
              
             With Rows(i).Borders(xlEdgeBottom)
                 .LineStyle = xlDash
                 .Weight = xlMedium
             End With
              
         End If
          
     Next i
      
      
'---------------------------------------------------------------------------------------------
     'ГРУППИРОВКА ПО ВТОРОМУ СТОЛБЦУ.
      
     'Т.к. количество строк изменилось, нужно заново провести некоторые действия.
     myLastRow = Cells(Rows.Count, ActiveCell.Column).End(xlUp).Row
      
     'Берём в VBA-таблицу "tblA" данные из второго столбца.
     tblA() = Cells(1, ActiveCell.Column + 1).Resize(myLastRow, 1).Value
      
     For i = UBound(tblA, 1) To 2 Step -1
      
         'Если текущая или вышестоящая ячейка пустые.
         If IsEmpty(tblA(i, 1)) = True Or IsEmpty(tblA(i - 1, 1)) = True Then
             'Переходим к следующей ячейке.
             GoTo metka
         End If
          
         'Если данные в текущей ячейке и вышестоящей ячейке разные.
         If tblA(i, 1) <> tblA(i - 1, 1) Then
          
             Rows(i).Insert Shift:=xlShiftDown, CopyOrigin:=xlFormatFromRightOrBelow
          
         End If
          
metka:
      
     Next i
      
     Application.ScreenUpdating = True

End Sub

Sub Procedure_1()

     Dim tblMy() As Variant
     Dim myLastRow As Long
     Dim i As Long
      
      
     Application.ScreenUpdating = False
      
     myLastRow = Cells(Rows.Count, ActiveCell.Column).End(xlUp).Row
      
     'Берём в VBA-таблицу "tblMy" данные из двух столбцов.
     tblMy() = Cells(1, ActiveCell.Column).Resize(myLastRow, 2).Value
      
     For i = UBound(tblMy, 1) To 2 Step -1
          
         'Если данные в первом столбце в текущей строке и строке,
             'которая выше, не совпадают.
         If tblMy(i, 1) <> tblMy(i - 1, 1) Then
          
             Rows(i).Resize(2).Insert Shift:=xlShiftDown, CopyOrigin:=xlFormatFromRightOrBelow
              
             With Rows(i).Borders(xlEdgeBottom)
                 .LineStyle = xlDash
                 .Weight = xlMedium
             End With
          
         'Если данные во втором столбце в текущей строке и строке,
             'которая выше, не совпадают.
         ElseIf tblMy(i, 2) <> tblMy(i - 1, 2) Then
             Rows(i).Insert Shift:=xlShiftDown, CopyOrigin:=xlFormatFromRightOrBelow
         End If
          
     Next i
      
     Application.ScreenUpdating = True

End Sub

Sub Procedure_1()

      Dim tblMy() As Variant
      Dim myLastRow As Long
      Dim myActiveColumn As Long
      Dim i As Long
       
       
      Application.ScreenUpdating = False
       
      'Берём номер столбца, где находится активная ячейка,
         'в переменную. Т.к. этот номер столбца
         'в коде нужен несколько раз и удобнее указывать
         'переменную вместо "ActiveCell.Column",
         'т.к. можно что-нибудь забыть сделать,
         'если код будет меняться и данные будут браться не те.
      myActiveColumn = ActiveCell.Column
       
      myLastRow = Cells(Rows.Count, myActiveColumn).End(xlUp).Row
       
      'Берём в VBA-таблицу "tblMy" данные из двух столбцов.
      tblMy() = Cells(1, myActiveColumn).Resize(myLastRow, 2).Value
       
      For i = UBound(tblMy, 1) To 2 Step -1
           
          'Если данные в первом столбце в текущей строке и строке,
              'которая выше, не совпадают.
          If tblMy(i, 1) <> tblMy(i - 1, 1) Then
              
              'Вставка двух пустых строк между группами.
              Rows(i).Resize(2).Insert Shift:=xlShiftDown, CopyOrigin:=xlFormatFromRightOrBelow
               
              'Делаем границу между двумя вставленными
                 'пустыми строками.
              With Rows(i).Borders(xlEdgeBottom)
                  .LineStyle = xlDash
                  .Weight = xlMedium
              End With
               
              'Делаем заголовок у нижней группы.
              Cells(i + 1, myActiveColumn).Value = "Шапка группы"
           
          'Если данные во втором столбце в текущей строке и строке,
              'которая выше, не совпадают.
          ElseIf tblMy(i, 2) <> tblMy(i - 1, 2) Then
              Rows(i).Insert Shift:=xlShiftDown, CopyOrigin:=xlFormatFromRightOrBelow
          End If
           
      Next i
       
      Application.ScreenUpdating = True

End Sub

Sub Procedure_1()

      Dim tblMy() As Variant
      Dim myLastRow As Long
      Dim myActiveColumn As Long
      Dim i As Long
       
       
      Application.ScreenUpdating = False
       
      'Берём номер столбца, где находится активная ячейка,
          'в переменную.
      myActiveColumn = ActiveCell.Column
       
      myLastRow = Cells(Rows.Count, myActiveColumn).End(xlUp).Row
       
      'Берём в VBA-таблицу "tblMy" данные из двух столбцов.
      tblMy() = Cells(1, myActiveColumn).Resize(myLastRow, 2).Value
       
      'Двигаемся до третьей строки, т.к. в первой строке
         'находится заголовок и вторую строку
         'не нужно сравнивать с первой.
      For i = UBound(tblMy, 1) To 3 Step -1
           
          'Если данные в первом столбце в текущей строке и строке,
              'которая выше, не совпадают.
          If tblMy(i, 1) <> tblMy(i - 1, 1) Then
               
              'Вставка трёх пустых строк между группами.
              Rows(i).Resize(3).Insert Shift:=xlShiftDown, CopyOrigin:=xlFormatFromRightOrBelow
               
              'Делаем границу между двумя вставленными
                 'пустыми строками.
              With Rows(i).Borders(xlEdgeBottom)
                  .LineStyle = xlDash
                  .Weight = xlMedium
              End With
               
              'Делаем заголовок у нижней группы.
              'Копируем заголовок из первой строки Excel-листа.
              'Копировать нужно, т.к. нужно сохранять форматирование.
              Cells(1, myActiveColumn).Resize(1, 3).Copy _
                 Destination:=Cells(i + 2, myActiveColumn)
           
          'Если данные во втором столбце в текущей строке и строке,
              'которая выше, не совпадают.
          ElseIf tblMy(i, 2) <> tblMy(i - 1, 2) Then
              Rows(i).Insert Shift:=xlShiftDown, CopyOrigin:=xlFormatFromRightOrBelow
          End If
           
      Next i
       
      Application.ScreenUpdating = True

End Sub