Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/сумма чисел из суммы результата - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_, DrMini  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » сумма чисел из суммы результата (Формулы/Formulas)
сумма чисел из суммы результата
sasa Дата: Понедельник, 09.02.2015, 11:08 | Сообщение № 1
Группа: Пользователи
Ранг: Прохожий
Сообщений: 1
Репутация: 0 ±
Замечаний: 0% ±

Excel 2007
В таблице Числа5508.xls забита формула - месяцДата х (год рождения + 5508)= результат. Нужна сумма чисел из результата. А в результате стоит формула /см. файл Числа5508.xls/, вот тута мои познания и заканчиваются :( Помогите кто чем может

месяцДата - это обезательно одно число. Например 1 января - 0101, 31 января 0131, 1 февраля - 0201, 8 марта - 0308 и т.д.
К сообщению приложен файл: 5508.xls (31.5 Kb)
 
Ответить
СообщениеВ таблице Числа5508.xls забита формула - месяцДата х (год рождения + 5508)= результат. Нужна сумма чисел из результата. А в результате стоит формула /см. файл Числа5508.xls/, вот тута мои познания и заканчиваются :( Помогите кто чем может

месяцДата - это обезательно одно число. Например 1 января - 0101, 31 января 0131, 1 февраля - 0201, 8 марта - 0308 и т.д.
Автор - sasa
Дата добавления - 09.02.2015 в 11:08
Richman Дата: Понедельник, 09.02.2015, 11:42 | Сообщение № 2
Группа: Проверенные
Ранг: Обитатель
Сообщений: 346
Репутация: 54 ±
Замечаний: 0% ±

Excel 2007
Так нужно?

Код
=ПСТР(H4;1;1)+ПСТР(H4;2;1)+ПСТР(H4;3;1)+ПСТР(H4;4;1)+ПСТР(H4;5;1)+ПСТР(H4;6;1)
К сообщению приложен файл: 9833977.xls (25.0 Kb)

С Уважением, Richman

 
Ответить
СообщениеТак нужно?

Код
=ПСТР(H4;1;1)+ПСТР(H4;2;1)+ПСТР(H4;3;1)+ПСТР(H4;4;1)+ПСТР(H4;5;1)+ПСТР(H4;6;1)
Автор - Richman
Дата добавления - 09.02.2015 в 11:42
buchlotnik Дата: Понедельник, 09.02.2015, 11:45 | Сообщение № 3
Группа: Заблокированные
Ранг: Участник клуба
Сообщений: 3442
Репутация: 929 ±
Замечаний: 20% ±

2010, 2013, 2016 RUS / ENG
если все шестизначные:
Код
=СУММПРОИЗВ(--ПСТР(H4;СТОЛБЕЦ(A1:F1);1))
массивка
К сообщению приложен файл: _5508.xls (35.5 Kb)
 
Ответить
Сообщениеесли все шестизначные:
Код
=СУММПРОИЗВ(--ПСТР(H4;СТОЛБЕЦ(A1:F1);1))
массивка
Автор - buchlotnik
Дата добавления - 09.02.2015 в 11:45
buchlotnik Дата: Понедельник, 09.02.2015, 11:50 | Сообщение № 4
Группа: Заблокированные
Ранг: Участник клуба
Сообщений: 3442
Репутация: 929 ±
Замечаний: 20% ±

2010, 2013, 2016 RUS / ENG
или в общем виде - монстрик какой-то получился B)
Код
=СУММПРОИЗВ(ЕСЛИ(ЕОШИБКА(--ПСТР(H4;СТРОКА($B$1:$B$15);1));0;--ПСТР(H4;СТРОКА($B$1:$B$15);1)))
К сообщению приложен файл: 4127166.xls (36.5 Kb)
 
Ответить
Сообщениеили в общем виде - монстрик какой-то получился B)
Код
=СУММПРОИЗВ(ЕСЛИ(ЕОШИБКА(--ПСТР(H4;СТРОКА($B$1:$B$15);1));0;--ПСТР(H4;СТРОКА($B$1:$B$15);1)))
Автор - buchlotnik
Дата добавления - 09.02.2015 в 11:50
amfor Дата: Понедельник, 09.02.2015, 11:51 | Сообщение № 5
Группа: Проверенные
Ранг: Обитатель
Сообщений: 250
Репутация: 75 ±
Замечаний: 0% ±

Excel 2016
Так?
К сообщению приложен файл: 1866413.xls (43.0 Kb)

Семь бед - один RESET.
 
Ответить
СообщениеТак?
Автор - amfor
Дата добавления - 09.02.2015 в 11:51
buchlotnik Дата: Понедельник, 09.02.2015, 12:00 | Сообщение № 6
Группа: Заблокированные
Ранг: Участник клуба
Сообщений: 3442
Репутация: 929 ±
Замечаний: 20% ±

2010, 2013, 2016 RUS / ENG
amfor, классный вариант hands
 
Ответить
Сообщениеamfor, классный вариант hands
Автор - buchlotnik
Дата добавления - 09.02.2015 в 12:00
amfor Дата: Понедельник, 09.02.2015, 12:34 | Сообщение № 7
Группа: Проверенные
Ранг: Обитатель
Сообщений: 250
Репутация: 75 ±
Замечаний: 0% ±

Excel 2016
buchlotnik,Спасибо,но на авторство я не претендую. Давно нашел на просторах инета и положил в загашник. yes

Семь бед - один RESET.
 
Ответить
Сообщениеbuchlotnik,Спасибо,но на авторство я не претендую. Давно нашел на просторах инета и положил в загашник. yes
Автор - amfor
Дата добавления - 09.02.2015 в 12:34
_Boroda_ Дата: Понедельник, 09.02.2015, 13:22 | Сообщение № 8
Группа: Админы
Ранг: Местный житель
Сообщений: 16895
Репутация: 6612 ±
Замечаний: ±

2003; 2007; 2010; 2013 RUS
Еще вариант
Код
=СУММ(ЕСЛИОШИБКА(--ПСТР(H4;СТОЛБЕЦ(A:G);1);))

формула массива. Вводится одновременным нажатием Контрл Шифт Ентер
или обычная формула
Код
=СУММ(--ПСТР(H4*10^9;{1;2;3;4;5;6;7;8;9};1))
К сообщению приложен файл: 1866413_3.xls (53.0 Kb)

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
СообщениеЕще вариант
Код
=СУММ(ЕСЛИОШИБКА(--ПСТР(H4;СТОЛБЕЦ(A:G);1);))

формула массива. Вводится одновременным нажатием Контрл Шифт Ентер
или обычная формула
Код
=СУММ(--ПСТР(H4*10^9;{1;2;3;4;5;6;7;8;9};1))
Автор - _Boroda_
Дата добавления - 09.02.2015 в 13:22
krosav4ig Дата: Понедельник, 09.02.2015, 13:58 | Сообщение № 9
Группа: Друзья
Ранг: Старожил
Сообщений: 2348
Репутация: 997 ±
Замечаний: 0% ±

Excel 2007,2010,2013
Цитата buchlotnik, 09.02.2015 в 11:50, в сообщении № 4
монстрик какой-то получился
это заразно ;)
Код
=СУММПРОИЗВ(ЕЧИСЛО(ПОИСК("*"&ПОВТОР((СТРОКА($1:$10)-1)&"*";СТОЛБЕЦ(СМЕЩ($A:$A;;;;ДЛСТР(H4))));H4))*(СТРОКА($1:$10)-1))

email:krosav4ig26@gmail.com WMR R207627035142 WMZ Z821145374535 ЯД 410012026478460
 
Ответить
Сообщение
Цитата buchlotnik, 09.02.2015 в 11:50, в сообщении № 4
монстрик какой-то получился
это заразно ;)
Код
=СУММПРОИЗВ(ЕЧИСЛО(ПОИСК("*"&ПОВТОР((СТРОКА($1:$10)-1)&"*";СТОЛБЕЦ(СМЕЩ($A:$A;;;;ДЛСТР(H4))));H4))*(СТРОКА($1:$10)-1))
Автор - krosav4ig
Дата добавления - 09.02.2015 в 13:58
AlexM Дата: Понедельник, 09.02.2015, 14:09 | Сообщение № 10
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4517
Репутация: 1130 ±
Замечаний: 0% ±

Excel 2003
Насколько я понял число, цифры которого суммируем, не превышает 8 разрядов.
Пример 1231*9999+9999=24617538
Значит формулу Александра можно сократить чуток
Код
=СУММ(--ПСТР(H4*100;{1;2;3;4}+{0:4};1);)


Номер мобильного модема (без голосовой связи)
9269171249 МегаФон, Московский регион.
 
Ответить
СообщениеНасколько я понял число, цифры которого суммируем, не превышает 8 разрядов.
Пример 1231*9999+9999=24617538
Значит формулу Александра можно сократить чуток
Код
=СУММ(--ПСТР(H4*100;{1;2;3;4}+{0:4};1);)
Автор - AlexM
Дата добавления - 09.02.2015 в 14:09
AlexM Дата: Понедельник, 09.02.2015, 17:46 | Сообщение № 11
Группа: Друзья
Ранг: Участник клуба
Сообщений: 4517
Репутация: 1130 ±
Замечаний: 0% ±

Excel 2003
В результате суммирования цифр числа получаются двух разрядные числа.
Если и их цифры надо сложить, то общая формула получится еще короче.
Формула на всякий случай
Код
=И(-H4)*(ОСТАТ(H4-1;9)+1)


Номер мобильного модема (без голосовой связи)
9269171249 МегаФон, Московский регион.
 
Ответить
СообщениеВ результате суммирования цифр числа получаются двух разрядные числа.
Если и их цифры надо сложить, то общая формула получится еще короче.
Формула на всякий случай
Код
=И(-H4)*(ОСТАТ(H4-1;9)+1)
Автор - AlexM
Дата добавления - 09.02.2015 в 17:46
vikttur Дата: Понедельник, 09.02.2015, 20:47 | Сообщение № 12
Группа: Друзья
Ранг: Участник клуба
Сообщений: 2941
Репутация: 526 ±
Замечаний: 0% ±

Цитата
на авторство я не претендую. Давно нашел на просторах инета

ZORRO2005 баловался, в 2011 или 2012 году.
Тему, наверное, в Избушке тогда крутили.
 
Ответить
Сообщение
Цитата
на авторство я не претендую. Давно нашел на просторах инета

ZORRO2005 баловался, в 2011 или 2012 году.
Тему, наверное, в Избушке тогда крутили.
Автор - vikttur
Дата добавления - 09.02.2015 в 20:47
Мир MS Excel » Вопросы и решения » Вопросы по Excel » сумма чисел из суммы результата (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2025 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!