Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Как подтянуть год из ячейки сопоставить его с коэффициентом - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Как подтянуть год из ячейки сопоставить его с коэффициентом (Формулы/Formulas)
Как подтянуть год из ячейки сопоставить его с коэффициентом
DrMini Дата: Четверг, 21.04.2016, 14:00 | Сообщение № 1
Группа: Проверенные
Ранг: Старожил
Сообщений: 1605
Репутация: 195 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Доброго времени суток. Имеется таблица со списком книг в конце названия книги ставится пробел пишется год, пробел и две цифры (значение двух последних цифр может меняться). Надо год из колонки C3:C10 сопоставить с коэффициентом заданным в жёлтой таблице и автоматически подставить коэффициент в колонку L3:L10.
К сообщению приложен файл: 20160421.xlsx (13.0 Kb)
 
Ответить
СообщениеДоброго времени суток. Имеется таблица со списком книг в конце названия книги ставится пробел пишется год, пробел и две цифры (значение двух последних цифр может меняться). Надо год из колонки C3:C10 сопоставить с коэффициентом заданным в жёлтой таблице и автоматически подставить коэффициент в колонку L3:L10.

Автор - DrMini
Дата добавления - 21.04.2016 в 14:00
pabchek Дата: Четверг, 21.04.2016, 14:12 | Сообщение № 2
Группа: Проверенные
Ранг: Ветеран
Сообщений: 931
Репутация: 218 ±
Замечаний: 0% ±

Excel 2007
Здравствуйте. У меня вот так получилось. Правильно?
Код
=ВПР(--ЛЕВБ(ПРАВБ(C3;7);4);B$14:C$33;2)

еще вариант
Код
=ПРОСМОТР(--ЛЕВБ(ПРАВБ(C3;7);4);B$14:B$33;C$14:C$33)

Код
=ВПР(--ПСТР(C3;ДЛСТР(C3)-6;4);B$14:C$33;2)

Код
=ИНДЕКС(C$14:C$33;ПОИСКПОЗ(--ЛЕВБ(ПРАВБ(C3;7);4);B$14:B$33))
К сообщению приложен файл: 0565343.xlsx (12.7 Kb)


"Учиться, учиться и еще раз учиться!"
WM: R399923528092


Сообщение отредактировал pabchek - Четверг, 21.04.2016, 14:22
 
Ответить
СообщениеЗдравствуйте. У меня вот так получилось. Правильно?
Код
=ВПР(--ЛЕВБ(ПРАВБ(C3;7);4);B$14:C$33;2)

еще вариант
Код
=ПРОСМОТР(--ЛЕВБ(ПРАВБ(C3;7);4);B$14:B$33;C$14:C$33)

Код
=ВПР(--ПСТР(C3;ДЛСТР(C3)-6;4);B$14:C$33;2)

Код
=ИНДЕКС(C$14:C$33;ПОИСКПОЗ(--ЛЕВБ(ПРАВБ(C3;7);4);B$14:B$33))

Автор - pabchek
Дата добавления - 21.04.2016 в 14:12
DrMini Дата: Четверг, 21.04.2016, 14:22 | Сообщение № 3
Группа: Проверенные
Ранг: Старожил
Сообщений: 1605
Репутация: 195 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Здравствуйте. У меня вот так получилось. Правильно?

СПАСИБО. Всё работает. hands respect
 
Ответить
Сообщение
Здравствуйте. У меня вот так получилось. Правильно?

СПАСИБО. Всё работает. hands respect

Автор - DrMini
Дата добавления - 21.04.2016 в 14:22
китин Дата: Четверг, 21.04.2016, 14:38 | Сообщение № 4
Группа: Модераторы
Ранг: Экселист
Сообщений: 7013
Репутация: 1073 ±
Замечаний: 0% ±

Excel 2007;2010;2016
а уменя длинно, массивно и монструозно :p зато повыделывался :D
Код
=ЕСЛИОШИБКА(ПРОСМОТР(ПСТР(C3;ПОИСКПОЗ(ИСТИНА;ЕЧИСЛО(--ПСТР(C3;СТРОКА($1:$100);4));0)+1;4);ЛЕВБ($B$14:$B$32;4);$C$14:$C$32);12,9)
К сообщению приложен файл: Boox.xlsx (13.3 Kb)


Не судите очень строго:я пытаюсь научиться
ЯД 41001877306852
 
Ответить
Сообщениеа уменя длинно, массивно и монструозно :p зато повыделывался :D
Код
=ЕСЛИОШИБКА(ПРОСМОТР(ПСТР(C3;ПОИСКПОЗ(ИСТИНА;ЕЧИСЛО(--ПСТР(C3;СТРОКА($1:$100);4));0)+1;4);ЛЕВБ($B$14:$B$32;4);$C$14:$C$32);12,9)

Автор - китин
Дата добавления - 21.04.2016 в 14:38
DrMini Дата: Четверг, 21.04.2016, 15:16 | Сообщение № 5
Группа: Проверенные
Ранг: Старожил
Сообщений: 1605
Репутация: 195 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
китин, Спасибо. Возьму обязательно к себе в "копилку". Проверил повнимательнее. Не работает вааще. :(


Сообщение отредактировал DrMini - Четверг, 21.04.2016, 16:22
 
Ответить
Сообщениекитин, Спасибо. Возьму обязательно к себе в "копилку". Проверил повнимательнее. Не работает вааще. :(

Автор - DrMini
Дата добавления - 21.04.2016 в 15:16
китин Дата: Четверг, 21.04.2016, 15:23 | Сообщение № 6
Группа: Модераторы
Ранг: Экселист
Сообщений: 7013
Репутация: 1073 ±
Замечаний: 0% ±

Excel 2007;2010;2016
раз в копилку yahoo тогда добавлю комментарий:
Код
=ПСТР(C3;ПОИСКПОЗ(ИСТИНА;ЕЧИСЛО(--ПСТР(C3;СТРОКА($1:$100);4));0)+1;4)
вытянет число(первое) любой длины из текста надо только поменять цифру 4 здесь
Цитата
СТРОКА($1:$100);4));0)+1;4)
на необходимую цифру,(это длина числа которое вам надо достать


Не судите очень строго:я пытаюсь научиться
ЯД 41001877306852
 
Ответить
Сообщениераз в копилку yahoo тогда добавлю комментарий:
Код
=ПСТР(C3;ПОИСКПОЗ(ИСТИНА;ЕЧИСЛО(--ПСТР(C3;СТРОКА($1:$100);4));0)+1;4)
вытянет число(первое) любой длины из текста надо только поменять цифру 4 здесь
Цитата
СТРОКА($1:$100);4));0)+1;4)
на необходимую цифру,(это длина числа которое вам надо достать

Автор - китин
Дата добавления - 21.04.2016 в 15:23
_Boroda_ Дата: Четверг, 21.04.2016, 16:20 | Сообщение № 7
Группа: Модераторы
Ранг: Местный житель
Сообщений: 16666
Репутация: 6478 ±
Замечаний: 0% ±

2003; 2007; 2010; 2013 RUS
вытянет число(первое)

Вот здесь-то ты и прокололся. Если строка такая?
Астафьева Н. 9999 рецептов, 1965 83
Нам нужно не первые 4 цифры, а последние.
Предлагаю так
Код
=ЕСЛИОШИБКА(ПРОСМОТР(ПСТР(C3;ПРОСМОТР(;-1/(ДЛСТР(-ПСТР(C3;СТРОКА($1:$99);4))=5);СТРОКА($1:$99));4);ЛЕВБ(B$14:B$32;4);C$14:C$32);12,9)
К сообщению приложен файл: Boox_1.xlsx (13.3 Kb)


Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995
 
Ответить
Сообщение
вытянет число(первое)

Вот здесь-то ты и прокололся. Если строка такая?
Астафьева Н. 9999 рецептов, 1965 83
Нам нужно не первые 4 цифры, а последние.
Предлагаю так
Код
=ЕСЛИОШИБКА(ПРОСМОТР(ПСТР(C3;ПРОСМОТР(;-1/(ДЛСТР(-ПСТР(C3;СТРОКА($1:$99);4))=5);СТРОКА($1:$99));4);ЛЕВБ(B$14:B$32;4);C$14:C$32);12,9)

Автор - _Boroda_
Дата добавления - 21.04.2016 в 16:20
DrMini Дата: Четверг, 21.04.2016, 16:25 | Сообщение № 8
Группа: Проверенные
Ранг: Старожил
Сообщений: 1605
Репутация: 195 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
_Boroda_, Спасибо. Ваш вариант работает. Абалдеть. У одного и того же примера - столько вариантов решения. Я всё больше преклоняюсь перед людьми которые могут (а главное хотят) работать в excel и безвозмездно помогать. Спасибо Вам и низкий поклон.
[moder]А знали бы Вы, сколько их еще! Я про варианты


Сообщение отредактировал _Boroda_ - Четверг, 21.04.2016, 16:52
 
Ответить
Сообщение_Boroda_, Спасибо. Ваш вариант работает. Абалдеть. У одного и того же примера - столько вариантов решения. Я всё больше преклоняюсь перед людьми которые могут (а главное хотят) работать в excel и безвозмездно помогать. Спасибо Вам и низкий поклон.
[moder]А знали бы Вы, сколько их еще! Я про варианты

Автор - DrMini
Дата добавления - 21.04.2016 в 16:25
Nic70y Дата: Четверг, 21.04.2016, 16:49 | Сообщение № 9
Группа: Друзья
Ранг: Экселист
Сообщений: 8703
Репутация: 2258 ±
Замечаний: 0% ±

Excel 2010
для разнообразия
Код
=ИНДЕКС(C$14:C$32;ПОИСКПОЗ(--ПОДСТАВИТЬ(ПРАВБ(C3;7);" ";",");--ПОДСТАВИТЬ(ЛЕВБ(B$14:B$32;4);1980;0)))
Код
=ЕСЛИОШИБКА(ИНДЕКС(C$14:C$32;ПОИСКПОЗ(--ПОДСТАВИТЬ(ПРАВБ(C3;7);" ";",");--ЛЕВБ(B$14:B$32;4)));C$14)
немассивные
Код
=ЕСЛИОШИБКА(ПРОСМОТР(--ПОДСТАВИТЬ(ПРАВБ(C3;7);" ";",");--ЛЕВБ(B$14:B$32;4);C$14:C$32);C$14)
Код
=ЕСЛИ(--ЛЕВБ(ПРАВБ(C3;7);4)<1981;C$14;ЕСЛИ(--ЛЕВБ(ПРАВБ(C3;7);4)<1991;C$15;ИНДЕКС(C$16:C$32;МИН(ЛЕВБ(ПРАВБ(C3;7);4)-1990;17))))
Код
=ИНДЕКС(C$14:C$32;МИН((ЛЕВБ(ПРАВБ(C3;7);4)/1981>=1)+1+МАКС(ЛЕВБ(ПРАВБ(C3;7);4)-1990;0);19))
Код
=ИНДЕКС(C$14:C$32;МИН(ЛЕВБ((ЛЕВБ(МАКС(ЛЕВБ(ПРАВБ(C3;7);4)-1990;-10)/10;3)+2)*10-20;2)+2;19))


ЮMoney 41001841029809

Сообщение отредактировал Nic70y - Четверг, 21.04.2016, 18:10
 
Ответить
Сообщениедля разнообразия
Код
=ИНДЕКС(C$14:C$32;ПОИСКПОЗ(--ПОДСТАВИТЬ(ПРАВБ(C3;7);" ";",");--ПОДСТАВИТЬ(ЛЕВБ(B$14:B$32;4);1980;0)))
Код
=ЕСЛИОШИБКА(ИНДЕКС(C$14:C$32;ПОИСКПОЗ(--ПОДСТАВИТЬ(ПРАВБ(C3;7);" ";",");--ЛЕВБ(B$14:B$32;4)));C$14)
немассивные
Код
=ЕСЛИОШИБКА(ПРОСМОТР(--ПОДСТАВИТЬ(ПРАВБ(C3;7);" ";",");--ЛЕВБ(B$14:B$32;4);C$14:C$32);C$14)
Код
=ЕСЛИ(--ЛЕВБ(ПРАВБ(C3;7);4)<1981;C$14;ЕСЛИ(--ЛЕВБ(ПРАВБ(C3;7);4)<1991;C$15;ИНДЕКС(C$16:C$32;МИН(ЛЕВБ(ПРАВБ(C3;7);4)-1990;17))))
Код
=ИНДЕКС(C$14:C$32;МИН((ЛЕВБ(ПРАВБ(C3;7);4)/1981>=1)+1+МАКС(ЛЕВБ(ПРАВБ(C3;7);4)-1990;0);19))
Код
=ИНДЕКС(C$14:C$32;МИН(ЛЕВБ((ЛЕВБ(МАКС(ЛЕВБ(ПРАВБ(C3;7);4)-1990;-10)/10;3)+2)*10-20;2)+2;19))

Автор - Nic70y
Дата добавления - 21.04.2016 в 16:49
DrMini Дата: Четверг, 21.04.2016, 16:55 | Сообщение № 10
Группа: Проверенные
Ранг: Старожил
Сообщений: 1605
Репутация: 195 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Nic70y, Спасибо. Обязательно завтра попробую.
 
Ответить
СообщениеNic70y, Спасибо. Обязательно завтра попробую.

Автор - DrMini
Дата добавления - 21.04.2016 в 16:55
DrMini Дата: Четверг, 21.04.2016, 17:00 | Сообщение № 11
Группа: Проверенные
Ранг: Старожил
Сообщений: 1605
Репутация: 195 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Модератор:
А знали бы Вы, сколько их еще! Я про варианты

Если бы знал, наверное голову бы разбил. Шутка конечно. Классный сайт. Хотелось бы что бы нужные темы форума добавлять в избранное. Очень бы пригодилось. Знаю, что не в тему пишу. Но всё-таки может админ что-то под шаманит для этого.
[moder]Можно подписаться на тему: справа над первым сообщением темы[/moder]


Сообщение отредактировал Manyasha - Четверг, 21.04.2016, 17:13
 
Ответить
Сообщение
Модератор:
А знали бы Вы, сколько их еще! Я про варианты

Если бы знал, наверное голову бы разбил. Шутка конечно. Классный сайт. Хотелось бы что бы нужные темы форума добавлять в избранное. Очень бы пригодилось. Знаю, что не в тему пишу. Но всё-таки может админ что-то под шаманит для этого.
[moder]Можно подписаться на тему: справа над первым сообщением темы[/moder]

Автор - DrMini
Дата добавления - 21.04.2016 в 17:00
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Как подтянуть год из ячейки сопоставить его с коэффициентом (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2024 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!