' если в таблице только числа и пустые ячейки, то можно так:
' (но все равно остается оч. много ограничений на условие...
' например, условие: ="" не сработает НИКОГДА, условие <>"" удалит ВСЕ(!) строки,
' а условие: =0 удалит строки не только с ячейками =0, но и с пустыми ячейками)
Sub Удаление_строки_по_условию()
        Dim i As Long, kol As Long, Stolbec As Long
        Dim Uclovie As String, i_n&
        Stolbec = InputBox("Укажите номер столбца, в котором будем искать условие", "Номер столбца", "1")
        Uclovie = InputBox("Укажите, выражение, согласно которому будем удалять строки", "Условие", "=1")
        i_n = Cells(Rows.Count, 1).End(xlUp).Row
        Application.ScreenUpdating = False
        For i = i_n To 1 Step -1
            If Evaluate((Cells(i, Stolbec) * 1) & Uclovie) Then
                Rows(i).Delete
                kol = kol + 1
            End If
        Next
        Application.ScreenUpdating = True
        MsgBox ("Удалено " & kol & " строк")
End Sub

' если в таблице может быть и текст (тем более с пробелами), то нужно так:
' (в качестве условия можно задать и поиск пустой строки,
' т.е. корректно обработаются такие условия, как: ="" ; <>"" ; >=1 ; <="1" ; =какой-то текст ; ="какой-то текст" ; и т.д.,
' а также, если первый символ условия не >, < или =, то введенное значение будет заключено в кавычки,
' а перед ними будет добавлен символ =, например, если введено слово: доллар, то оно будет преобразовано в: ="доллар",
' а если нужно разрешить вводить не только <>, но и !=, то необходимо раскомментировать соответствующую строчку, см. ниже)
Sub Удаление_строки_по_условию()
        Dim i As Long, i_n As Long, kol As Long, Stolbec As Long
        Dim Uclovie As String
            
        Uclovie = InputBox("Укажите номер столбца, в котором будем искать условие", "Номер столбца", "1")
        ' если, вдруг, пользователь передумал и нажал "Отмена", или очистил поле и нажал "ОК",
        ' то не выполняем никаких действий
        If Len(Uclovie) Then
            ' если пользователь ввел не число
            If IsNumeric(Uclovie) Then
                Stolbec = Uclovie
            Else
                MsgBox "Введенное значение не является числом!", vbExclamation, ThisWorkbook.Name
                Exit Sub
            End If
                
            Uclovie = InputBox("Укажите, выражение, согласно которому будем удалять строки", "Условие", "=1")
            If Len(Uclovie) Then
                ' если нужно разрешить вводить не только <>, но и !=, то необходимо раскомментировать следующую строчку
                'Uclovie = Replace(Uclovie, "!=", "<>")
                Do While InStr("<=>", Mid$(Uclovie, i + 1, 1))
                    i = i + 1
                Loop
                If i = 0 Then
                    i = 1
                    Uclovie = "=" & Uclovie
                End If
                ' если правая часть условия не в кавычках,
                ' то заключаем ее в кавычки
                If Mid$(Uclovie, i + 1, 1) <> """" Then
                    Uclovie = Left$(Uclovie, i) & """" & Mid$(Uclovie, i + 1) & """"
                End If
                    
                i_n = Cells(Rows.Count, 1).End(xlUp).Row
                Application.ScreenUpdating = False
                For i = i_n To 1 Step -1
                    If Evaluate("""" & Cells(i, Stolbec) & """" & Uclovie) Then
                        Rows(i).Delete
                        kol = kol + 1
                    End If
                Next
                Application.ScreenUpdating = True
                MsgBox ("Удалено " & kol & " строк")
            End If
        End If
End Sub