Домашняя страница Undo Do Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Подсчет писем за нужный период и адресата - Мир MS Excel

Регистрация · Логин: · Пароль: · · Забыли пароль?
  • Страница 1 из 2
  • 1
  • 2
  • »
Модератор форума: _Boroda_, Manyasha, SLAVICK, китин  
Мир MS Excel » Вопросы и решения » Excel и другие приложения » Outlook » Подсчет писем за нужный период и адресата
Подсчет писем за нужный период и адресата
ovechkin1973 Дата: Среда, 27.12.2017, 17:37 | Сообщение № 1
Группа: Проверенные
Ранг: Обитатель
Сообщений: 284
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
Есть какая то возможность выгрузить из Оутлука данные по письмам в эксель? Допустим дату отправки, адресат, тема письма. Так же по входящим сделать? Иногда очень надо узнать, что и сколько на работал..


Плохо когда не знаешь, да еще забудешь.
 
Ответить
СообщениеЕсть какая то возможность выгрузить из Оутлука данные по письмам в эксель? Допустим дату отправки, адресат, тема письма. Так же по входящим сделать? Иногда очень надо узнать, что и сколько на работал..

Автор - ovechkin1973
Дата добавления - 27.12.2017 в 17:37
Gustav Дата: Среда, 27.12.2017, 23:52 | Сообщение № 2
Группа: Друзья
Ранг: Старожил
Сообщений: 1619
Репутация: 662 ±
Замечаний: 0% ±

начинал с Excel 4.0...
Вот здесь: http://www.excelworld.ru/forum/19-15042-126979-16-1420852811 есть моя "рыба" по доступу к папкам Исходящие и Входящие и по перебору писем в них. Также там выделяются адресаты писем, причем в общем случае по несколько человек на одно письмо. Тривиальные одиночные свойства писем типа даты отправки и темы найдёте в справке по объектной модели Outlook. В общем, рекомендую взять материал за основу.


Мой tip box - яд 41001663842605
 
Ответить
СообщениеВот здесь: http://www.excelworld.ru/forum/19-15042-126979-16-1420852811 есть моя "рыба" по доступу к папкам Исходящие и Входящие и по перебору писем в них. Также там выделяются адресаты писем, причем в общем случае по несколько человек на одно письмо. Тривиальные одиночные свойства писем типа даты отправки и темы найдёте в справке по объектной модели Outlook. В общем, рекомендую взять материал за основу.

Автор - Gustav
Дата добавления - 27.12.2017 в 23:52
ovechkin1973 Дата: Четверг, 28.12.2017, 05:37 | Сообщение № 3
Группа: Проверенные
Ранг: Обитатель
Сообщений: 284
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
В общем, рекомендую взять материал за основу.

Спасибо Gustav, попробую разобраться..


Плохо когда не знаешь, да еще забудешь.
 
Ответить
Сообщение
В общем, рекомендую взять материал за основу.

Спасибо Gustav, попробую разобраться..

Автор - ovechkin1973
Дата добавления - 28.12.2017 в 05:37
Gustav Дата: Четверг, 28.12.2017, 17:31 | Сообщение № 4
Группа: Друзья
Ранг: Старожил
Сообщений: 1619
Репутация: 662 ±
Замечаний: 0% ±

начинал с Excel 4.0...
ovechkin1973, держите модуль:
[vba]
Код
Option Explicit

'В Tools\References включить ссылку на Microsoft Outlook 15.0 Object Library
'если нет 15.0, то на ту которая есть

Dim colLetters  As Collection
Dim objLetter   As Letter 'создать модуль класса Letter!
Dim FolderPath  As String

Sub main() 'запускаем эту процедуру

    Dim olApp As Outlook.Application
    Dim fldr  As Outlook.Folder
    Dim arr(), i
    
    Set colLetters = New Collection
    
    Set olApp = CreateObject("Outlook.Application")
    
    'обрабатываем папку Входящие и вложенные в нее
    Set fldr = olApp.Session.GetDefaultFolder(6)  '6 = olFolderInbox
    Call processFolder(fldr)
    
    'обрабатываем папку Исходящие и вложенные в нее
    Set fldr = olApp.Session.GetDefaultFolder(5) '5 = olFolderSentMail
    Call processFolder(fldr)
       
    'вывод в новую книгу Excel
    ReDim arr(1 To colLetters.Count, 1 To 8)
    For i = 1 To colLetters.Count
        arr(i, 1) = colLetters(i).FolderPath
        arr(i, 2) = colLetters(i).ReceivedTime
        arr(i, 3) = colLetters(i).Sender
        arr(i, 4) = colLetters(i).Subject
        arr(i, 5) = colLetters(i).To_
        arr(i, 6) = colLetters(i).CC
        arr(i, 7) = colLetters(i).BCC
        arr(i, 8) = colLetters(i).NamesAddress
    Next i
    
    With Application.Workbooks.Add.Worksheets(1)
        .Range("A1:H1") = Array("Папка", "Дата/время", "Отправитель", "Тема", "Кому", "Копия", "Скрытая копия", "Адреса участников")
        .Range("A1:H1").Font.Bold = True
        .Range("A1:H1").EntireColumn.ColumnWidth = 30
        .Range("A2").Resize(colLetters.Count, 8) = arr
    End With
    
End Sub

Sub processFolder(ByVal pFolder As Outlook.Folder) 'Outlook.Folder)
    Dim fldr    As Outlook.Folder
    Dim item    As Object
    Dim mail    As Outlook.MailItem
    Dim rcpnt   As Outlook.Recipient
    Dim i
    Dim folderPathPrev As String
    Dim recpntAddr As String

    folderPathPrev = FolderPath
    FolderPath = FolderPath & "\" & pFolder.Name
    
    'перебор элементов в папке
    For Each item In pFolder.Items
        If item.Class = 43 Then 'обрабатываем только письма, 43 = olMail
            Set mail = item
            i = i + 1
            recpntAddr = ""
            'If i > 10 Then Exit For
            Debug.Print "Письмо " & i & " в папке " & pFolder.Name
            Set objLetter = New Letter
            
            On Error Resume Next
            With objLetter
                .FolderPath = FolderPath
                .ReceivedTime = mail.ReceivedTime
                .Sender = mail.Sender
                .Subject = mail.Subject
                .To_ = mail.To
                .CC = mail.CC
                .BCC = mail.BCC
             End With
            
            recpntAddr = recpntAddr & "; " & mail.Sender & " -- " & getAddress(mail.Sender, mail.Sender.Address)
            For Each rcpnt In mail.Recipients 'цикл по получателям
                recpntAddr = recpntAddr & "; " & rcpnt.Name & " -- " & getAddress(rcpnt.AddressEntry, rcpnt.Address)
            Next rcpnt
            recpntAddr = Mid(recpntAddr, 3)
            objLetter.NamesAddress = recpntAddr
            On Error GoTo 0
            
            colLetters.Add objLetter
            
            Set mail = Nothing
        End If
    Next item
    
    'перебор папок (первого уровня вложенности)
    For Each fldr In pFolder.Folders
        Call processFolder(fldr) 'рекурсия
    Next fldr
    
    FolderPath = folderPathPrev
End Sub

Function getAddress(ByVal pAddressEntry As Object, _
                    ByVal altaddr As String)
    Dim pa      As PropertyAccessor
    Dim addr    As String
    Set pa = pAddressEntry.PropertyAccessor
    On Error Resume Next
    addr = pa.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x39FE001E")
    If addr = "" Then addr = altaddr
    On Error GoTo 0
    getAddress = addr
End Function
[/vba]

Процедура main выводит в таблицу Excel информацию о письмах, находящихся в папках "Входящие" (Inbox) и "Исходящие" (Sent Items), а также из всех вложенных в них папок (рекурсивно). Состав информации (названия колонок): "Папка", "Дата/время", "Отправитель", "Тема", "Кому", "Копия", "Скрытая копия", "Адреса участников". Наиболее заморочные (и от того интересные) - первая и последняя колонки.

ВАЖНО! Помимо вышеуказанного модуля в рабочей книге нужно будет создать модуль класса под названием "Letter" со следующим содержимым:
[vba]
Код
Option Explicit

Public FolderPath   As String
Public ReceivedTime As Date
Public Sender       As String
Public Subject      As String
Public To_          As String
Public CC           As String
Public BCC          As String
Public NamesAddress As String
[/vba]


Мой tip box - яд 41001663842605

Сообщение отредактировал Gustav - Четверг, 28.12.2017, 17:31
 
Ответить
Сообщениеovechkin1973, держите модуль:
[vba]
Код
Option Explicit

'В Tools\References включить ссылку на Microsoft Outlook 15.0 Object Library
'если нет 15.0, то на ту которая есть

Dim colLetters  As Collection
Dim objLetter   As Letter 'создать модуль класса Letter!
Dim FolderPath  As String

Sub main() 'запускаем эту процедуру

    Dim olApp As Outlook.Application
    Dim fldr  As Outlook.Folder
    Dim arr(), i
    
    Set colLetters = New Collection
    
    Set olApp = CreateObject("Outlook.Application")
    
    'обрабатываем папку Входящие и вложенные в нее
    Set fldr = olApp.Session.GetDefaultFolder(6)  '6 = olFolderInbox
    Call processFolder(fldr)
    
    'обрабатываем папку Исходящие и вложенные в нее
    Set fldr = olApp.Session.GetDefaultFolder(5) '5 = olFolderSentMail
    Call processFolder(fldr)
       
    'вывод в новую книгу Excel
    ReDim arr(1 To colLetters.Count, 1 To 8)
    For i = 1 To colLetters.Count
        arr(i, 1) = colLetters(i).FolderPath
        arr(i, 2) = colLetters(i).ReceivedTime
        arr(i, 3) = colLetters(i).Sender
        arr(i, 4) = colLetters(i).Subject
        arr(i, 5) = colLetters(i).To_
        arr(i, 6) = colLetters(i).CC
        arr(i, 7) = colLetters(i).BCC
        arr(i, 8) = colLetters(i).NamesAddress
    Next i
    
    With Application.Workbooks.Add.Worksheets(1)
        .Range("A1:H1") = Array("Папка", "Дата/время", "Отправитель", "Тема", "Кому", "Копия", "Скрытая копия", "Адреса участников")
        .Range("A1:H1").Font.Bold = True
        .Range("A1:H1").EntireColumn.ColumnWidth = 30
        .Range("A2").Resize(colLetters.Count, 8) = arr
    End With
    
End Sub

Sub processFolder(ByVal pFolder As Outlook.Folder) 'Outlook.Folder)
    Dim fldr    As Outlook.Folder
    Dim item    As Object
    Dim mail    As Outlook.MailItem
    Dim rcpnt   As Outlook.Recipient
    Dim i
    Dim folderPathPrev As String
    Dim recpntAddr As String

    folderPathPrev = FolderPath
    FolderPath = FolderPath & "\" & pFolder.Name
    
    'перебор элементов в папке
    For Each item In pFolder.Items
        If item.Class = 43 Then 'обрабатываем только письма, 43 = olMail
            Set mail = item
            i = i + 1
            recpntAddr = ""
            'If i > 10 Then Exit For
            Debug.Print "Письмо " & i & " в папке " & pFolder.Name
            Set objLetter = New Letter
            
            On Error Resume Next
            With objLetter
                .FolderPath = FolderPath
                .ReceivedTime = mail.ReceivedTime
                .Sender = mail.Sender
                .Subject = mail.Subject
                .To_ = mail.To
                .CC = mail.CC
                .BCC = mail.BCC
             End With
            
            recpntAddr = recpntAddr & "; " & mail.Sender & " -- " & getAddress(mail.Sender, mail.Sender.Address)
            For Each rcpnt In mail.Recipients 'цикл по получателям
                recpntAddr = recpntAddr & "; " & rcpnt.Name & " -- " & getAddress(rcpnt.AddressEntry, rcpnt.Address)
            Next rcpnt
            recpntAddr = Mid(recpntAddr, 3)
            objLetter.NamesAddress = recpntAddr
            On Error GoTo 0
            
            colLetters.Add objLetter
            
            Set mail = Nothing
        End If
    Next item
    
    'перебор папок (первого уровня вложенности)
    For Each fldr In pFolder.Folders
        Call processFolder(fldr) 'рекурсия
    Next fldr
    
    FolderPath = folderPathPrev
End Sub

Function getAddress(ByVal pAddressEntry As Object, _
                    ByVal altaddr As String)
    Dim pa      As PropertyAccessor
    Dim addr    As String
    Set pa = pAddressEntry.PropertyAccessor
    On Error Resume Next
    addr = pa.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x39FE001E")
    If addr = "" Then addr = altaddr
    On Error GoTo 0
    getAddress = addr
End Function
[/vba]

Процедура main выводит в таблицу Excel информацию о письмах, находящихся в папках "Входящие" (Inbox) и "Исходящие" (Sent Items), а также из всех вложенных в них папок (рекурсивно). Состав информации (названия колонок): "Папка", "Дата/время", "Отправитель", "Тема", "Кому", "Копия", "Скрытая копия", "Адреса участников". Наиболее заморочные (и от того интересные) - первая и последняя колонки.

ВАЖНО! Помимо вышеуказанного модуля в рабочей книге нужно будет создать модуль класса под названием "Letter" со следующим содержимым:
[vba]
Код
Option Explicit

Public FolderPath   As String
Public ReceivedTime As Date
Public Sender       As String
Public Subject      As String
Public To_          As String
Public CC           As String
Public BCC          As String
Public NamesAddress As String
[/vba]

Автор - Gustav
Дата добавления - 28.12.2017 в 17:31
ovechkin1973 Дата: Пятница, 29.12.2017, 15:43 | Сообщение № 5
Группа: Проверенные
Ранг: Обитатель
Сообщений: 284
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
Gustav, выдает ошибку "модуль не является допустимым типом"
Создал два модуля - в первом код разместил, что в первым приложили и сделал отдельный модуль Letter и в него разместил то, что во второй части у вас..


Плохо когда не знаешь, да еще забудешь.
 
Ответить
СообщениеGustav, выдает ошибку "модуль не является допустимым типом"
Создал два модуля - в первом код разместил, что в первым приложили и сделал отдельный модуль Letter и в него разместил то, что во второй части у вас..

Автор - ovechkin1973
Дата добавления - 29.12.2017 в 15:43
anvg Дата: Пятница, 29.12.2017, 15:59 | Сообщение № 6
Группа: Друзья
Ранг: Обитатель
Сообщений: 402
Репутация: 213 ±
Замечаний: 0% ±

2010, 2016
сделал отдельный модуль Letter
А нужно было
создать модуль класса под названием "Letter"
 
Ответить
Сообщение
сделал отдельный модуль Letter
А нужно было
создать модуль класса под названием "Letter"

Автор - anvg
Дата добавления - 29.12.2017 в 15:59
ovechkin1973 Дата: Суббота, 30.12.2017, 07:35 | Сообщение № 7
Группа: Проверенные
Ранг: Обитатель
Сообщений: 284
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
А нужно было
Мда.. абсолютно не внимателен и ни разу таким пользоваться не приходилось. После исправление ошибка "определяемый пользователем тип не определен" на строке кода
Код
Sub processFolder(ByVal pFolder As Outlook.Folder) 'Outlook.Folder)


Плохо когда не знаешь, да еще забудешь.
 
Ответить
Сообщение
А нужно было
Мда.. абсолютно не внимателен и ни разу таким пользоваться не приходилось. После исправление ошибка "определяемый пользователем тип не определен" на строке кода
Код
Sub processFolder(ByVal pFolder As Outlook.Folder) 'Outlook.Folder)

Автор - ovechkin1973
Дата добавления - 30.12.2017 в 07:35
Gustav Дата: Суббота, 30.12.2017, 13:15 | Сообщение № 8
Группа: Друзья
Ранг: Старожил
Сообщений: 1619
Репутация: 662 ±
Замечаний: 0% ±

начинал с Excel 4.0...
абсолютно не внимателен

Увы, похоже, и второй тест на внимательность не пройден - указание про включение ссылки в начале модуля следует выполнить буквально:
[vba]
Код
Option Explicit

'В Tools\References включить ссылку на Microsoft Outlook 15.0 Object Library
'если нет 15.0, то на ту которая есть

Dim colLetters  As Collection
Dim objLetter   As Letter 'создать модуль класса Letter!
Dim FolderPath  As String
[/vba]

ни разу таким пользоваться не приходилось

Если коллекцию пользовательских объектов ни разу не создавали, то и не приходилось поэтому. Но всё же когда-нибудь происходит в первый раз - вот и случай познакомиться!


Мой tip box - яд 41001663842605
 
Ответить
Сообщение
абсолютно не внимателен

Увы, похоже, и второй тест на внимательность не пройден - указание про включение ссылки в начале модуля следует выполнить буквально:
[vba]
Код
Option Explicit

'В Tools\References включить ссылку на Microsoft Outlook 15.0 Object Library
'если нет 15.0, то на ту которая есть

Dim colLetters  As Collection
Dim objLetter   As Letter 'создать модуль класса Letter!
Dim FolderPath  As String
[/vba]

ни разу таким пользоваться не приходилось

Если коллекцию пользовательских объектов ни разу не создавали, то и не приходилось поэтому. Но всё же когда-нибудь происходит в первый раз - вот и случай познакомиться!

Автор - Gustav
Дата добавления - 30.12.2017 в 13:15
ovechkin1973 Дата: Суббота, 30.12.2017, 13:55 | Сообщение № 9
Группа: Проверенные
Ранг: Обитатель
Сообщений: 284
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
указание про включение ссылки в начале модуля следует выполнить буквально

Так и сделал - поставил галку на Microsoft Outlook 14.0 Object Library
Но всё же когда-нибудь происходит в первый раз - вот и случай познакомиться!

Это думаю для меня еще очень рано.. знаний пока нуль, пока смотрю в инете самые элементарные уроки по VBA.. усваиваются пока тяжко
К сообщению приложен файл: 2529839.xlsm(18.9 Kb)


Плохо когда не знаешь, да еще забудешь.
 
Ответить
Сообщение
указание про включение ссылки в начале модуля следует выполнить буквально

Так и сделал - поставил галку на Microsoft Outlook 14.0 Object Library
Но всё же когда-нибудь происходит в первый раз - вот и случай познакомиться!

Это думаю для меня еще очень рано.. знаний пока нуль, пока смотрю в инете самые элементарные уроки по VBA.. усваиваются пока тяжко

Автор - ovechkin1973
Дата добавления - 30.12.2017 в 13:55
Gustav Дата: Суббота, 30.12.2017, 14:55 | Сообщение № 10
Группа: Друзья
Ранг: Старожил
Сообщений: 1619
Репутация: 662 ±
Замечаний: 0% ±

начинал с Excel 4.0...
поставил галку на Microsoft Outlook 14.0 Object Library

Ну, в приложенном-то файле ее нет! Может только галку поставили, но ОК не нажали? Или наоборот - у меня иногда так бывало - выделяешь строку и жмёшь OK, забыв поставить галку.

Ладно. Если это для Вас так сложно, то можно не париться с галкой, но тогда надо в коде заменить явные типы объектов Outlook на безликие Object:
[vba]
Код
Sub main() 'запускаем эту процедуру

    Dim olApp As Object 'Outlook.Application
    Dim fldr  As Object 'Outlook.Folder

..........

Sub processFolder(ByVal pFolder As Object) 'Outlook.Folder)
    Dim fldr    As Object 'Outlook.Folder
    Dim item    As Object
    Dim mail    As Object 'Outlook.MailItem
    Dim rcpnt   As Object 'Outlook.Recipient
[/vba]
После такой замены при редактировании кода потеряется возможность пользоваться списком свойств и методов, появляющимся при наборе точки после имени объекта (а это несомненно удобно!). Но если Вы не собираетесь модифицировать мой код, то, наверное, и фиг с ним...


Мой tip box - яд 41001663842605
 
Ответить
Сообщение
поставил галку на Microsoft Outlook 14.0 Object Library

Ну, в приложенном-то файле ее нет! Может только галку поставили, но ОК не нажали? Или наоборот - у меня иногда так бывало - выделяешь строку и жмёшь OK, забыв поставить галку.

Ладно. Если это для Вас так сложно, то можно не париться с галкой, но тогда надо в коде заменить явные типы объектов Outlook на безликие Object:
[vba]
Код
Sub main() 'запускаем эту процедуру

    Dim olApp As Object 'Outlook.Application
    Dim fldr  As Object 'Outlook.Folder

..........

Sub processFolder(ByVal pFolder As Object) 'Outlook.Folder)
    Dim fldr    As Object 'Outlook.Folder
    Dim item    As Object
    Dim mail    As Object 'Outlook.MailItem
    Dim rcpnt   As Object 'Outlook.Recipient
[/vba]
После такой замены при редактировании кода потеряется возможность пользоваться списком свойств и методов, появляющимся при наборе точки после имени объекта (а это несомненно удобно!). Но если Вы не собираетесь модифицировать мой код, то, наверное, и фиг с ним...

Автор - Gustav
Дата добавления - 30.12.2017 в 14:55
ovechkin1973 Дата: Суббота, 30.12.2017, 15:28 | Сообщение № 11
Группа: Проверенные
Ранг: Обитатель
Сообщений: 284
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
в приложенном-то файле ее нет!

Странно, я открываю то, что выложил на форум и галка в нужном месте стоит
Код заменил, но так же ошибка в том же месте, что в сообщении №7 описывал..
К сообщению приложен файл: 9457269.xlsm(19.1 Kb)


Плохо когда не знаешь, да еще забудешь.
 
Ответить
Сообщение
в приложенном-то файле ее нет!

Странно, я открываю то, что выложил на форум и галка в нужном месте стоит
Код заменил, но так же ошибка в том же месте, что в сообщении №7 описывал..

Автор - ovechkin1973
Дата добавления - 30.12.2017 в 15:28
Gustav Дата: Суббота, 30.12.2017, 16:01 | Сообщение № 12
Группа: Друзья
Ранг: Старожил
Сообщений: 1619
Репутация: 662 ±
Замечаний: 0% ±

начинал с Excel 4.0...
ошибка в том же месте

Дык, а кто же внесёт исправление в это место-то, как было велено выше?
[vba]
Код
[s]Sub processFolder(ByVal pFolder As Outlook.Folder) 'Outlook.Folder)[/s]

Sub processFolder(ByVal pFolder As Object) 'Outlook.Folder)
[/vba]
Хм... может, я не вижу галку от того, что версии разные... хотя в этом случае у галки, которая не может включиться на другом компьютере, обычно появляется слово MISSING, которого я также не вижу...

Коллеги, у кого еще Офис 2010! Видите ли вы в ссылках VBA галку на библиотеку Outlook 14.0 в файле сообщения №9 ?


Мой tip box - яд 41001663842605
 
Ответить
Сообщение
ошибка в том же месте

Дык, а кто же внесёт исправление в это место-то, как было велено выше?
[vba]
Код
[s]Sub processFolder(ByVal pFolder As Outlook.Folder) 'Outlook.Folder)[/s]

Sub processFolder(ByVal pFolder As Object) 'Outlook.Folder)
[/vba]
Хм... может, я не вижу галку от того, что версии разные... хотя в этом случае у галки, которая не может включиться на другом компьютере, обычно появляется слово MISSING, которого я также не вижу...

Коллеги, у кого еще Офис 2010! Видите ли вы в ссылках VBA галку на библиотеку Outlook 14.0 в файле сообщения №9 ?

Автор - Gustav
Дата добавления - 30.12.2017 в 16:01
ovechkin1973 Дата: Суббота, 30.12.2017, 16:30 | Сообщение № 13
Группа: Проверенные
Ранг: Обитатель
Сообщений: 284
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
Gustav, пардон.. исправил. Сейчас та же ошибка, но в этой части кода


Плохо когда не знаешь, да еще забудешь.
 
Ответить
СообщениеGustav, пардон.. исправил. Сейчас та же ошибка, но в этой части кода

Автор - ovechkin1973
Дата добавления - 30.12.2017 в 16:30
Gustav Дата: Суббота, 30.12.2017, 17:32 | Сообщение № 14
Группа: Друзья
Ранг: Старожил
Сообщений: 1619
Репутация: 662 ±
Замечаний: 0% ±

начинал с Excel 4.0...
[vba]
Код
    Dim pa      As Object 'PropertyAccessor
[/vba]


Мой tip box - яд 41001663842605
 
Ответить
Сообщение[vba]
Код
    Dim pa      As Object 'PropertyAccessor
[/vba]

Автор - Gustav
Дата добавления - 30.12.2017 в 17:32
RAN Дата: Суббота, 30.12.2017, 17:34 | Сообщение № 15
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4854
Репутация: 971 ±
Замечаний: 0% ±

2010
Видите ли вы

Мои очки не позволяют разглядеть.


Быть или не быть, вот в чем загвоздка!
 
Ответить
Сообщение
Видите ли вы

Мои очки не позволяют разглядеть.

Автор - RAN
Дата добавления - 30.12.2017 в 17:34
ovechkin1973 Дата: Суббота, 30.12.2017, 18:33 | Сообщение № 16
Группа: Проверенные
Ранг: Обитатель
Сообщений: 284
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
RAN,
Мои очки не позволяют разглядеть.

Т.е у Вас 2010 эксель и в том файле, что я выложил не галки в строке Microsoft Outlook 14.0 Object Library ?


Плохо когда не знаешь, да еще забудешь.
 
Ответить
СообщениеRAN,
Мои очки не позволяют разглядеть.

Т.е у Вас 2010 эксель и в том файле, что я выложил не галки в строке Microsoft Outlook 14.0 Object Library ?

Автор - ovechkin1973
Дата добавления - 30.12.2017 в 18:33
ovechkin1973 Дата: Суббота, 30.12.2017, 18:39 | Сообщение № 17
Группа: Проверенные
Ранг: Обитатель
Сообщений: 284
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
Dim pa      As Object 'PropertyAccessor

Уважаемый Gustav, процесс сдвинулся, код у меня заработал. Проверить полностью смогу только на работе.. дома Оутлуком почти не пользуюсь..
Всех с наступающим Новым Годом! Здоровья и новых знаний...


Плохо когда не знаешь, да еще забудешь.
 
Ответить
Сообщение
Dim pa      As Object 'PropertyAccessor

Уважаемый Gustav, процесс сдвинулся, код у меня заработал. Проверить полностью смогу только на работе.. дома Оутлуком почти не пользуюсь..
Всех с наступающим Новым Годом! Здоровья и новых знаний...

Автор - ovechkin1973
Дата добавления - 30.12.2017 в 18:39
ovechkin1973 Дата: Воскресенье, 07.01.2018, 10:59 | Сообщение № 18
Группа: Проверенные
Ранг: Обитатель
Сообщений: 284
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
Gustav,
Проверить полностью смогу только на работе

Проверил на работе. Работает код.. но за письма за полтора года час точно файл обрабатывал, если даже не два.. видимо нужно диапазон дат для выгрузки задавать..


Плохо когда не знаешь, да еще забудешь.
 
Ответить
СообщениеGustav,
Проверить полностью смогу только на работе

Проверил на работе. Работает код.. но за письма за полтора года час точно файл обрабатывал, если даже не два.. видимо нужно диапазон дат для выгрузки задавать..

Автор - ovechkin1973
Дата добавления - 07.01.2018 в 10:59
Gustav Дата: Воскресенье, 07.01.2018, 14:20 | Сообщение № 19
Группа: Друзья
Ранг: Старожил
Сообщений: 1619
Репутация: 662 ±
Замечаний: 0% ±

начинал с Excel 4.0...
видимо нужно диапазон дат для выгрузки задавать

Да, пожалуй, эта возможность напрашивалась... Воплотил - см. прилагаемый файл (сюда не поместилось).
К сообщению приложен файл: WithDates.txt(4.4 Kb)


Мой tip box - яд 41001663842605
 
Ответить
Сообщение
видимо нужно диапазон дат для выгрузки задавать

Да, пожалуй, эта возможность напрашивалась... Воплотил - см. прилагаемый файл (сюда не поместилось).

Автор - Gustav
Дата добавления - 07.01.2018 в 14:20
ovechkin1973 Дата: Вторник, 16.01.2018, 17:29 | Сообщение № 20
Группа: Проверенные
Ранг: Обитатель
Сообщений: 284
Репутация: 0 ±
Замечаний: 0% ±

Excel 2010
Да, пожалуй, эта возможность напрашивалась... Воплотил - см. прилагаемый файл (сюда не поместилось).


Уважаемый Gustav, извиняюсь, что не отвечаю сразу. Не успел проверить. Точнее с наскока не получилось, пока пытаюсь разобраться, что не так сделал (по аналогии с первым разом)


Плохо когда не знаешь, да еще забудешь.
 
Ответить
Сообщение
Да, пожалуй, эта возможность напрашивалась... Воплотил - см. прилагаемый файл (сюда не поместилось).


Уважаемый Gustav, извиняюсь, что не отвечаю сразу. Не успел проверить. Точнее с наскока не получилось, пока пытаюсь разобраться, что не так сделал (по аналогии с первым разом)

Автор - ovechkin1973
Дата добавления - 16.01.2018 в 17:29
Мир MS Excel » Вопросы и решения » Excel и другие приложения » Outlook » Подсчет писем за нужный период и адресата
  • Страница 1 из 2
  • 1
  • 2
  • »
Поиск:

Яндекс цитирования
© 2010-2018 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!