Извлечь данные из всех пар круглых скобок в ячейке.

Старая форма входа

Страница 1 из 1 1
Модератор форума: китин, _Boroda_

Мир MS Excel » Вопросы и решения » Вопросы по Excel » Извлечь данные из всех пар круглых скобок в ячейке. (Формулы/Formulas)

танбраун

Дата: Понедельник, 22.04.2019, 13:11 | Сообщение № 1

Группа: Пользователи

Ранг: Участник

Сообщений: 54

Репутация: 0 ±

Замечаний: 0% ±

Excel 2013

Добрый день!
Прошу помочь в данном вопросе: нужно извлечь данные из всех пар круглых скобок в ячейке.

К сообщению приложен файл: 0907964.xlsx (8.4 Kb)

Ответить

Nic70y

Дата: Понедельник, 22.04.2019, 13:59 | Сообщение № 2

Группа: Друзья

Ранг: Экселист

Сообщений: 8759

Репутация: 2272 ±

Замечаний: 0% ±

Excel 2010

Ctrl + H
1)
Найти: )*(
Заменить на: ; (с пробелом)
Заменить все
2)
Найти: *(
Заменить на: (здесь ни чего)
Заменить все
3)
Найти: )*
Заменить на: (здесь ни чего)
Заменить все

ЮMoney 41001841029809

Ответить

танбраун

Дата: Понедельник, 22.04.2019, 14:36 | Сообщение № 3

Группа: Пользователи

Ранг: Участник

Сообщений: 54

Репутация: 0 ±

Замечаний: 0% ±

Excel 2013

Nic70y, спасибо, но мне нужно с помощью формулы.

Ответить

Nic70y

Дата: Понедельник, 22.04.2019, 15:29 | Сообщение № 4

Группа: Друзья

Ранг: Экселист

Сообщений: 8759

Репутация: 2272 ±

Замечаний: 0% ±

Excel 2010

Цитата танбраун, 22.04.2019 в 14:36, в сообщении № 3 ()

с помощью формулы

Цитата танбраун, 22.04.2019 в 13:11, в сообщении № 1 ()

из всех пар

это проблематично.
кол-во всех нам же не известно.

ЮMoney 41001841029809

Ответить

танбраун

Дата: Понедельник, 22.04.2019, 15:38 | Сообщение № 5

Группа: Пользователи

Ранг: Участник

Сообщений: 54

Репутация: 0 ±

Замечаний: 0% ±

Excel 2013

если до 5 пар, это проще?

Ответить

sboy

Дата: Понедельник, 22.04.2019, 16:08 | Сообщение № 6

Группа: Друзья

Ранг: Участник клуба

Сообщений: 2566

Репутация: 724 ±

Замечаний: 0% ±

Excel 2010

Добрый день.
Вариант пользовательской функцией
[vba]

Код

Function танбраун(t As String) As String
    With CreateObject("VBScript.RegExp")
        .Global = True
        .Pattern = "\(([^)]+)"
        If .test(t) Then
            For i = 0 To .Execute(t).Count - 1
                танбраун = танбраун & .Execute(t)(i).Submatches(0) & "; "
            Next
            танбраун = Left(танбраун, Len(танбраун) - 2)
        End If
    End With
End Function

[/vba]

К сообщению приложен файл: 0907964.xlsb (13.4 Kb)

Яндекс: 410016850021169

Ответить

танбраун

Дата: Понедельник, 22.04.2019, 16:35 | Сообщение № 7

Группа: Пользователи

Ранг: Участник

Сообщений: 54

Репутация: 0 ±

Замечаний: 0% ±

Excel 2013

sboy, спасибо за вариант, но хотелось бы формулой.

Ответить

Nic70y

Дата: Понедельник, 22.04.2019, 16:37 | Сообщение № 8

Группа: Друзья

Ранг: Экселист

Сообщений: 8759

Репутация: 2272 ±

Замечаний: 0% ±

Excel 2010

Цитата танбраун, 22.04.2019 в 15:38, в сообщении № 5 ()

если до 5 пар

как-то так, примерно

Код

=ПОДСТАВИТЬ(СЖПРОБЕЛЫ(ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("(";A3)+1;999);")";ПОВТОР(" ";999));999))&"; "&ЕСЛИОШИБКА(СЖПРОБЕЛЫ(ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("\";ПОДСТАВИТЬ(A3;"(";"\";2))+1;999);")";ПОВТОР(" ";999));999))&"; ";"")&ЕСЛИОШИБКА(СЖПРОБЕЛЫ(ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("\";ПОДСТАВИТЬ(A3;"(";"\";3))+1;999);")";ПОВТОР(" ";999));999))&"; ";"")&ЕСЛИОШИБКА(СЖПРОБЕЛЫ(ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("\";ПОДСТАВИТЬ(A3;"(";"\";4))+1;999);")";ПОВТОР(" ";999));999))&"; ";"")&ЕСЛИОШИБКА(СЖПРОБЕЛЫ(ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("\";ПОДСТАВИТЬ(A3;"(";"\";5))+1;999);")";ПОВТОР(" ";999));999))&"; ";"");"; ";;ДЛСТР(A3)-ДЛСТР(ПОДСТАВИТЬ(A3;"(";)))

ЮMoney 41001841029809

Ответить

bmv98rus

Дата: Понедельник, 22.04.2019, 16:50 | Сообщение № 9

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4106

Репутация: 768 ±

Замечаний: 0% ±

Excel 2013/2016

Код

=SUBSTITUTE(TRIM(MID(SUBSTITUTE(SUBSTITUTE(A3;"(";REPT(" ";999));")";REPT(" ";999));999*1;999))&"; "&
TRIM(MID(SUBSTITUTE(SUBSTITUTE(A3;"(";REPT(" ";999));")";REPT(" ";999));999*3;999))&"; "&
TRIM(MID(SUBSTITUTE(SUBSTITUTE(A3;"(";REPT(" ";999));")";REPT(" ";999));999*5;999))&"; "&
TRIM(MID(SUBSTITUTE(SUBSTITUTE(A3;"(";REPT(" ";999));")";REPT(" ";999));999*7;999))&"; "&
TRIM(MID(SUBSTITUTE(SUBSTITUTE(A3;"(";REPT(" ";999));")";REPT(" ";999));999*9;999));"; ; ";"")

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Сообщение отредактировал bmv98rus - Понедельник, 22.04.2019, 16:58

Ответить

Samaretz

Дата: Вторник, 23.04.2019, 07:56 | Сообщение № 10

Группа: Проверенные

Ранг: Форумчанин

Сообщений: 223

Репутация: 63 ±

Замечаний: 0% ±

Excel 2010; 2013; 2016

С доп.ячейками, но количество скобок в исходном выражении никак не лимитируется - формулы в колонках А, В и С можно протягивать вниз сколь угодно далеко; при этом формула в ячейке D3 в любом случае выдаст корректный результат (если количество строк в первых трех колонках достаточно).

К сообщению приложен файл: 3249744.xlsx (10.5 Kb)

Ответить

танбраун

Дата: Вторник, 23.04.2019, 08:17 | Сообщение № 11

Группа: Пользователи

Ранг: Участник

Сообщений: 54

Репутация: 0 ±

Замечаний: 0% ±

Excel 2013

Всем ответившим большое спасибо.

Ответить

Светлый

Дата: Среда, 24.04.2019, 06:50 | Сообщение № 12

Группа: Друзья

Ранг: Старожил

Сообщений: 1829

Репутация: 510 ±

Замечаний: 0% ±

Excel 2013, 2016

Всё крутилось в голове и родилось. СЖПРОБЕЛЫ только один раз, нет ЕСЛИОШИБКА и хвостик убирает аккуратно:

Код

=ПОДСТАВИТЬ(СЖПРОБЕЛЫ(ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("!";ПОДСТАВИТЬ(A3&"!)";"(";"!";1))+1;999);")";";"&ПОВТОР(" ";999));999)&ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("!";ПОДСТАВИТЬ(A3&"!)";"(";"!";2))+1;999);")";";"&ПОВТОР(" ";999));999)&ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("!";ПОДСТАВИТЬ(A3&"!)";"(";"!";3))+1;999);")";";"&ПОВТОР(" ";999));999)&ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("!";ПОДСТАВИТЬ(A3&"!)";"(";"!";4))+1;999);")";";"&ПОВТОР(" ";999));999)&ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("!";ПОДСТАВИТЬ(A3&"!)";"(";"!";5))+1;999);")";";"&ПОВТОР(" ";999));999))&-1;";-1";)

Nic70y, Извините, что правлю Вашу формулу. "; " лучше ставить в начало под ЕСЛИОШИБКА и тогда хвосты не надо рубить:

Код

=ПОДСТАВИТЬ(СЖПРОБЕЛЫ(ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("(";A3)+1;999);")";ПОВТОР(" ";999));999)&ЕСЛИОШИБКА("; "&ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("\";ПОДСТАВИТЬ(A3;"(";"\";2))+1;999);")";ПОВТОР(" ";999));999);"")&ЕСЛИОШИБКА("; "&ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("\";ПОДСТАВИТЬ(A3;"(";"\";3))+1;999);")";ПОВТОР(" ";999));999);"")&ЕСЛИОШИБКА("; "&ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("\";ПОДСТАВИТЬ(A3;"(";"\";4))+1;999);")";ПОВТОР(" ";999));999);"")&ЕСЛИОШИБКА("; "&ЛЕВБ(ПОДСТАВИТЬ(ПСТР(A3;ПОИСК("\";ПОДСТАВИТЬ(A3;"(";"\";5))+1;999);")";ПОВТОР(" ";999));999);""));" ;";";")

Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Среда, 24.04.2019, 06:53

Ответить

bmv98rus

Дата: Среда, 24.04.2019, 07:55 | Сообщение № 13

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4106

Репутация: 768 ±

Замечаний: 0% ±

Excel 2013/2016

ну если хвосты мешают, то

Код

=SUBSTITUTE(SUBSTITUTE(TRIM(SUBSTITUTE(SUBSTITUTE(TRIM(
MID(SUBSTITUTE(SUBSTITUTE(A4;"(";REPT(" ";999));")";REPT(" ";999));999*1;999)&";"&
MID(SUBSTITUTE(SUBSTITUTE(A4;"(";REPT(" ";999));")";REPT(" ";999));999*3;999)&";"&
MID(SUBSTITUTE(SUBSTITUTE(A4;"(";REPT(" ";999));")";REPT(" ";999));999*5;999)&";"&
MID(SUBSTITUTE(SUBSTITUTE(A4;"(";REPT(" ";999));")";REPT(" ";999));999*7;999)&";"&
MID(SUBSTITUTE(SUBSTITUTE(A4;"(";REPT(" ";999));")";REPT(" ";999));999*9;999));
" ";"/");";";" "));" ";";");"/";" ")

~~Замечательный~~ Временно просто медведь ~~, процентов на 20~~.

Ответить

Светлый

Дата: Среда, 24.04.2019, 09:18 | Сообщение № 14

Группа: Друзья

Ранг: Старожил

Сообщений: 1829

Репутация: 510 ±

Замечаний: 0% ±

Excel 2013, 2016

Совместная с bmv98rus формула:

Код

=ПОДСТАВИТЬ(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";ПОВТОР(" ";999));")";";"&ПОВТОР(" ";999));999*1;999)&ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";ПОВТОР(" ";999));")";";"&ПОВТОР(" ";999));999*3;999)&ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";ПОВТОР(" ";999));")";";"&ПОВТОР(" ";999));999*5;999)&ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";ПОВТОР(" ";999));")";";"&ПОВТОР(" ";999));999*7;999)&ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";ПОВТОР(" ";999));")";ПОВТОР(" ";999));999*9;999))&-1;";-1";)

Программировать проще, чем писать стихи.

Ответить

Светлый

Дата: Среда, 24.04.2019, 10:51 | Сообщение № 15

Группа: Друзья

Ранг: Старожил

Сообщений: 1829

Репутация: 510 ±

Замечаний: 0% ±

Excel 2013, 2016

А ещё лучше вот так:

Код

=ПОДСТАВИТЬ(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";")");")";";"&ПОВТОР(" ";999));999*1;999)&ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";")");")";";"&ПОВТОР(" ";999));999*3;999)&ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";")");")";";"&ПОВТОР(" ";999));999*5;999)&ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";")");")";";"&ПОВТОР(" ";999));999*7;999)&ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";")");")";";"&ПОВТОР(" ";999));999*9;999))&"#";";#";)

*В формуле была небольшая ошибка. Исправил.
И ещё формула:

Код

=ПОДСТАВИТЬ(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";")");")";ПОВТОР(" ";999));999*1;999)&ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";"); ");")";ПОВТОР(" ";999));999*3;999)&ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";"); ");")";ПОВТОР(" ";999));999*5;999)&ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";"); ");")";ПОВТОР(" ";999));999*7;999)&ПСТР(ПОДСТАВИТЬ(ПОДСТАВИТЬ(A3;"(";"); ");")";ПОВТОР(" ";999));999*9;999));" ;";";")

Первый элемент отличается от остальных.

Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Среда, 24.04.2019, 13:31

Ответить

bmv98rus

Дата: Среда, 24.04.2019, 15:09 | Сообщение № 16

Группа: Друзья

Ранг: Участник клуба

Сообщений: 4106

Репутация: 768 ±

Замечаний: 0% ±

Excel 2013/2016

Код

=MID(TRIM(MID(SUBSTITUTE(SUBSTITUTE(A3;"(";"); ");")";REPT(" ";999));999*1;999)&
MID(SUBSTITUTE(SUBSTITUTE(A3;"(";"); ");")";REPT(" ";999));999*3;999)&
MID(SUBSTITUTE(SUBSTITUTE(A3;"(";"); ");")";REPT(" ";999));999*5;999)&
MID(SUBSTITUTE(SUBSTITUTE(A3;"(";"); ");")";REPT(" ";999));999*7;999)&
MID(SUBSTITUTE(SUBSTITUTE(A3;"(";"); ");")";REPT(" ";999));999*9;999));3;2^15)

Но разделитель с лишним пробелом