Подсчет процентов между данными двух ячеек

Страница 1 из 1 1
Модератор форума: китин, _Boroda_, DrMini

Подсчет процентов между данными двух ячеек (Формулы/Formulas)

aequit

Дата: Четверг, 19.02.2015, 21:51 | Сообщение № 1

Группа: Пользователи

Ранг: Новичок

Сообщений: 29

Репутация: 2 ±

Замечаний: 0% ±

Excel 2010

Здравствуйте! Составил формулу для подсчета разницы в процентах (или случаях) между данными в двух ячейках. Если разница положительна, прибавляется "Ув.", если отрицательна - "Ум.", если в одной ячейке 0 - то вместо процентов идёт подсчет случаев, если в обеих ячейках нули - выводится "так же". (В реальной жизни идёт учет несчастных случаев и происшествий).

Код

=ЕСЛИОШИБКА(ЕСЛИ((B3=E3); "так же"; ЕСЛИ((E3>B3);("Ув. "&" "&ОКРУГЛ((ABS(B3-E3)/B3)*100;1)&"%");ЕСЛИ(E3=0;"Ум. на "&(B3-E3)&" случ."; "Ум. "&" "&ОКРУГЛ(((B3-E3)/B3)*100;1)&"%"))); "Ув. на "&(E3-B3)&" случ.")

В основном работает, подскажите пожалуйста, как добиться, чтобы выводилась дробная часть в процентах, равная нулю, например, сейчас выводится "23,7%", "68,4%", а если дробной части нет, то выводится "10%", "20%".

Нужно, чтобы всегда выводился знак после запятой, даже если это ноль - "10,0%", "20,0%" и т.п.
[moder]Для оформления формул используйте кнопку fx

К сообщению приложен файл: protcents.xlsx (9.5 Kb)

Сообщение отредактировал aequit - Четверг, 19.02.2015, 21:53

Ответить

_Boroda_

Дата: Четверг, 19.02.2015, 21:57 | Сообщение № 2

Группа: Админы

Ранг: Местный житель

Сообщений: 16910

Репутация: 6616 ±

Замечаний: ±

2003; 2007; 2010; 2013 RUS

Так нужно?

Код

=ЕСЛИОШИБКА(ЕСЛИ(B3=E3; "также"; ЕСЛИ(E3>B3;"Ув. "&" "&ТЕКСТ(ОКРУГЛ((ABS(B3-E3)/B3);1);"0,0%");ЕСЛИ(E3=0;"Ум. на "&B3-E3&" случ."; "Ум. "&" "&ТЕКСТ(ОКРУГЛ((B3-E3)/B3;1);"0,0%")))); "Ув. на "&E3-B3&" случ.")

Еще немного в формуле постирал лишнее

К сообщению приложен файл: protcents_2.xlsx (10.1 Kb)

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995

Ответить

aequit

Дата: Четверг, 19.02.2015, 22:20 | Сообщение № 3

Группа: Пользователи

Ранг: Новичок

Сообщений: 29

Репутация: 2 ±

Замечаний: 0% ±

Excel 2010

Цитата _Boroda_, 19.02.2015 в 21:57, в сообщении № 2

Еще немного в формуле постирал лишнее

Спасибо, но что-то лишнее удалено, ноль, конечно, подставляется после запятой, но проценты считаются теперь неправильно.
Например, в моей формуле разница между 54 и 29 равна 46,3%, а в исправленной 50,0%.

Ответить

_Boroda_

Дата: Четверг, 19.02.2015, 22:24 | Сообщение № 4

Группа: Админы

Ранг: Местный житель

Сообщений: 16910

Репутация: 6616 ±

Замечаний: ±

2003; 2007; 2010; 2013 RUS

Ща посмотрю
В ОКРУГЛ единички замените на тройки

Код

=ЕСЛИОШИБКА(ЕСЛИ(B3=E3; "также"; ЕСЛИ(E3>B3;"Ув. "&" "&ТЕКСТ(ОКРУГЛ((ABS(B3-E3)/B3);3);"0,0%");ЕСЛИ(E3=0;"Ум. на "&B3-E3&" случ."; "Ум. "&" "&ТЕКСТ(ОКРУГЛ((B3-E3)/B3;3);"0,0%")))); "Ув. на "&E3-B3&" случ.")

К сообщению приложен файл: protcents_3.xlsx (10.1 Kb)

Ответить

buchlotnik

Дата: Четверг, 19.02.2015, 22:32 | Сообщение № 5

Группа: Заблокированные

Ранг: Участник клуба

Сообщений: 3442

Репутация: 929 ±

Замечаний: 20% ±

2010, 2013, 2016 RUS / ENG

а если так?

Код

=ЕСЛИ(B3=E3;"так же";ЕСЛИ(МИН(B3;E3)=0;ЕСЛИ(B3>E3;"Ум. на "&(B3-E3)&" случ.";"Ув. на "&(E3-B3)&" случ.");ЕСЛИ(B3>E3;"Ум. "&ТЕКСТ((B3-E3)/B3;"0,0%");"Ув. "&ТЕКСТ((E3-B3)/B3;"0,0%"))))