Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Преобразовать текст (ФИО) - Мир MS Excel

  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_, DrMini  
Преобразовать текст (ФИО)
Muhan Дата: Вторник, 17.11.2026, 17:52 | Сообщение № 1
Группа: Проверенные
Ранг: Участник
Сообщений: 78
Репутация: 0 ±
Замечаний: 0% ±

Доброго времени суток!
Уважаемые знатоки, помогите пжл преобразовать ФИО.
Как преобразовать ФИО в инициалы на другом столбце формулами?
При этом , первым идет имя (полностью) ,затем Ф. затем О.
файл прикрепил
К сообщению приложен файл: fio_pereobrazovat.xlsx (9.4 Kb)
 
Ответить
СообщениеДоброго времени суток!
Уважаемые знатоки, помогите пжл преобразовать ФИО.
Как преобразовать ФИО в инициалы на другом столбце формулами?
При этом , первым идет имя (полностью) ,затем Ф. затем О.
файл прикрепил

Автор - Muhan
Дата добавления - 17.11.2026 в 17:52
bigor Дата: Вторник, 17.11.2026, 18:00 | Сообщение № 2
Группа: Проверенные
Ранг: Старожил
Сообщений: 1461
Репутация: 294 ±
Замечаний: 0% ±

нет
первым идет имя (полностью) ,затем Ф. затем О.
можно так
Код
=TRIM(MID(SUBSTITUTE(B2;" ";REPT(" ";100));100;100)&LEFT(B2;1)&". "&LEFT(TRIM(RIGHT(SUBSTITUTE(B2;" ";REPT(" ";100));100));1))&"."
 
Ответить
Сообщение
первым идет имя (полностью) ,затем Ф. затем О.
можно так
Код
=TRIM(MID(SUBSTITUTE(B2;" ";REPT(" ";100));100;100)&LEFT(B2;1)&". "&LEFT(TRIM(RIGHT(SUBSTITUTE(B2;" ";REPT(" ";100));100));1))&"."

Автор - bigor
Дата добавления - 17.11.2026 в 18:00
Muhan Дата: Вторник, 17.11.2026, 18:10 | Сообщение № 3
Группа: Проверенные
Ранг: Участник
Сообщений: 78
Репутация: 0 ±
Замечаний: 0% ±

bigor, Точно! Спасибо большое!
 
Ответить
Сообщениеbigor, Точно! Спасибо большое!

Автор - Muhan
Дата добавления - 17.11.2026 в 18:10
DrMini Дата: Вторник, 17.11.2026, 20:31 | Сообщение № 4
Группа: Модераторы
Ранг: Старожил
Сообщений: 2203
Репутация: 395 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Здравствуйте Muhan.
Как вариант формулой:
Код
=ИНДЕКС(ТЕКСТРАЗД(СЖПРОБЕЛЫ(B2);" ");2)&" "&ЛЕВСИМВ(ИНДЕКС(ТЕКСТРАЗД(СЖПРОБЕЛЫ(B2);" ");1);1)&"."&ЛЕВСИМВ(ИНДЕКС(ТЕКСТРАЗД(СЖПРОБЕЛЫ(B2);" ");3);1)&"."

или паразитируя на варианте bigor если фамилия и отчество не более 50 символов:
Код
=СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(B2;" ";ПОВТОР(" ";50));50;50)&ЛЕВСИМВ(B2)&". "&ПСТР(B2;ПОИСК(" ";B2;ПОИСК(" ";B2)+1)+1;1))&"."

и вариант без формул:
Пишите в ячейку C1:
Петр И. С.
За тем выделяете (в Вашем варианте C1:C3 (можно и больше)) и нажимаете Ctrl+E и всё заполнено.
UPD: для новых версий Excel (у меня Excel 2024)
Код
=ИНДЕКС(ТЕКСТРАЗД(B2;" ");2)&" "&ЛЕВСИМВ(ИНДЕКС(ТЕКСТРАЗД(B2;" ");1))&". "&ЛЕВСИМВ(ИНДЕКС(ТЕКСТРАЗД(B2;" ");3))&"."

или совсем короче через LET:
Код
=LET(т;ТЕКСТРАЗД(B2;" ");ИНДЕКС(т;2)&" "&ЛЕВСИМВ(ИНДЕКС(т;1))&". "&ЛЕВСИМВ(ИНДЕКС(т;3))&".")
 
Ответить
СообщениеЗдравствуйте Muhan.
Как вариант формулой:
Код
=ИНДЕКС(ТЕКСТРАЗД(СЖПРОБЕЛЫ(B2);" ");2)&" "&ЛЕВСИМВ(ИНДЕКС(ТЕКСТРАЗД(СЖПРОБЕЛЫ(B2);" ");1);1)&"."&ЛЕВСИМВ(ИНДЕКС(ТЕКСТРАЗД(СЖПРОБЕЛЫ(B2);" ");3);1)&"."

или паразитируя на варианте bigor если фамилия и отчество не более 50 символов:
Код
=СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(B2;" ";ПОВТОР(" ";50));50;50)&ЛЕВСИМВ(B2)&". "&ПСТР(B2;ПОИСК(" ";B2;ПОИСК(" ";B2)+1)+1;1))&"."

и вариант без формул:
Пишите в ячейку C1:
Петр И. С.
За тем выделяете (в Вашем варианте C1:C3 (можно и больше)) и нажимаете Ctrl+E и всё заполнено.
UPD: для новых версий Excel (у меня Excel 2024)
Код
=ИНДЕКС(ТЕКСТРАЗД(B2;" ");2)&" "&ЛЕВСИМВ(ИНДЕКС(ТЕКСТРАЗД(B2;" ");1))&". "&ЛЕВСИМВ(ИНДЕКС(ТЕКСТРАЗД(B2;" ");3))&"."

или совсем короче через LET:
Код
=LET(т;ТЕКСТРАЗД(B2;" ");ИНДЕКС(т;2)&" "&ЛЕВСИМВ(ИНДЕКС(т;1))&". "&ЛЕВСИМВ(ИНДЕКС(т;3))&".")

Автор - DrMini
Дата добавления - 17.11.2026 в 20:31
Nic70y Дата: Среда, 18.11.2026, 08:18 | Сообщение № 5
Группа: Друзья
Ранг: Экселист
Сообщений: 9312
Репутация: 2523 ±
Замечаний: 0% ±

Excel 2010
для разнообразия
Код
=ПСТР(ПОДСТАВИТЬ(ЛЕВСИМВ(B2;ПОИСК("\";ПОДСТАВИТЬ(B2;" ";"\";2))+1);" ";" "&ЛЕВСИМВ(B2)&". ";2);ПОИСК(" ";B2)+1;99)&"."
 
Ответить
Сообщениедля разнообразия
Код
=ПСТР(ПОДСТАВИТЬ(ЛЕВСИМВ(B2;ПОИСК("\";ПОДСТАВИТЬ(B2;" ";"\";2))+1);" ";" "&ЛЕВСИМВ(B2)&". ";2);ПОИСК(" ";B2)+1;99)&"."

Автор - Nic70y
Дата добавления - 18.11.2026 в 08:18
прохожий2019 Дата: Среда, 18.11.2026, 13:35 | Сообщение № 6
Группа: Проверенные
Ранг: Старожил
Сообщений: 1424
Репутация: 377 ±
Замечаний: 0% ±

365 Beta Channel
Код
=РЕГЗАМЕНИТЬ(B2;"(.)\w+\s(\w+)\s(.)\w+";"$2 $1. $3.")
или просто
Код
=РЕГЗАМЕНИТЬ(B2;"(.)\w+ (\w+) (.)\w+";"$2 $1. $3.")


Сообщение отредактировал прохожий2019 - Среда, 18.11.2026, 13:40
 
Ответить
Сообщение
Код
=РЕГЗАМЕНИТЬ(B2;"(.)\w+\s(\w+)\s(.)\w+";"$2 $1. $3.")
или просто
Код
=РЕГЗАМЕНИТЬ(B2;"(.)\w+ (\w+) (.)\w+";"$2 $1. $3.")

Автор - прохожий2019
Дата добавления - 18.11.2026 в 13:35
msi2102 Дата: Среда, 18.11.2026, 14:32 | Сообщение № 7
Группа: Проверенные
Ранг: Обитатель
Сообщений: 478
Репутация: 142 ±
Замечаний: 0% ±

Excel 2019
Чтобы было
[vba]
Код
=СЦЕП(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(B2;" ";"</s><s>")&"</s></t>";"//s[2]");" ";ЛЕВСИМВ(B2;1);". ";ЛЕВСИМВ(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(B2;" ";"</s><s>")&"</s></t>";"//s[3]");1);".")
[/vba]
 
Ответить
СообщениеЧтобы было
[vba]
Код
=СЦЕП(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(B2;" ";"</s><s>")&"</s></t>";"//s[2]");" ";ЛЕВСИМВ(B2;1);". ";ЛЕВСИМВ(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(B2;" ";"</s><s>")&"</s></t>";"//s[3]");1);".")
[/vba]

Автор - msi2102
Дата добавления - 18.11.2026 в 14:32
Gustav Дата: Четверг, 19.11.2026, 00:52 | Сообщение № 8
Группа: Админы
Ранг: Участник клуба
Сообщений: 2918
Репутация: 1227 ±
Замечаний: ±

начинал с Excel 4.0, видел 2.1
или совсем короче через LET:

=LET(т;ТЕКСТРАЗД(B2;" ");ИНДЕКС(т;2)&" "&ЛЕВСИМВ(ИНДЕКС(т;1))&". "&ЛЕВСИМВ(ИНДЕКС(т;3))&".")

Мои "5 копеек". Не то, чтобы короче, но с претензией на концептуальность - параметрическая функция F внутри LET для повторяющихся вычислений:
[vba]
Код
=LET(
т; ТЕКСТРАЗД(B2;" ");
F; LAMBDA(i;n;s; ЛЕВСИМВ(ИНДЕКС(т;i); n) & s);
F(2;99;" ") & F(1;1;".") & F(3;1;".")
)
[/vba]


МОИ: Ник, Tip box: 41001663842605
 
Ответить
Сообщение
или совсем короче через LET:

=LET(т;ТЕКСТРАЗД(B2;" ");ИНДЕКС(т;2)&" "&ЛЕВСИМВ(ИНДЕКС(т;1))&". "&ЛЕВСИМВ(ИНДЕКС(т;3))&".")

Мои "5 копеек". Не то, чтобы короче, но с претензией на концептуальность - параметрическая функция F внутри LET для повторяющихся вычислений:
[vba]
Код
=LET(
т; ТЕКСТРАЗД(B2;" ");
F; LAMBDA(i;n;s; ЛЕВСИМВ(ИНДЕКС(т;i); n) & s);
F(2;99;" ") & F(1;1;".") & F(3;1;".")
)
[/vba]

Автор - Gustav
Дата добавления - 19.11.2026 в 00:52
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2026 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!