Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Извлечь максимальное число из каждых 2 ячеек в столбце - Мир MS Excel

Старая форма входа
  • Страница 1 из 2
  • 1
  • 2
  • »
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Извлечь максимальное число из каждых 2 ячеек в столбце (Формулы/Formulas)
Извлечь максимальное число из каждых 2 ячеек в столбце
DrMini Дата: Четверг, 09.11.2023, 09:30 | Сообщение № 1
Группа: Проверенные
Ранг: Старожил
Сообщений: 1566
Репутация: 179 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Здравствуйте Форумчане и гости форума!
Нужно извлечь из диапазона A2:A13 бОльшее число из каждых двух ячеек в столбце и записать его в соседний столбец.
В примере B2:B7 сделал, как должно получится.
К сообщению приложен файл: maksimalnoe_chislo_iz_kazhdykh.xlsx (11.2 Kb)
 
Ответить
СообщениеЗдравствуйте Форумчане и гости форума!
Нужно извлечь из диапазона A2:A13 бОльшее число из каждых двух ячеек в столбце и записать его в соседний столбец.
В примере B2:B7 сделал, как должно получится.

Автор - DrMini
Дата добавления - 09.11.2023 в 09:30
Nic70y Дата: Четверг, 09.11.2023, 09:38 | Сообщение № 2
Группа: Друзья
Ранг: Экселист
Сообщений: 8650
Репутация: 2207 ±
Замечаний: 0% ±

Excel 2010
Код
=МАКС(ИНДЕКС(A:A;(СТРОКА(A1)-1)*2+2):ИНДЕКС(A:A;(СТРОКА(A1)-1)*2+3))


ЮMoney 41001841029809
 
Ответить
Сообщение
Код
=МАКС(ИНДЕКС(A:A;(СТРОКА(A1)-1)*2+2):ИНДЕКС(A:A;(СТРОКА(A1)-1)*2+3))

Автор - Nic70y
Дата добавления - 09.11.2023 в 09:38
DrMini Дата: Четверг, 09.11.2023, 10:14 | Сообщение № 3
Группа: Проверенные
Ранг: Старожил
Сообщений: 1566
Репутация: 179 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Николай, большое Вам спасибо.
"Прикрутил" к своему файлу — всё отлично считает.
 
Ответить
СообщениеНиколай, большое Вам спасибо.
"Прикрутил" к своему файлу — всё отлично считает.

Автор - DrMini
Дата добавления - 09.11.2023 в 10:14
Serge_007 Дата: Четверг, 09.11.2023, 11:44 | Сообщение № 4
Группа: Админы
Ранг: Местный житель
Сообщений: 16452
Репутация: 2746 ±
Замечаний: ±

Excel 2016
Волатильная альтернатива:
Код
=МАКС(ДВССЫЛ("A"&СТРОКА(A1)*2&":A"&СТРОКА(A1)*2+1))
Код
=МАКС(СМЕЩ(A2;СТРОКА()-2;;2))


ЮMoney:41001419691823 | WMR:126292472390
 
Ответить
СообщениеВолатильная альтернатива:
Код
=МАКС(ДВССЫЛ("A"&СТРОКА(A1)*2&":A"&СТРОКА(A1)*2+1))
Код
=МАКС(СМЕЩ(A2;СТРОКА()-2;;2))

Автор - Serge_007
Дата добавления - 09.11.2023 в 11:44
DrMini Дата: Четверг, 09.11.2023, 13:53 | Сообщение № 5
Группа: Проверенные
Ранг: Старожил
Сообщений: 1566
Репутация: 179 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Волатильная альтернатива

Сергей, огромное спасибо.
Обе формулы работают идеально.
Пытался "методом научного тыка" выбрать максимальное число из трёх или четырёх ячеек подряд но... не хватает знаний.
[p.s.]Если будет время разъясните пожалуйста, как это работает.[/p.s.]
 
Ответить
Сообщение
Волатильная альтернатива

Сергей, огромное спасибо.
Обе формулы работают идеально.
Пытался "методом научного тыка" выбрать максимальное число из трёх или четырёх ячеек подряд но... не хватает знаний.
[p.s.]Если будет время разъясните пожалуйста, как это работает.[/p.s.]

Автор - DrMini
Дата добавления - 09.11.2023 в 13:53
elovkov Дата: Четверг, 09.11.2023, 14:36 | Сообщение № 6
Группа: Друзья
Ранг: Обитатель
Сообщений: 364
Репутация: 50 ±
Замечаний: 0% ±

Excel 2013
С ДВССЫЛ прикольно, интересная функция, много с ней можно, но не в больших объемах)))


Умное лицо это еще не признак ума. Все глупости на земле делаются именно с этим выражением лица
 
Ответить
СообщениеС ДВССЫЛ прикольно, интересная функция, много с ней можно, но не в больших объемах)))

Автор - elovkov
Дата добавления - 09.11.2023 в 14:36
Serge_007 Дата: Четверг, 09.11.2023, 14:37 | Сообщение № 7
Группа: Админы
Ранг: Местный житель
Сообщений: 16452
Репутация: 2746 ±
Замечаний: ±

Excel 2016
разъясните пожалуйста, как это работает
Пояснялка)

Сначала для формулы с ДВССЫЛ()
Если в ячейку второй строки, например С2 ввести вот эту часть формулы ="A"&СТРОКА(A1)*2&":A"&СТРОКА(A1)*2+1, то результатом её работы будет текст "A2:A3"
Далее функция ДВССЫЛ() преобразует текст в ссылку на диапазон, из которого функция МАКС() вернет максимальное значение
Тут всё просто)

Если необходимо иметь не две ячейки в диапазоне, а три, то эту часть формулы: "A"&СТРОКА(A1)*2&":A"&СТРОКА(A1)*2+1 необходимо заменить на такую: "A"&(СТРОКА()-2)*3+2&":A"&(СТРОКА()-2)*3+4
Почему именно так?
Потому что каждый диапазон должен иметь три ячейки, начиная со второй строки
Т.е. нам надо получить пары (первое число в паре - нижняя граница, второе - верхняя) чисел с шагом 3:
2 - 4
5 - 7
8 - 10
и т.д, что бы получить диапазоны
A2:A4
A5:A7
A8:A10
и т.д.

(СТРОКА()-2)*3+2 во второй строке вернет 2, а (СТРОКА()-2)*3+4 вернет 4

Если нужен шаг 4, то действуем по аналогии:
(СТРОКА()-2)*3+2 заменяем на (СТРОКА()-2)*4+2, а (СТРОКА()-2)*3+4 на (СТРОКА()-2)*4+5


ЮMoney:41001419691823 | WMR:126292472390
 
Ответить
Сообщение
разъясните пожалуйста, как это работает
Пояснялка)

Сначала для формулы с ДВССЫЛ()
Если в ячейку второй строки, например С2 ввести вот эту часть формулы ="A"&СТРОКА(A1)*2&":A"&СТРОКА(A1)*2+1, то результатом её работы будет текст "A2:A3"
Далее функция ДВССЫЛ() преобразует текст в ссылку на диапазон, из которого функция МАКС() вернет максимальное значение
Тут всё просто)

Если необходимо иметь не две ячейки в диапазоне, а три, то эту часть формулы: "A"&СТРОКА(A1)*2&":A"&СТРОКА(A1)*2+1 необходимо заменить на такую: "A"&(СТРОКА()-2)*3+2&":A"&(СТРОКА()-2)*3+4
Почему именно так?
Потому что каждый диапазон должен иметь три ячейки, начиная со второй строки
Т.е. нам надо получить пары (первое число в паре - нижняя граница, второе - верхняя) чисел с шагом 3:
2 - 4
5 - 7
8 - 10
и т.д, что бы получить диапазоны
A2:A4
A5:A7
A8:A10
и т.д.

(СТРОКА()-2)*3+2 во второй строке вернет 2, а (СТРОКА()-2)*3+4 вернет 4

Если нужен шаг 4, то действуем по аналогии:
(СТРОКА()-2)*3+2 заменяем на (СТРОКА()-2)*4+2, а (СТРОКА()-2)*3+4 на (СТРОКА()-2)*4+5

Автор - Serge_007
Дата добавления - 09.11.2023 в 14:37
Serge_007 Дата: Четверг, 09.11.2023, 14:44 | Сообщение № 8
Группа: Админы
Ранг: Местный житель
Сообщений: 16452
Репутация: 2746 ±
Замечаний: ±

Excel 2016
С ДВССЫЛ прикольно, интересная функция, много с ней можно, но не в больших объемах)
Да, волатильными функциями лучше поменьше пользоваться, если речь идет о формулах на листе

Интересно что VBA "понимает" простую конкатенацию текстовых частей ссылок и преобразовывает их в "настоящие" ссылки без каких-либо дополнительных функций
Excel так не умеет


ЮMoney:41001419691823 | WMR:126292472390
 
Ответить
Сообщение
С ДВССЫЛ прикольно, интересная функция, много с ней можно, но не в больших объемах)
Да, волатильными функциями лучше поменьше пользоваться, если речь идет о формулах на листе

Интересно что VBA "понимает" простую конкатенацию текстовых частей ссылок и преобразовывает их в "настоящие" ссылки без каких-либо дополнительных функций
Excel так не умеет

Автор - Serge_007
Дата добавления - 09.11.2023 в 14:44
DrMini Дата: Четверг, 09.11.2023, 14:55 | Сообщение № 9
Группа: Проверенные
Ранг: Старожил
Сообщений: 1566
Репутация: 179 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Пояснялка

Спасибо за исчерпывающее объяснение и потраченное на это время.
Проверил всё работает.
Сделал для 5-ти ячеек:
Код
=МАКС(ДВССЫЛ("A"&(СТРОКА()-2)*5+2&":A"&(СТРОКА()-2)*5+6))

Отлично работает.
 
Ответить
Сообщение
Пояснялка

Спасибо за исчерпывающее объяснение и потраченное на это время.
Проверил всё работает.
Сделал для 5-ти ячеек:
Код
=МАКС(ДВССЫЛ("A"&(СТРОКА()-2)*5+2&":A"&(СТРОКА()-2)*5+6))

Отлично работает.

Автор - DrMini
Дата добавления - 09.11.2023 в 14:55
Serge_007 Дата: Четверг, 09.11.2023, 15:09 | Сообщение № 10
Группа: Админы
Ранг: Местный житель
Сообщений: 16452
Репутация: 2746 ±
Замечаний: ±

Excel 2016
Сначала для формулы с ДВССЫЛ()
Пояснялка для формулы со СМЕЩ():
Функция СМЕЩ() "умеет" создавать виртуальные массивы
Формула =СМЕЩ(A2;СТРОКА()-2;;2), написанная во второй строке, создает виртуальный массив начиная с ячейки А2 (первый аргумент), высотой 2 ячейки (четвертый аргумент) и со смещением в 0 строк (второй аргумент) от А2, т.е. виртуальный массив соответствует диапазону А2:А3
Однако, когда при копировании формула оказывается в третьей строке =СМЕЩ(A3;СТРОКА()-2;;2) второй аргумент (смещение по строкам) уже становится равен единице, т.е. смещение происходит на одну строку от А3, что соответствует диапазону А4:А5
Ну и дальше, с каждой строкой смещение становится каждый раз больше на единицу
Тут, вроде всё должно быть понятно)

Что надо изменить в формуле, если берем диапазон не из двух ячеек, а, например, из трех?
Разумеется, что четвертый аргумент изменится с 2 на 3
Но, кроме того, смещение теперь должно быть не на одну строку, а на две, т.е. часть формулы СТРОКА()-2 надо будет заменить на (СТРОКА(A1)-1)*2
Таким образом мы последовательность
0
1
2
3

заменяем на
0
2
4
6

Итоговая формула получается такой:
Код
=МАКС(СМЕЩ(A2;(СТРОКА(A1)-1)*2;;3))

Для четырех ячеек:
Код
=МАКС(СМЕЩ(A2;(СТРОКА(A1)-1)*3;;4))
Далее - по аналогии :)

Если что-то непонятно написал - спрашивайте, постараюсь перефразировать)


ЮMoney:41001419691823 | WMR:126292472390
 
Ответить
Сообщение
Сначала для формулы с ДВССЫЛ()
Пояснялка для формулы со СМЕЩ():
Функция СМЕЩ() "умеет" создавать виртуальные массивы
Формула =СМЕЩ(A2;СТРОКА()-2;;2), написанная во второй строке, создает виртуальный массив начиная с ячейки А2 (первый аргумент), высотой 2 ячейки (четвертый аргумент) и со смещением в 0 строк (второй аргумент) от А2, т.е. виртуальный массив соответствует диапазону А2:А3
Однако, когда при копировании формула оказывается в третьей строке =СМЕЩ(A3;СТРОКА()-2;;2) второй аргумент (смещение по строкам) уже становится равен единице, т.е. смещение происходит на одну строку от А3, что соответствует диапазону А4:А5
Ну и дальше, с каждой строкой смещение становится каждый раз больше на единицу
Тут, вроде всё должно быть понятно)

Что надо изменить в формуле, если берем диапазон не из двух ячеек, а, например, из трех?
Разумеется, что четвертый аргумент изменится с 2 на 3
Но, кроме того, смещение теперь должно быть не на одну строку, а на две, т.е. часть формулы СТРОКА()-2 надо будет заменить на (СТРОКА(A1)-1)*2
Таким образом мы последовательность
0
1
2
3

заменяем на
0
2
4
6

Итоговая формула получается такой:
Код
=МАКС(СМЕЩ(A2;(СТРОКА(A1)-1)*2;;3))

Для четырех ячеек:
Код
=МАКС(СМЕЩ(A2;(СТРОКА(A1)-1)*3;;4))
Далее - по аналогии :)

Если что-то непонятно написал - спрашивайте, постараюсь перефразировать)

Автор - Serge_007
Дата добавления - 09.11.2023 в 15:09
DrMini Дата: Четверг, 09.11.2023, 15:53 | Сообщение № 11
Группа: Проверенные
Ранг: Старожил
Сообщений: 1566
Репутация: 179 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
для формулы со СМЕЩ()

Теперь всё стало понятнее.
Получается, что первый вариант (через 2-ве строки) можно было записать так:
Код
=МАКС(СМЕЩ(A2;(СТРОКА(A1)-1)*1;;2))

Большое спасибо Вам Сергей, за подробное разъяснение.
 
Ответить
Сообщение
для формулы со СМЕЩ()

Теперь всё стало понятнее.
Получается, что первый вариант (через 2-ве строки) можно было записать так:
Код
=МАКС(СМЕЩ(A2;(СТРОКА(A1)-1)*1;;2))

Большое спасибо Вам Сергей, за подробное разъяснение.

Автор - DrMini
Дата добавления - 09.11.2023 в 15:53
Nic70y Дата: Четверг, 09.11.2023, 16:08 | Сообщение № 12
Группа: Друзья
Ранг: Экселист
Сообщений: 8650
Репутация: 2207 ±
Замечаний: 0% ±

Excel 2010
DrMini, умножать на 1 нет смысла


ЮMoney 41001841029809
 
Ответить
СообщениеDrMini, умножать на 1 нет смысла

Автор - Nic70y
Дата добавления - 09.11.2023 в 16:08
Serge_007 Дата: Четверг, 09.11.2023, 16:12 | Сообщение № 13
Группа: Админы
Ранг: Местный житель
Сообщений: 16452
Репутация: 2746 ±
Замечаний: ±

Excel 2016
первый вариант (через 2-ве строки) можно было записать так
Можно
Но, как написал Ник - умножать на 1 нет смысла, да и так в формуле получается 34 символа, а как я записал - 28 ;)

Вам Сергей
Можно на "ты"?
Не первый день уже знакомы yes


ЮMoney:41001419691823 | WMR:126292472390
 
Ответить
Сообщение
первый вариант (через 2-ве строки) можно было записать так
Можно
Но, как написал Ник - умножать на 1 нет смысла, да и так в формуле получается 34 символа, а как я записал - 28 ;)

Вам Сергей
Можно на "ты"?
Не первый день уже знакомы yes

Автор - Serge_007
Дата добавления - 09.11.2023 в 16:12
Gustav Дата: Четверг, 09.11.2023, 16:22 | Сообщение № 14
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2652
Репутация: 1114 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
В Excel 365/2021+ вопрос решается формулой следующего вида (вводится в одну ячейку B2):
Код
=BYROW(СВЕРНСТРОК(A2:A13;2);LAMBDA(row;МАКС(row)))

Функция СВЕРНСТРОК(A2:A13;2) из одного столбца A2:A13 (12 строк) создает виртуальный массив 6 строк x 2 столбца:
[vba]
Код
2    2
4    3
5    1
6    85
9    10
12    10
[/vba]Далее итератор BYROW перебирает все строки, вычисляя для каждой row значение МАКС(row):
[vba]
Код
2
4
5
85
10
12
[/vba]Этот массив и воспроизводится в столбце B, начиная с ячейки B2 и вниз.


МОИ: Ник, Tip box: 41001663842605
 
Ответить
СообщениеВ Excel 365/2021+ вопрос решается формулой следующего вида (вводится в одну ячейку B2):
Код
=BYROW(СВЕРНСТРОК(A2:A13;2);LAMBDA(row;МАКС(row)))

Функция СВЕРНСТРОК(A2:A13;2) из одного столбца A2:A13 (12 строк) создает виртуальный массив 6 строк x 2 столбца:
[vba]
Код
2    2
4    3
5    1
6    85
9    10
12    10
[/vba]Далее итератор BYROW перебирает все строки, вычисляя для каждой row значение МАКС(row):
[vba]
Код
2
4
5
85
10
12
[/vba]Этот массив и воспроизводится в столбце B, начиная с ячейки B2 и вниз.

Автор - Gustav
Дата добавления - 09.11.2023 в 16:22
Serge_007 Дата: Четверг, 09.11.2023, 16:27 | Сообщение № 15
Группа: Админы
Ранг: Местный житель
Сообщений: 16452
Репутация: 2746 ±
Замечаний: ±

Excel 2016
Функция СВЕРНСТРОК(A2:A13;2) из одного столбца A2:A13 (12 строк) создает виртуальный массив 6 строк x 2 столбца
Очень удобная "фишка" для больших массивов
Константин, спасибо за дополнение


ЮMoney:41001419691823 | WMR:126292472390
 
Ответить
Сообщение
Функция СВЕРНСТРОК(A2:A13;2) из одного столбца A2:A13 (12 строк) создает виртуальный массив 6 строк x 2 столбца
Очень удобная "фишка" для больших массивов
Константин, спасибо за дополнение

Автор - Serge_007
Дата добавления - 09.11.2023 в 16:27
Gustav Дата: Четверг, 09.11.2023, 16:37 | Сообщение № 16
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2652
Репутация: 1114 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
Сергей, да не во что! ;) Я уже понял, что это сейчас моя миссия - показывать людям светлое будущее Excel'я, так сказать, разжигать аппетит. Поэтому стараюсь в любой мало-мальски интересной для меня теме отметиться новым синтаксисом.


МОИ: Ник, Tip box: 41001663842605
 
Ответить
СообщениеСергей, да не во что! ;) Я уже понял, что это сейчас моя миссия - показывать людям светлое будущее Excel'я, так сказать, разжигать аппетит. Поэтому стараюсь в любой мало-мальски интересной для меня теме отметиться новым синтаксисом.

Автор - Gustav
Дата добавления - 09.11.2023 в 16:37
DrMini Дата: Четверг, 09.11.2023, 16:46 | Сообщение № 17
Группа: Проверенные
Ранг: Старожил
Сообщений: 1566
Репутация: 179 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
умножать на 1 нет смысла

Умножение на 1 сделал, что бы было более понятно таким, как я сам. Мне так понятнее.
вопрос решается формулой следующего вида

Спасибо за ещё один вариант. Кому то точно пригодится. У меня Офис 2021 плюс. В нём не работает.
Можно на "ты"

Попробую Но не обещаю.
:D :p yes
 
Ответить
Сообщение
умножать на 1 нет смысла

Умножение на 1 сделал, что бы было более понятно таким, как я сам. Мне так понятнее.
вопрос решается формулой следующего вида

Спасибо за ещё один вариант. Кому то точно пригодится. У меня Офис 2021 плюс. В нём не работает.
Можно на "ты"

Попробую Но не обещаю.
:D :p yes

Автор - DrMini
Дата добавления - 09.11.2023 в 16:46
Gustav Дата: Четверг, 09.11.2023, 17:07 | Сообщение № 18
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2652
Репутация: 1114 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
У меня Офис 2021 плюс. В нём не работает

Когда я пишу "365/2021+", то имею в виду как бы "...и все последующие (будущие) версии". Надо для усиления, наверное, писать по-СИшному "по-пацански", типа "365/2021++" :)

А Вы в office.com вхожи? Туда, где бесплатный Microsoft 365 он-лайн? Там всё работает, я там проверяю работоспособность формул. Этот доступ, как я понимаю, автоматически даётся всем, имеющим учетку Microsoft (Live Id). Ну, или в Google Sheets можно - они вообще молодцы, дают всё всем и всегда. У них вышла новая функция - значит, она вышла для всех. А то, что Мелкомягкие с "цветовой дифференциацией штанов" устроили: кому-то добавляем функцию, кому-то нет, кто-то заплати сначала - это удручает крайне (два раза "Ку!").


МОИ: Ник, Tip box: 41001663842605
 
Ответить
Сообщение
У меня Офис 2021 плюс. В нём не работает

Когда я пишу "365/2021+", то имею в виду как бы "...и все последующие (будущие) версии". Надо для усиления, наверное, писать по-СИшному "по-пацански", типа "365/2021++" :)

А Вы в office.com вхожи? Туда, где бесплатный Microsoft 365 он-лайн? Там всё работает, я там проверяю работоспособность формул. Этот доступ, как я понимаю, автоматически даётся всем, имеющим учетку Microsoft (Live Id). Ну, или в Google Sheets можно - они вообще молодцы, дают всё всем и всегда. У них вышла новая функция - значит, она вышла для всех. А то, что Мелкомягкие с "цветовой дифференциацией штанов" устроили: кому-то добавляем функцию, кому-то нет, кто-то заплати сначала - это удручает крайне (два раза "Ку!").

Автор - Gustav
Дата добавления - 09.11.2023 в 17:07
DrMini Дата: Четверг, 09.11.2023, 19:10 | Сообщение № 19
Группа: Проверенные
Ранг: Старожил
Сообщений: 1566
Репутация: 179 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
А Вы в office.com вхожи? Туда, где бесплатный Microsoft 365 он-лайн?

Нет не вхож. Если честно даже не задумывался об этом.
Ну, а там где я работаю, новых офисов в ближайшей перспективе не предвидится.
Константин, ваши комментарии всегда читаю с интересом. Спасибо Вам за это. А вдруг пригодится?!
(два раза "Ку!")

:D
 
Ответить
Сообщение
А Вы в office.com вхожи? Туда, где бесплатный Microsoft 365 он-лайн?

Нет не вхож. Если честно даже не задумывался об этом.
Ну, а там где я работаю, новых офисов в ближайшей перспективе не предвидится.
Константин, ваши комментарии всегда читаю с интересом. Спасибо Вам за это. А вдруг пригодится?!
(два раза "Ку!")

:D

Автор - DrMini
Дата добавления - 09.11.2023 в 19:10
bmv98rus Дата: Четверг, 09.11.2023, 21:07 | Сообщение № 20
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4095
Репутация: 766 ±
Замечаний: 0% ±

Excel 2013/2016
Я уже понял, что это сейчас моя миссия - показывать людям светлое будущее Excel'я, так сказать, разжигать аппетит.
Это прям как пармезаном дразнить. Если учесть факт, что на смену выстраданному многолетним трудом спецов Excel приходит насажденный даже не Libre. а P7 или МойОфис , которые конечно могут стать альтернативой, но оооочень вялой альтернативой, то я даже не знаю, что и сказать о недосягаемом светлом будущем :(

много с ней можно, но не в больших объемах)))

Вопрос не в объемах. Сейчас не найду но на планете был пример, когда замена множества OFFSET на нелетучий вариант приводила к еще большим тормозам. Самое то стращное не то, что она медленная, а то что пересчитывается при любом пересчете в приложении. наберете в новой книге =1+1 а открытой начнутся пересчеты OFFSET. А потом вопрос , почему 1+1 так долго считает.


Замечательный Временно просто медведь , процентов на 20.

Сообщение отредактировал bmv98rus - Четверг, 09.11.2023, 21:19
 
Ответить
Сообщение
Я уже понял, что это сейчас моя миссия - показывать людям светлое будущее Excel'я, так сказать, разжигать аппетит.
Это прям как пармезаном дразнить. Если учесть факт, что на смену выстраданному многолетним трудом спецов Excel приходит насажденный даже не Libre. а P7 или МойОфис , которые конечно могут стать альтернативой, но оооочень вялой альтернативой, то я даже не знаю, что и сказать о недосягаемом светлом будущем :(

много с ней можно, но не в больших объемах)))

Вопрос не в объемах. Сейчас не найду но на планете был пример, когда замена множества OFFSET на нелетучий вариант приводила к еще большим тормозам. Самое то стращное не то, что она медленная, а то что пересчитывается при любом пересчете в приложении. наберете в новой книге =1+1 а открытой начнутся пересчеты OFFSET. А потом вопрос , почему 1+1 так долго считает.

Автор - bmv98rus
Дата добавления - 09.11.2023 в 21:07
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Извлечь максимальное число из каждых 2 ячеек в столбце (Формулы/Formulas)
  • Страница 1 из 2
  • 1
  • 2
  • »
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!