Поиск данных в нескольких листах Google Таблицы.

Старая форма входа

Страница 1 из 1 1
Модератор форума: _Boroda_, китин

Мир MS Excel » Вопросы и решения » Excel и другие приложения » Google Docs » Поиск данных в нескольких листах Google Таблицы. (Сводные таблицы/Pivot Table)

Professor

Дата: Суббота, 13.11.2021, 20:00 | Сообщение № 1

Группа: Пользователи

Ранг: Прохожий

Сообщений: 3

Репутация: 0 ±

Замечаний: 0% ±

[color=black Доброго времени суток.
Помогите решить задачу по работе с Google таблицами.
Есть книга, в ней 4 листа.
1. Общий список
2. Поврежденные
3. На ремонте
4. Готовые
Нужно сопоставить номера заказов в лист "общий список" из остальных листов.
Проще говоря в Ячейке рядом с № заказа, Должен стоять статус (В каком листе), данный заказ находится.
Какую формулу нужно использовать всю голову сломал.
№ заказов в листах расположены в хаотичном порядке, поэтому искать нужно в диапазоне столбца.

Ответить

aliramora191

Дата: Суббота, 13.11.2021, 20:07 | Сообщение № 2

Группа: Проверенные

Ранг: Новичок

Сообщений: 36

Репутация: 17 ±

Замечаний: 0% ±

2016

Добрый вечер! Приложите ссылку на таблицу

Анастасия

Ответить

Professor

Дата: Суббота, 13.11.2021, 21:07 | Сообщение № 3

Группа: Пользователи

Ранг: Прохожий

Сообщений: 3

Репутация: 0 ±

Замечаний: 0% ±

aliramora191, https://docs.google.com/spreads....sharing

Ответить

aliramora191

Дата: Суббота, 13.11.2021, 21:42 | Сообщение № 4

Группа: Проверенные

Ранг: Новичок

Сообщений: 36

Репутация: 17 ±

Замечаний: 0% ±

2016

Код

=ЕСЛИ(СЧЁТЕСЛИ('Поврежденый Девайс'!$B$4:$B; $B4)>0;"Поврежденные";ЕСЛИ(СЧЁТЕСЛИ('Девайс на ремонте'!$B$3:$B; $B4)>0;"На ремонте";ЕСЛИ(СЧЁТЕСЛИ('Готовый девайс'!$B$3:$B; $B4)>0;"Готовые";"Нет статуса")))

Анастасия

Сообщение отредактировал aliramora191 - Суббота, 13.11.2021, 21:43

Ответить

Professor

Дата: Суббота, 13.11.2021, 21:47 | Сообщение № 5

Группа: Пользователи

Ранг: Прохожий

Сообщений: 3

Репутация: 0 ±

Замечаний: 0% ±

aliramora191, Так просто?) Спасибо огромное)
Я вообще не в ту сторону смотрел)

Ответить

Gustav

Дата: Воскресенье, 14.11.2021, 20:25 | Сообщение № 6

Группа: Друзья

Ранг: Участник клуба

Сообщений: 2742

Репутация: 1137 ±

Замечаний: 0% ±

начинал с Excel 4.0, видел 2.1

Цитата Professor, 13.11.2021 в 21:47, в сообщении № 5 (

)

Я вообще не в ту сторону смотрел

Я тоже. Поэтому вот еще решеньеце на формуле массива - "из другой стороны". Формула вводится в единственную ячейку D4 листа "Сводная таблица" и дальше саморасширяется в зависимости от заполняемости колонки A:
[vba]

Код

=ArrayFormula( IFERROR( VLOOKUP( B4:INDEX(B:B;MAX(ROW(A4);ROW(A:A)*(A:A<>""))); QUERY({
'Поврежденый Девайс'!B:B\TRANSPOSE(SPLIT(REPT("Поврежденные|";ROWS('Поврежденый Девайс'!B:B));"|"));
'Девайс на ремонте'!B:B\TRANSPOSE(SPLIT(REPT("На ремонте|";ROWS('Девайс на ремонте'!B:B));"|"));
'Готовый девайс'!B:B\TRANSPOSE(SPLIT(REPT("Готовые|";ROWS('Готовый девайс'!B:B));"|"))
};"where Col1 <> ''");2;FALSE); "Нет статуса") )

[/vba]

Или версия попроще - с меньшим количеством используемых функций:
[vba]

Код

=ArrayFormula( IFERROR( VLOOKUP( B4:INDEX(B:B;MAX(ROW(A4);ROW(A:A)*(A:A<>""))); QUERY({
'Поврежденый Девайс'!B:B\T(ROW('Поврежденый Девайс'!B:B))&"Поврежденные";
'Девайс на ремонте'!B:B\T(ROW('Девайс на ремонте'!B:B))&"На ремонте";
'Готовый девайс'!B:B\T(ROW('Готовый девайс'!B:B))&"Готовые"
};"where Col1 <> ''");2;FALSE); "Нет статуса") )

[/vba]

МОИ: Ник, Tip box: 41001663842605

Сообщение отредактировал Gustav - Воскресенье, 14.11.2021, 20:47

Ответить

Страница 1 из 1
1