Незаполненные ячейки

Старая форма входа

Страница 1 из 1 1
Модератор форума: китин, _Boroda_

Незаполненные ячейки (Формулы/Formulas)

olya2084

Дата: Четверг, 31.08.2023, 01:15 | Сообщение № 1

Группа: Пользователи

Ранг: Участник

Сообщений: 87

Репутация: -2 ±

Замечаний: 20% ±

Здравствуйте! На листе 2 нужна формула (без макроса): чтобы при заполнении хотя бы одной ячейки отображался статус "что-то заполнено", при всех незаполненных ячейках- "все пусто", а при заполнении всех ячеек- "все заполнено". Реально так сделать?

К сообщению приложен файл: 2153996.xls (27.5 Kb)

Ответить

DrMini

Дата: Четверг, 31.08.2023, 04:59 | Сообщение № 2

Группа: Друзья

Ранг: Старожил

Сообщений: 1760

Репутация: 244 ±

Замечаний: 0% ±

Excel LTSC 2024 RUS

Цитата olya2084, 31.08.2023 в 01:15, в сообщении № 1 (

)

Реально так сделать?

Да
Ваш (подправленный) вариант:

Код

=ЕСЛИ(СЧИТАТЬПУСТОТЫ(A2:H2)=8;"все пустые";ЕСЛИ(СЧИТАТЬПУСТОТЫ(A2:H2)=0;"все заполнено";"что-то заполнено"))

Как вариант:

Код

=ЕСЛИ(СЧЁТЕСЛИ(A2:H2;"")=0;"все заполнено";ЕСЛИ(СЧЁТЕСЛИ(A2:H2;"")=8;"все пусто";"что-то заполнено"))

К сообщению приложен файл: 3975782.xls (32.0 Kb)

Сообщение отредактировал DrMini - Четверг, 31.08.2023, 05:48

Ответить

прохожий2019

Дата: Четверг, 31.08.2023, 07:32 | Сообщение № 3

Группа: Проверенные

Ранг: Старожил

Сообщений: 1272

Репутация: 322 ±

Замечаний: 0% ±

365 Beta Channel

Код

=ПРОСМОТР(СЧЁТЗ(A2:H2);{0;1;8};{"все пустые";"что-то заполнено";"все заполнено"})

Ответить

olya2084

Дата: Четверг, 31.08.2023, 07:47 | Сообщение № 4

Группа: Пользователи

Ранг: Участник

Сообщений: 87

Репутация: -2 ±

Замечаний: 20% ±

DrMini, огромное спасибо!

Ответить

olya2084

Дата: Четверг, 31.08.2023, 07:48 | Сообщение № 5

Группа: Пользователи

Ранг: Участник

Сообщений: 87

Репутация: -2 ±

Замечаний: 20% ±

DrMini, и за ваш вариант премного благодарна!!

Ответить

olya2084

Дата: Четверг, 31.08.2023, 07:49 | Сообщение № 6

Группа: Пользователи

Ранг: Участник

Сообщений: 87

Репутация: -2 ±

Замечаний: 20% ±

прохожий2019, и вам спасибо!

Ответить

Светлый

Дата: Четверг, 31.08.2023, 13:28 | Сообщение № 7

Группа: Друзья

Ранг: Старожил

Сообщений: 1838

Репутация: 516 ±

Замечаний: 0% ±

Excel 2013, 2016

И мои 5 копеек

Код

=ВПР(СЧЁТЗ(A2:H2);{0;"все пустые":1;"что-то заполнено":8;"все заполнено"};2)

Код

=ТЕКСТ(СУММ((СЧЁТЗ(A2:H2)>{0;7})-0,5);"в\се заполнено;в\се пу\стые;\что-то заполнено")

Программировать проще, чем писать стихи.

Ответить

olya2084

Дата: Среда, 06.09.2023, 22:54 | Сообщение № 8

Группа: Пользователи

Ранг: Участник

Сообщений: 87

Репутация: -2 ±

Замечаний: 20% ±

DrMini, а если нужно перепрыгнуть/пропустить одну/две ячейки- как этот разрыв отразить в формуле? Например: с A2 по H2 и с K2 по L2?

К сообщению приложен файл: 3975782_1.xls (32.5 Kb)

Сообщение отредактировал olya2084 - Среда, 06.09.2023, 23:42

Ответить

cmivadwot

Дата: Четверг, 07.09.2023, 01:02 | Сообщение № 9

Группа: Проверенные

Ранг: Обитатель

Сообщений: 497

Репутация: 93 ±

Замечаний: 0% ±

365

olya2084, вариант с условным форматированием.. и другими вариациями...

К сообщению приложен файл: 9501545.xls (134.0 Kb)

Ответить

DrMini

Дата: Четверг, 07.09.2023, 05:06 | Сообщение № 10

Группа: Друзья

Ранг: Старожил

Сообщений: 1760

Репутация: 244 ±

Замечаний: 0% ±

Excel LTSC 2024 RUS

Цитата olya2084, 06.09.2023 в 22:54, в сообщении № 8 (

)

а если нужно перепрыгнуть/пропустить одну/две ячейки-

Я так полагаю это означает, что эти ячейки выкидываем из расчёта.
Тогда нужно просто изменить диапазон и поменять количество сравниваемых ячеек.
Например так:

Код

=ЕСЛИ(СЧЁТЗ(A2:H2;K2:L2)=0;"все пустые";ЕСЛИ(СЧЁТЗ(A2:H2;K2:L2)=10;"все заполнено";"что-то заполнено"))

Ответить

olya2084

Дата: Четверг, 07.09.2023, 12:11 | Сообщение № 11

Группа: Пользователи

Ранг: Участник

Сообщений: 87

Репутация: -2 ±

Замечаний: 20% ±

DrMini, большое спасибо! Очень оперативно выручили!

Ответить

Незаполненные ячейки (Формулы/Formulas)

Страница 1 из 1
1