Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Линейная интерполяция - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Линейная интерполяция (Формулы/Formulas)
Линейная интерполяция
andreinickolaevich2016 Дата: Среда, 22.11.2023, 22:35 | Сообщение № 1
Группа: Пользователи
Ранг: Прохожий
Сообщений: 5
Репутация: 0 ±
Замечаний: 0% ±

Добрый день.Подскажите как можно формулу линейной интерполяции = y1 + (x – x1) ⨯ (y2 – y1) / (x2 – x1) использовать для 100 точек Х и Y у меня эксель 2021 русская версия.
 
Ответить
СообщениеДобрый день.Подскажите как можно формулу линейной интерполяции = y1 + (x – x1) ⨯ (y2 – y1) / (x2 – x1) использовать для 100 точек Х и Y у меня эксель 2021 русская версия.
Автор - andreinickolaevich2016
Дата добавления - 22.11.2023 в 22:35
elovkov Дата: Четверг, 23.11.2023, 08:02 | Сообщение № 2
Группа: Друзья
Ранг: Обитатель
Сообщений: 398
Репутация: 54 ±
Замечаний: 0% ±

Excel 2013
Написать и протянуть на все точки, у меня 2013 - работает

Умное лицо это еще не признак ума. Все глупости на земле делаются именно с этим выражением лица
 
Ответить
СообщениеНаписать и протянуть на все точки, у меня 2013 - работает
Автор - elovkov
Дата добавления - 23.11.2023 в 08:02
andreinickolaevich2016 Дата: Воскресенье, 03.12.2023, 22:43 | Сообщение № 3
Группа: Пользователи
Ранг: Прохожий
Сообщений: 5
Репутация: 0 ±
Замечаний: 0% ±

Цитата elovkov, 23.11.2023 в 08:02, в сообщении № 2 ()
Написать и протянуть на все точки, у меня 2013 - работает
Вот файл нужно что бы в этой формуле уместились 100 точек х и y и промежуточная точка которую ищем Х1 отображалась на графике.
К сообщению приложен файл: linejnaja.xlsx (17.0 Kb)
 
Ответить
Сообщение
Цитата elovkov, 23.11.2023 в 08:02, в сообщении № 2 ()
Написать и протянуть на все точки, у меня 2013 - работает
Вот файл нужно что бы в этой формуле уместились 100 точек х и y и промежуточная точка которую ищем Х1 отображалась на графике.
Автор - andreinickolaevich2016
Дата добавления - 03.12.2023 в 22:43
Pelena Дата: Понедельник, 04.12.2023, 07:58 | Сообщение № 4
Группа: Админы
Ранг: Местный житель
Сообщений: 19281
Репутация: 4446 ±
Замечаний: ±

Excel 365 & Mac Excel
Посмотрите, так хотели?
К сообщению приложен файл: 2033888.xlsx (22.7 Kb)

"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
СообщениеПосмотрите, так хотели?
Автор - Pelena
Дата добавления - 04.12.2023 в 07:58
andreinickolaevich2016 Дата: Понедельник, 04.12.2023, 20:23 | Сообщение № 5
Группа: Пользователи
Ранг: Прохожий
Сообщений: 5
Репутация: 0 ±
Замечаний: 0% ±

Цитата Pelena, 04.12.2023 в 07:58, в сообщении № 4 ()
Посмотрите, так хотели?

Добрый день.Нет не совсем так.Мне нужно ту формулу что я написал для расчета линейной интерполяции применить ко все 100 точкам.Мне нужна формула расчет ко все точкам что я обозначил в желтом квадрате по ней должны считаться точки.
К сообщению приложен файл: 5001468.xlsx (20.8 Kb)
 
Ответить
Сообщение
Цитата Pelena, 04.12.2023 в 07:58, в сообщении № 4 ()
Посмотрите, так хотели?

Добрый день.Нет не совсем так.Мне нужно ту формулу что я написал для расчета линейной интерполяции применить ко все 100 точкам.Мне нужна формула расчет ко все точкам что я обозначил в желтом квадрате по ней должны считаться точки.
Автор - andreinickolaevich2016
Дата добавления - 04.12.2023 в 20:23
Gustav Дата: Вторник, 05.12.2023, 00:17 | Сообщение № 6
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2766
Репутация: 1140 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
Тоже сделаю попытку. Коль скоро Excel - 2021, то, по идее, должна работать следующая формула для ячейки K2:
[vba]
Код
=LET(
x; J2;
arrX; $F$4:$F$13;
arrY; $G$4:$G$13;
maxI; СЧЁТ(arrX);
posX; ЕСНД(ПОИСКПОЗX(x;arrX;-1);0);
p_1; ЕСЛИМН(posX=0;1; posX=maxI;maxI-1; ИСТИНА;posX);
p_2; p_1+1;
x_1; ИНДЕКС(arrX; p_1);
x_2; ИНДЕКС(arrX; p_2);
y_1; ИНДЕКС(arrY; p_1);
y_2; ИНДЕКС(arrY; p_2);
y_1 + (x-x_1) / (x_2-x_1) * (y_2-y_1)
)
[/vba]Это для тестирования значений "x", вводимых в ячейку J2.

А если в ячейку A1 ввести такую формулу:
[vba]
Код
=СВЕРНСТОЛБЦ(ВСТОЛБИК(ПОСЛЕД(101;1;0);MAP(ПОСЛЕД(101;1;0);LAMBDA(a;
LET(
x; a;
arrX; $F$4:$F$13;
arrY; $G$4:$G$13;
maxI; СЧЁТ(arrX);
posX; ЕСНД(ПОИСКПОЗX(x;arrX;-1);0);
p_1; ЕСЛИМН(posX=0;1; posX=maxI;maxI-1; ИСТИНА;posX);
p_2; p_1+1;
x_1; ИНДЕКС(arrX; p_1);
x_2; ИНДЕКС(arrX; p_2);
y_1; ИНДЕКС(arrY; p_1);
y_2; ИНДЕКС(arrY; p_2);
y_1 + (x-x_1) / (x_2-x_1) * (y_2-y_1)
)
)));101)
[/vba]то в колонках A:B получится таблица значений, рассчитанных интерполяцией/экстраполяцией по исходной таблице:

МОИ: Ник, Tip box: 41001663842605

Сообщение отредактировал Gustav - Вторник, 05.12.2023, 01:30
 
Ответить
СообщениеТоже сделаю попытку. Коль скоро Excel - 2021, то, по идее, должна работать следующая формула для ячейки K2:
[vba]
Код
=LET(
x; J2;
arrX; $F$4:$F$13;
arrY; $G$4:$G$13;
maxI; СЧЁТ(arrX);
posX; ЕСНД(ПОИСКПОЗX(x;arrX;-1);0);
p_1; ЕСЛИМН(posX=0;1; posX=maxI;maxI-1; ИСТИНА;posX);
p_2; p_1+1;
x_1; ИНДЕКС(arrX; p_1);
x_2; ИНДЕКС(arrX; p_2);
y_1; ИНДЕКС(arrY; p_1);
y_2; ИНДЕКС(arrY; p_2);
y_1 + (x-x_1) / (x_2-x_1) * (y_2-y_1)
)
[/vba]Это для тестирования значений "x", вводимых в ячейку J2.

А если в ячейку A1 ввести такую формулу:
[vba]
Код
=СВЕРНСТОЛБЦ(ВСТОЛБИК(ПОСЛЕД(101;1;0);MAP(ПОСЛЕД(101;1;0);LAMBDA(a;
LET(
x; a;
arrX; $F$4:$F$13;
arrY; $G$4:$G$13;
maxI; СЧЁТ(arrX);
posX; ЕСНД(ПОИСКПОЗX(x;arrX;-1);0);
p_1; ЕСЛИМН(posX=0;1; posX=maxI;maxI-1; ИСТИНА;posX);
p_2; p_1+1;
x_1; ИНДЕКС(arrX; p_1);
x_2; ИНДЕКС(arrX; p_2);
y_1; ИНДЕКС(arrY; p_1);
y_2; ИНДЕКС(arrY; p_2);
y_1 + (x-x_1) / (x_2-x_1) * (y_2-y_1)
)
)));101)
[/vba]то в колонках A:B получится таблица значений, рассчитанных интерполяцией/экстраполяцией по исходной таблице:
Автор - Gustav
Дата добавления - 05.12.2023 в 00:17
andreinickolaevich2016 Дата: Вторник, 05.12.2023, 17:05 | Сообщение № 7
Группа: Пользователи
Ранг: Прохожий
Сообщений: 5
Репутация: 0 ±
Замечаний: 0% ±

Цитата Gustav, 05.12.2023 в 00:17, в сообщении № 6 ()
Тоже сделаю попытку. Коль скоро Excel - 2021, то, по идее, должна работать следующая формула для ячейки K2:
=LET(

Как это в формулу оформить в экселе?
 
Ответить
Сообщение
Цитата Gustav, 05.12.2023 в 00:17, в сообщении № 6 ()
Тоже сделаю попытку. Коль скоро Excel - 2021, то, по идее, должна работать следующая формула для ячейки K2:
=LET(

Как это в формулу оформить в экселе?
Автор - andreinickolaevich2016
Дата добавления - 05.12.2023 в 17:05
Gustav Дата: Вторник, 05.12.2023, 17:51 | Сообщение № 8
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2766
Репутация: 1140 ±
Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1
Ну, как обычная формула вводится? Встаем на ячейку K2, нажимаем клавишу F2 для перехода в режим редактирования. Здесь копируем текст формулы (прямо так, как есть, со всеми переносами строк), возвращаемся в ячейку K2, вставляем, нажимаем Enter.

МОИ: Ник, Tip box: 41001663842605
 
Ответить
СообщениеНу, как обычная формула вводится? Встаем на ячейку K2, нажимаем клавишу F2 для перехода в режим редактирования. Здесь копируем текст формулы (прямо так, как есть, со всеми переносами строк), возвращаемся в ячейку K2, вставляем, нажимаем Enter.
Автор - Gustav
Дата добавления - 05.12.2023 в 17:51
andreinickolaevich2016 Дата: Вторник, 05.12.2023, 22:12 | Сообщение № 9
Группа: Пользователи
Ранг: Прохожий
Сообщений: 5
Репутация: 0 ±
Замечаний: 0% ±

Цитата Gustav, 05.12.2023 в 17:51, в сообщении № 8 ()
Ну, как обычная формула вводится? Встаем на ячейку K2, нажимаем клавишу F2 для перехода в режим редактирования. Здесь копируем текст формулы (прямо так, как есть, со всеми переносами строк), возвращаемся в ячейку K2, вставляем, нажимаем Enter.
Подскажите как мне поставить точку на графике.Выделяю две точки J2 K2 но они не появляются на графике.Может какая функция в экселе не включена?Точка не отображается.
К сообщению приложен файл: 2033888_1.xlsx (23.4 Kb)
 
Ответить
Сообщение
Цитата Gustav, 05.12.2023 в 17:51, в сообщении № 8 ()
Ну, как обычная формула вводится? Встаем на ячейку K2, нажимаем клавишу F2 для перехода в режим редактирования. Здесь копируем текст формулы (прямо так, как есть, со всеми переносами строк), возвращаемся в ячейку K2, вставляем, нажимаем Enter.
Подскажите как мне поставить точку на графике.Выделяю две точки J2 K2 но они не появляются на графике.Может какая функция в экселе не включена?Точка не отображается.
Автор - andreinickolaevich2016
Дата добавления - 05.12.2023 в 22:12
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Линейная интерполяция (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!