Найти и вставить значение из другого листа

Старая форма входа

Страница 1 из 1 1
Модератор форума: китин, _Boroda_

Мир MS Excel » Вопросы и решения » Вопросы по Excel » Найти и вставить значение из другого листа (Формулы/Formulas)

GeorgeXIII

Дата: Четверг, 28.12.2017, 08:20 | Сообщение № 1

Группа: Пользователи

Ранг: Новичок

Сообщений: 18

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

Уважаемые форумчане!
Есть проблема: можно ли формулой заполнить столбец "Лицевой счет" листа "Список" из столбца "№ л. счета" листа "БазаЛС"?
Искать по полному совпадению полей "Населенный пункт", "Улица", "дом", "Корпус", "Квартира".
Всех с Наступающим!!!

К сообщению приложен файл: 1215190.xlsx (10.0 Kb)

Ответить

ВладимирG

Дата: Четверг, 28.12.2017, 09:05 | Сообщение № 2

Группа: Проверенные

Ранг: Форумчанин

Сообщений: 136

Репутация: 22 ±

Замечаний: 0% ±

2007

Если бы вместо "пусто" стояли нули, поиск был бы точнее. А так формула массива:

Код

=ИНДЕКС(БазаЛС!$B$2:$B$10;ПОИСКПОЗ(МАКС(МУМНОЖ(Ч(СЧЁТЕСЛИ(СМЕЩ(БазаЛС!$C$2;СТРОКА($A$2:$A$10)-2;{0;1;4;5;6;7});C2:H2));{1:1:1:1:1:1}));МУМНОЖ(Ч(СЧЁТЕСЛИ(СМЕЩ(БазаЛС!$C$2;СТРОКА($A$2:$A$10)-2;{0;1;4;5;6;7});C2:H2));{1:1:1:1:1:1});0))

Нули можно быстро проставить через ЗАМЕНИТЬ и выставить такой формат ячеек:

Код

[=0]"""";Основной

И формула стала бы значительно проще:

Код

=ИНДЕКС(БазаЛС!$B$2:$B$10;ПОИСКПОЗ(6;МУМНОЖ(Ч(СЧЁТЕСЛИ(СМЕЩ(БазаЛС!$C$2;СТРОКА($A$2:$A$10)-2;{0;1;4;5;6;7});C2:H2));{1:1:1:1:1:1});0))

Сообщение отредактировал ВладимирG - Четверг, 28.12.2017, 09:08

Ответить

Nic70y

Дата: Четверг, 28.12.2017, 09:15 | Сообщение № 3

Группа: Друзья

Ранг: Экселист

Сообщений: 8760

Репутация: 2273 ±

Замечаний: 0% ±

Excel 2010

Код

=СУММПРОИЗВ(БазаЛС!B$2:B$10*(C2=БазаЛС!C$2:C$10)*(D2=БазаЛС!D$2:D$10)*(E2=БазаЛС!G$2:G$10)*(F2=БазаЛС!H$2:H$10)*(G2=БазаЛС!I$2:I$10)*(H2=БазаЛС!J$2:J$10&""))

К сообщению приложен файл: 0098301.xlsx (11.2 Kb)

ЮMoney 41001841029809

Ответить

pabchek

Дата: Четверг, 28.12.2017, 10:07 | Сообщение № 4

Группа: Проверенные

Ранг: Ветеран

Сообщений: 931

Репутация: 218 ±

Замечаний: 0% ±

Excel 2007

Здравствуйте!
Если есть возможность использовать допстолбец можно так:

Код

=ИНДЕКС(БазаЛС!B:B;ПОИСКПОЗ(C2&D2&E2&F2&G2&H2;БазаЛС!K:K;0))

Пы.Сы. Этот подход можно и без допстолбца, но формула будет "тяжелее" и, если строк большое количество подтормаживать будет знатно. ~~Поэтому не предлагаю.~~
Хотя... На всякий случай

(формула массива)

Код

=ИНДЕКС(БазаЛС!B:B;ПОИСКПОЗ(C2&D2&E2&F2&G2&H2;БазаЛС!C:C&БазаЛС!D:D&БазаЛС!G:G&БазаЛС!H:H&БазаЛС!I:I&БазаЛС!J:J;0))

К сообщению приложен файл: 7182733.xlsx (11.0 Kb)

"Учиться, учиться и еще раз учиться!"
WM: R399923528092

Сообщение отредактировал pabchek - Четверг, 28.12.2017, 10:09

Ответить

Che79

Дата: Четверг, 28.12.2017, 10:40 | Сообщение № 5

Группа: Друзья

Ранг: Старожил

Сообщений: 1649

Репутация: 306 ±

Замечаний: 0% ±

2013 Win, 365 Mac

Здравствуйте.
Еще вариант

Код

=ПРОСМОТР(;-1/((C2=БазаЛС!$C$2:$C$100)/(D2=БазаЛС!$D$2:$D$100)/(E2=БазаЛС!$G$2:$G$100)/(F2=БазаЛС!$H$2:$H$100)/(G2=БазаЛС!$I$2:$I$100)/(--H2=БазаЛС!$J$2:$J$100));БазаЛС!$B$2:$B$100)

К сообщению приложен файл: 7182733_1.xlsx (11.2 Kb)

Делай нормально и будет нормально!

Ответить

китин

Дата: Четверг, 28.12.2017, 10:41 | Сообщение № 6

Группа: Модераторы

Ранг: Экселист

Сообщений: 7015

Репутация: 1073 ±

Замечаний: 0% ±

Excel 2007;2010;2016

или вот так. немассивная и довольно шустрая

Код

=ПРОСМОТР(2;1/(($C2=БазаЛС!$C$2:$C$10)*($D2=БазаЛС!$D$2:$D$10)*($E2=БазаЛС!$G$2:$G$10)*($F2=БазаЛС!$H$2:$H$10)*($G2=БазаЛС!$I$2:$I$10)*($H2=БазаЛС!$J$2:$J$10));БазаЛС!$B$2:$B$10)

[p.s.]Леша у кого там говорят мысли сходятся?