Sub Mail_Selection_Range_Outlook_Body()
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
'Don't forget to copy the function RangetoHTML in the module.
'Working in Excel 2000-2016
    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object

    Set rng = Nothing
    On Error Resume Next
    'Only the visible cells in the selection
    Set rng = Selection.SpecialCells(xlCellTypeVisible)
    'Тут указываем лист и диапазон
    Set rng = Sheets("название листа").Range("E41:S190").SpecialCells(xlCellTypeVisible)
    On Error GoTo 0

    If rng Is Nothing Then
        MsgBox "The selection is not a range or the sheet is protected" & _
               vbNewLine & "please correct and try again.", vbOKOnly
        Exit Sub
    End If

    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .To = "mymail@gmail.com"
        .CC = ""
        .BCC = ""
        .Subject = "This is the Subject line"
        .HTMLBody = RangetoHTML(rng)
        .Send   'or use .Display
    End With
    On Error GoTo 0

    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

Sub sendMail()

    Dim outApp  As Object 'Outlook.Application
    Dim outMail As Object 'Outlook.MailItem
    Dim myRange As Range
    
    Const ol_MailItem As Long = 0 'olMailItem
            
    Set myRange = Range("A1:C5") 'задаем диапазон Excel, из которого экспортируем значения
            
    Set outApp = CreateObject("Outlook.Application") 'New Outlook.Application
    Set outMail = outApp.CreateItem(ol_MailItem)
            
    With outMail
        .To = ".....@gmail.com" 'почтовый ящик на GMail
        .Subject = getSubject 'уникальный идентификатор отправки (для последующего контроля в Google)
        .Body = getBody(myRange) 'текстовое содержание заданного диапазона Excel
        .Display
    End With
    
    Set outMail = Nothing
    Set outApp = Nothing
End Sub

Function getSubject() As String 'уникальный идентификатор отправки
    getSubject = "add" & Format(Now, "_yyyymmdd_hhnnss_") & Right(Format(Timer, "#0.00"), 2)
End Function

Function getBody(rng As Range) As String 'текстовое содержание диапазона Excel
    Dim a
    Dim i As Integer
    Dim j As Integer
    Dim strAll As String
    Dim strRow As String
    
    Const rowSep As String = vbCrLf 'общепринятый разделитель строк - перевод строки
    Const colSep As String = "~" 'необычный разделитель колонок (ибо обычный vbTab превращается в серию пробелов)
    
    a = rng.Value
    
    strAll = ""
    For i = 1 To UBound(a, 1)
        strRow = ""
        For j = 1 To UBound(a, 2)
            strRow = strRow & colSep & a(i, j)
        Next j
        strRow = Mid(strRow, 2)
        strAll = strAll & rowSep & strRow
    Next i
    strAll = Mid(strAll, 3)
    getBody = strAll 'длинная-предлинная строка
End Function

1~Пролетарии~05.08.2017
2~всех~06.08.2017
3~стран~07.08.2017
4~соединяйтесь~08.08.2017
5~все вместе~09.08.2017

return SpreadsheetApp.openById(fileDataResponse.id);