Дата текстом в дату

Страница 1 из 1 1
Модератор форума: китин, _Boroda_, DrMini

Дата текстом в дату (Формулы/Formulas)

Дата текстом в дату

IgMaxx

Дата: Четверг, 10.08.2017, 09:36 | Сообщение № 1

Группа: Пользователи

Ранг: Новичок

Сообщений: 15

Репутация: 0 ±

Замечаний: 0% ±

Excel 2010

Добрый день уважаемым знатокам Excel!

Прошу помочь с проблемкой: дата в инвойсах приходит текстом, надо преобразовать нормальную в дату Excel. Год не имеет значения, к примеру здесь 2016. Главное как например 02DEC превратить в 02.12.2016 , чтобы это была полноценная дата. Извиняюсь, если где-то уже такое в форуме было, но я к сожалению не нашёл.

Заранее благодарю!

К сообщению приложен файл: Sample.xlsx (8.6 Kb)

Сообщение отредактировал IgMaxx - Четверг, 10.08.2017, 09:39

Ответить

китин

Дата: Четверг, 10.08.2017, 09:50 | Сообщение № 2

Группа: Модераторы

Ранг: Экселист

Сообщений: 7034

Репутация: 1079 ±

Замечаний: 0% ±

Excel 2007;2010;2016

И вам не хворать!!!

Как то так, наверное

Код

=ДАТА($E$1;ВПР(ПРАВБ(B2;3);{"Jan";1:"Feb";2:"Mar";3:"Apr";4:"May ";5:"Jun";6:"Jul";7:"Aug";8:"Sep ";9:"Oct";10:"Nov";11:"Dec";12};2;0);--ЛЕВБ(B2;2))

К сообщению приложен файл: IgMaxx.xlsx (9.7 Kb)

Не судите очень строго:я пытаюсь научиться
ЯД 41001877306852

Сообщение отредактировал китин - Четверг, 10.08.2017, 09:51

Ответить

IgMaxx

Дата: Четверг, 10.08.2017, 10:11 | Сообщение № 3

Группа: Пользователи

Ранг: Новичок

Сообщений: 15

Репутация: 0 ±

Замечаний: 0% ±

Excel 2010

Я всегда знал, что здесь лучшие УМЫ! Спасибо, очень помогли!!!

Ответить

buchlotnik

Дата: Четверг, 10.08.2017, 10:39 | Сообщение № 4

Группа: Заблокированные

Ранг: Участник клуба

Сообщений: 3442

Репутация: 929 ±

Замечаний: 20% ±

2010, 2013, 2016 RUS / ENG

чутка короче

Код

=ДАТА($E$1;ПОИСК(ПРАВБ(B2;2);" anebarprayunulugepctovec")/2;--ЛЕВБ(B2;2))

К сообщению приложен файл: 7054887.xlsx (9.4 Kb)

Ответить

_Boroda_

Дата: Четверг, 10.08.2017, 10:45 | Сообщение № 5

Группа: Админы

Ранг: Местный житель

Сообщений: 16881

Репутация: 6593 ±

Замечаний: ±

2003; 2007; 2010; 2013 RUS

Еще варианты по другому принципу
Массивный

Код

=--(ЛЕВБ(B2;2)&-ПОИСКПОЗ(ПРАВБ(B2;3);ТЕКСТ(СТРОКА($1:$12)*28;"[$-6]МММ");)&-E$1)

Обычный

Код

=--(ЛЕВБ(B2;2)&-ПРОСМОТР(;-1/(ПРАВБ(B2;3)=ТЕКСТ(СТРОКА($1:$12)*28;"[$-6]МММ"));СТРОКА($1:$12))&-E$1)

И Михаила без минусов "--"

Код

=ДАТА(E$1;ПОИСК(ПРАВБ(B2;2);" anebarprayunulugepctovec")/2;ЛЕВБ(B2;2))

К сообщению приложен файл: Sample-2-1.xlsx (10.9 Kb)

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995