Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Смещ в Агрегатее выдает ЗНАЧ при вычислении - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Смещ в Агрегатее выдает ЗНАЧ при вычислении (Формулы/Formulas)
Смещ в Агрегатее выдает ЗНАЧ при вычислении
ZetMenChavo Дата: Понедельник, 10.05.2021, 08:49 | Сообщение № 1
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 138
Репутация: 7 ±
Замечаний: 0% ±

Excel 2010
Здравствуйте.
Дело в следующем, в таблице использовал функцию АГРЕГАТ для поиска значения по нескольким критериям (т.к. в критериях есть и текст, и выводить тоже нужно текст, СУММЕСЛИМН не вариант). Но так как требуется проводить поиск сразу по нескольким группам критериев и получать результаты на них одновременно, формула находиться в нескольких ячейках. Изначально проблема с ней в том что в каждой ячейке приходилось в ручную подгонять формулу чтобы работала, но освоив функцию СМЕЩ, решил переделать прошлую функцию, что бы можно было её протягивать.
Написал формулу грамотно без ошибок, но в результате получал ошибку. Стал смотреть как она вычислялась и увидел что СМЕЩ почему то вместо диапазона выдавала ошибку ЗНАЧ, но когда решил проверить, работает ли СМЕЩ с АГРЕГАТом записав мелкий вариант, увидел что СМЕЩ нормально даёт диапазон.
Постепенно добавляя формулы в АГРЕГАТ я обнаружил что ошибка начинает выскакивать когда я в параметры "смещ_по_строкам/столбцам" добавляю формулы, в моём случае СТРОКА и СТОЛБЕЦ.
Единственный выход который я смог найти, это вынести расчёт столбцов и строк в другие ячейки и уже на эти ячейки ссылать параметры смещ_по..., но всё же хотелось бы сделать формулу без использования дополнительных ячеек, так что прошу подскажите, кто знает, можно ли как то заставить СМЕЩ нормально работать с функциями СТРОКА и СТОЛБЕЦ.

Из прикреплённого файла:
Формула в B5
Код
=(СТОЛБЕЦ()-СТОЛБЕЦ($B$4))/3

Результат идёт в эту формулу, и тут всё работает
Код
=АГРЕГАТ(15;6;(СТРОКА($A$15:$A$24)-СТРОКА($A$14))/(СМЕЩ($B$15;;;10)=СМЕЩ($A$1;B5;));1)

а если соединить их как в этой, то уже нет
Код
=АГРЕГАТ(15;6;(СТРОКА($A$15:$A$24)-СТРОКА($A$14))/(СМЕЩ($B$15;;;10)=СМЕЩ($A$1;(СТОЛБЕЦ()-СТОЛБЕЦ($B$4))/3;));1)
К сообщению приложен файл: 1878279.xlsx(10.1 Kb)


Сообщение отредактировал ZetMenChavo - Понедельник, 10.05.2021, 08:58
 
Ответить
СообщениеЗдравствуйте.
Дело в следующем, в таблице использовал функцию АГРЕГАТ для поиска значения по нескольким критериям (т.к. в критериях есть и текст, и выводить тоже нужно текст, СУММЕСЛИМН не вариант). Но так как требуется проводить поиск сразу по нескольким группам критериев и получать результаты на них одновременно, формула находиться в нескольких ячейках. Изначально проблема с ней в том что в каждой ячейке приходилось в ручную подгонять формулу чтобы работала, но освоив функцию СМЕЩ, решил переделать прошлую функцию, что бы можно было её протягивать.
Написал формулу грамотно без ошибок, но в результате получал ошибку. Стал смотреть как она вычислялась и увидел что СМЕЩ почему то вместо диапазона выдавала ошибку ЗНАЧ, но когда решил проверить, работает ли СМЕЩ с АГРЕГАТом записав мелкий вариант, увидел что СМЕЩ нормально даёт диапазон.
Постепенно добавляя формулы в АГРЕГАТ я обнаружил что ошибка начинает выскакивать когда я в параметры "смещ_по_строкам/столбцам" добавляю формулы, в моём случае СТРОКА и СТОЛБЕЦ.
Единственный выход который я смог найти, это вынести расчёт столбцов и строк в другие ячейки и уже на эти ячейки ссылать параметры смещ_по..., но всё же хотелось бы сделать формулу без использования дополнительных ячеек, так что прошу подскажите, кто знает, можно ли как то заставить СМЕЩ нормально работать с функциями СТРОКА и СТОЛБЕЦ.

Из прикреплённого файла:
Формула в B5
Код
=(СТОЛБЕЦ()-СТОЛБЕЦ($B$4))/3

Результат идёт в эту формулу, и тут всё работает
Код
=АГРЕГАТ(15;6;(СТРОКА($A$15:$A$24)-СТРОКА($A$14))/(СМЕЩ($B$15;;;10)=СМЕЩ($A$1;B5;));1)

а если соединить их как в этой, то уже нет
Код
=АГРЕГАТ(15;6;(СТРОКА($A$15:$A$24)-СТРОКА($A$14))/(СМЕЩ($B$15;;;10)=СМЕЩ($A$1;(СТОЛБЕЦ()-СТОЛБЕЦ($B$4))/3;));1)

Автор - ZetMenChavo
Дата добавления - 10.05.2021 в 08:49
Pelena Дата: Понедельник, 10.05.2021, 09:17 | Сообщение № 2
Группа: Админы
Ранг: Местный житель
Сообщений: 18616
Репутация: 4220 ±
Замечаний: ±

Excel 2016 & Mac Excel
Здравствуйте.
Или я чего-то не понимаю, или одно из двух(с)
Так не подойдёт разве?
Код
=ЕСЛИОШИБКА(ИНДЕКС($A$16:$A$25;ПОИСКПОЗ(C$12;$B$16:$B$25;0));"")

см. желтые ячейки
К сообщению приложен файл: 8624959.xlsx(11.1 Kb)


"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
СообщениеЗдравствуйте.
Или я чего-то не понимаю, или одно из двух(с)
Так не подойдёт разве?
Код
=ЕСЛИОШИБКА(ИНДЕКС($A$16:$A$25;ПОИСКПОЗ(C$12;$B$16:$B$25;0));"")

см. желтые ячейки

Автор - Pelena
Дата добавления - 10.05.2021 в 09:17
ZetMenChavo Дата: Понедельник, 10.05.2021, 09:24 | Сообщение № 3
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 138
Репутация: 7 ±
Замечаний: 0% ±

Excel 2010
Pelena, Нет, дело в том что в файле упрощённая версия, с той частью где ошибка возникает, ПОИСКПОЗ не позволял сделать то чего я хотел добиться, вот и перешёл на АГРЕГАТ.
Вот как выглядит формула из основной таблицы
Код
=ЕСЛИОШИБКА(ИНДЕКС($B$165:$B$219;АГРЕГАТ(15;6;(СТРОКА($B$165:$B$219)-СТРОКА($B$164))/(($A$165:$A$219>0)*($E$165:$E$219<>"")*($F$165:$F$219="Б")*(ПОИСК($A159;$Q$165:$Q$219)>0));1));"")

Как видите, тут есть критерии, которые некуда вставить в функцию ПОИСКПОЗ
Я хочу вот эту часть переделать с использованием СМЕЩ,
Код
=($F$165:$F$219="Б")

т.к. в верхней формуле приходилось вручную сдвигать диапазон и менять букву "Б"


Сообщение отредактировал ZetMenChavo - Понедельник, 10.05.2021, 09:30
 
Ответить
СообщениеPelena, Нет, дело в том что в файле упрощённая версия, с той частью где ошибка возникает, ПОИСКПОЗ не позволял сделать то чего я хотел добиться, вот и перешёл на АГРЕГАТ.
Вот как выглядит формула из основной таблицы
Код
=ЕСЛИОШИБКА(ИНДЕКС($B$165:$B$219;АГРЕГАТ(15;6;(СТРОКА($B$165:$B$219)-СТРОКА($B$164))/(($A$165:$A$219>0)*($E$165:$E$219<>"")*($F$165:$F$219="Б")*(ПОИСК($A159;$Q$165:$Q$219)>0));1));"")

Как видите, тут есть критерии, которые некуда вставить в функцию ПОИСКПОЗ
Я хочу вот эту часть переделать с использованием СМЕЩ,
Код
=($F$165:$F$219="Б")

т.к. в верхней формуле приходилось вручную сдвигать диапазон и менять букву "Б"

Автор - ZetMenChavo
Дата добавления - 10.05.2021 в 09:24
Pelena Дата: Понедельник, 10.05.2021, 09:32 | Сообщение № 4
Группа: Админы
Ранг: Местный житель
Сообщений: 18616
Репутация: 4220 ±
Замечаний: ±

Excel 2016 & Mac Excel
Не убедили. Приложите более полный пример.
Функцию СМЕЩ надо использовать только в крайних случаях, когда другие способы не работают. Из-за её волатильности


"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
СообщениеНе убедили. Приложите более полный пример.
Функцию СМЕЩ надо использовать только в крайних случаях, когда другие способы не работают. Из-за её волатильности

Автор - Pelena
Дата добавления - 10.05.2021 в 09:32
ZetMenChavo Дата: Понедельник, 10.05.2021, 10:03 | Сообщение № 5
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 138
Репутация: 7 ±
Замечаний: 0% ±

Excel 2010
Pelena, Вот из основной таблицы, надеюсь достаточно облегчил файл
К сообщению приложен файл: 8112520.xlsx(20.7 Kb)
 
Ответить
СообщениеPelena, Вот из основной таблицы, надеюсь достаточно облегчил файл

Автор - ZetMenChavo
Дата добавления - 10.05.2021 в 10:03
Pelena Дата: Понедельник, 10.05.2021, 10:28 | Сообщение № 6
Группа: Админы
Ранг: Местный житель
Сообщений: 18616
Репутация: 4220 ±
Замечаний: ±

Excel 2016 & Mac Excel
Вместо
Код
($F$14:$F$68="Б")
написать
Код
($F$14:$F$68=C$7)
не вариант? Или я опять не о том?
К сообщению приложен файл: 2837550.xlsx(20.7 Kb)


"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
СообщениеВместо
Код
($F$14:$F$68="Б")
написать
Код
($F$14:$F$68=C$7)
не вариант? Или я опять не о том?

Автор - Pelena
Дата добавления - 10.05.2021 в 10:28
ZetMenChavo Дата: Понедельник, 10.05.2021, 10:44 | Сообщение № 7
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 138
Репутация: 7 ±
Замечаний: 0% ±

Excel 2010
Pelena, так то да, можно вынести проблемный участок формулы что бы всё заработало, но как я писал в начале, хотелось бы не задействовать дополнительные ячейки, чисто из эстетических мотивов. поэтому и хочу узнать можно ли как то заставить работать СМЕЩ нормально
Код
=СМЕЩ($C$126;(СТОЛБЕЦ()-СТОЛБЕЦ($B$159))/3;)
, когда вставляю её в АГРЕГАТ.
Что можно сделать с формулами СТОЛБЕЦ, что бы из-за них СМЕЩ не выдавал ошибку?
 
Ответить
СообщениеPelena, так то да, можно вынести проблемный участок формулы что бы всё заработало, но как я писал в начале, хотелось бы не задействовать дополнительные ячейки, чисто из эстетических мотивов. поэтому и хочу узнать можно ли как то заставить работать СМЕЩ нормально
Код
=СМЕЩ($C$126;(СТОЛБЕЦ()-СТОЛБЕЦ($B$159))/3;)
, когда вставляю её в АГРЕГАТ.
Что можно сделать с формулами СТОЛБЕЦ, что бы из-за них СМЕЩ не выдавал ошибку?

Автор - ZetMenChavo
Дата добавления - 10.05.2021 в 10:44
Pelena Дата: Понедельник, 10.05.2021, 10:55 | Сообщение № 8
Группа: Админы
Ранг: Местный житель
Сообщений: 18616
Репутация: 4220 ±
Замечаний: ±

Excel 2016 & Mac Excel
А так?
Код
$F$14:$F$68=ИНДЕКС($A$2:$A$6;(СТОЛБЕЦ()-СТОЛБЕЦ($A$1))/3+1)

так тоже работает, но возможно будет тормозить из-за "летучести"
Код
$F$14:$F$68=СМЕЩ($A$2;(СТОЛБЕЦ()-СТОЛБЕЦ($B$8))/3;)


"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
СообщениеА так?
Код
$F$14:$F$68=ИНДЕКС($A$2:$A$6;(СТОЛБЕЦ()-СТОЛБЕЦ($A$1))/3+1)

так тоже работает, но возможно будет тормозить из-за "летучести"
Код
$F$14:$F$68=СМЕЩ($A$2;(СТОЛБЕЦ()-СТОЛБЕЦ($B$8))/3;)

Автор - Pelena
Дата добавления - 10.05.2021 в 10:55
ZetMenChavo Дата: Понедельник, 10.05.2021, 11:30 | Сообщение № 9
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 138
Репутация: 7 ±
Замечаний: 0% ±

Excel 2010
Pelena, вторая формула это мой изначальный вариант, где наличие формул СТОЛБЕЦ заставляет СМЕЩ выдавать ошибку, а вариант с ИНДЕКС работает, но ещё остается левая часть с диапазоном.
Он по плану должен смещаться в право при протягивании ячейки с формулой вниз. Я для того и обратил внимание на СМЕЩ что смещение диапазона
Код
=$F$14:$F$68
можно сделать зависимым от строки, но там уже формула СТРОКА приводит к той же ошибке что и СТОЛБЕЦ.


Сообщение отредактировал ZetMenChavo - Понедельник, 10.05.2021, 11:30
 
Ответить
СообщениеPelena, вторая формула это мой изначальный вариант, где наличие формул СТОЛБЕЦ заставляет СМЕЩ выдавать ошибку, а вариант с ИНДЕКС работает, но ещё остается левая часть с диапазоном.
Он по плану должен смещаться в право при протягивании ячейки с формулой вниз. Я для того и обратил внимание на СМЕЩ что смещение диапазона
Код
=$F$14:$F$68
можно сделать зависимым от строки, но там уже формула СТРОКА приводит к той же ошибке что и СТОЛБЕЦ.

Автор - ZetMenChavo
Дата добавления - 10.05.2021 в 11:30
ZetMenChavo Дата: Понедельник, 10.05.2021, 11:52 | Сообщение № 10
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 138
Репутация: 7 ±
Замечаний: 0% ±

Excel 2010
Pelena, Я заметил что, при вычислении, СТОЛБЕЦ()-СТОЛБЕЦ($B$8) становятся цифрами в фигурных скобках. Я заменял функции Столбцов в ячейке на числа без скобок в ручную, и СМЕЩ нормально становился диапазоном, а когда при помощи F9 превращал в ячейке СТОЛБЕЦ()-СТОЛБЕЦ($B$8) в {2}-{2}, то снова не работала. Похоже это из-за них. Что означают эти фигурные скобки, и как можно избавиться от них?
К сообщению приложен файл: 5429741.png(43.1 Kb) · 7282158.png(35.4 Kb)


Сообщение отредактировал ZetMenChavo - Понедельник, 10.05.2021, 11:54
 
Ответить
СообщениеPelena, Я заметил что, при вычислении, СТОЛБЕЦ()-СТОЛБЕЦ($B$8) становятся цифрами в фигурных скобках. Я заменял функции Столбцов в ячейке на числа без скобок в ручную, и СМЕЩ нормально становился диапазоном, а когда при помощи F9 превращал в ячейке СТОЛБЕЦ()-СТОЛБЕЦ($B$8) в {2}-{2}, то снова не работала. Похоже это из-за них. Что означают эти фигурные скобки, и как можно избавиться от них?

Автор - ZetMenChavo
Дата добавления - 10.05.2021 в 11:52
ZetMenChavo Дата: Понедельник, 10.05.2021, 12:33 | Сообщение № 11
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 138
Репутация: 7 ±
Замечаний: 0% ±

Excel 2010
:o О! Я нашёл способ обойти проблему не отдаляясь от первичной задумки слишком далеко :D
Не рабочий вариант
Код
=СМЕЩ($A$2;(СТОЛБЕЦ()-СТОЛБЕЦ($B$8))/3;)

А этот рабочий!!!
Код
=СМЕЩ($A$2;(ЯЧЕЙКА("столбец";B8)-ЯЧЕЙКА("столбец";$B$8))/3;)


Сообщение отредактировал ZetMenChavo - Понедельник, 10.05.2021, 12:33
 
Ответить
Сообщение:o О! Я нашёл способ обойти проблему не отдаляясь от первичной задумки слишком далеко :D
Не рабочий вариант
Код
=СМЕЩ($A$2;(СТОЛБЕЦ()-СТОЛБЕЦ($B$8))/3;)

А этот рабочий!!!
Код
=СМЕЩ($A$2;(ЯЧЕЙКА("столбец";B8)-ЯЧЕЙКА("столбец";$B$8))/3;)

Автор - ZetMenChavo
Дата добавления - 10.05.2021 в 12:33
Pelena Дата: Понедельник, 10.05.2021, 14:01 | Сообщение № 12
Группа: Админы
Ранг: Местный житель
Сообщений: 18616
Репутация: 4220 ±
Замечаний: ±

Excel 2016 & Mac Excel
Не рабочий вариант
Почему не рабочий? См. файл
Что означают эти фигурные скобки
это массив констант
как можно избавиться от них
попробуйте Ч(СТОЛБЕЦ()-СТОЛБЕЦ($B$8))
А этот рабочий
не лучший вариант: вместо одной волатильной функции теперь две :)

остается левая часть с диапазоном
если бы столбцы располагались через одинаковый интервал, то можно было бы примерно так
Код
ИНДЕКС($F$14:$P$68;0;(СТРОКА(A1)-1)*3+1)

а в Вашем случае как-то так
Код
ИНДЕКС($F$14:$P$68;0;ВЫБОР($A8;1;4;9))

см. лист 2
К сообщению приложен файл: 8112520-1-.xlsx(30.3 Kb)


"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
Сообщение
Не рабочий вариант
Почему не рабочий? См. файл
Что означают эти фигурные скобки
это массив констант
как можно избавиться от них
попробуйте Ч(СТОЛБЕЦ()-СТОЛБЕЦ($B$8))
А этот рабочий
не лучший вариант: вместо одной волатильной функции теперь две :)

остается левая часть с диапазоном
если бы столбцы располагались через одинаковый интервал, то можно было бы примерно так
Код
ИНДЕКС($F$14:$P$68;0;(СТРОКА(A1)-1)*3+1)

а в Вашем случае как-то так
Код
ИНДЕКС($F$14:$P$68;0;ВЫБОР($A8;1;4;9))

см. лист 2

Автор - Pelena
Дата добавления - 10.05.2021 в 14:01
ZetMenChavo Дата: Понедельник, 10.05.2021, 14:44 | Сообщение № 13
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 138
Репутация: 7 ±
Замечаний: 0% ±

Excel 2010
Pelena, В файле что то странное
Код
=ЕСЛИОШИБКА(_xlfn.SINGLE(ИНДЕКС($B$14:$B$68;АГРЕГАТ(15;6;(СТРОКА($B$14:$B$68)-СТРОКА($B$13))/(($A$14:$A$68>0)*($E$14:$E$68<>"")*(ИНДЕКС($F$14:$P$68;0;ВЫБОР($A8;1;4;9))=ИНДЕКС($A$2:$A$6;(СТОЛБЕЦ()-СТОЛБЕЦ($A$1))/3+1))*(ПОИСК($A8;$Q$14:$Q$68)>0));1)));"")

Участок _xlfn.SINGLE, то ли у меня версия старая что этой формулы нет, толи ещё что то, но в вашем файле у меня не заработало.
В принципе вычисление столбцов и строк через ф.ЯЧЕЙКА решила мою проблему, но учту и ваши варианты, поэкспериментирую с новыми формулами, может где пригодятся.

А касательно моей проблемы, я не сильно разбираюсь как разрабы делали все эти формулы, но думаю понял что работало не так.
АГРЕГАТ позволяет работать с массивами без использования Ctrl+Shift+Enter, т.е. все функции которые поддерживают работу массивов, автоматически считаются как массивы, без исключений. Функции СТОЛБЕЦ и СТРОКА одни из них, и хоть они были в ф.СМЕЩ, в целом они всё равно находились в АГРЕГАТе и выдавали результатом массив, даже если значение было всего одно, отсюда и брались цифры в фигурных скобках
Код
=СТРОКА(A1:A3)={1:2:3}

Код
=СТРОКА(А1)={1}

а СМЕЩ похоже не может использовать массивы для вычислений смещения ссылки или ширины с высотой, даже если значение всего одно, вот и выдавала ошибку #ЗНАЧ. А функция ЯЧЕЙКА наоборот не вычисляет массивы, поэтому и СМЕЩ принимает результаты вычисления этой функции.
Код
=ЯЧЕЙКА("строка";A1:A3)=1


Чтож, в целом Pelena спасибо, помогли отстраниться от корня проблемы и порассматривать другие варианты, что и помогло, а то со вчера сидел не мог разобраться :D


Сообщение отредактировал ZetMenChavo - Понедельник, 10.05.2021, 14:56
 
Ответить
СообщениеPelena, В файле что то странное
Код
=ЕСЛИОШИБКА(_xlfn.SINGLE(ИНДЕКС($B$14:$B$68;АГРЕГАТ(15;6;(СТРОКА($B$14:$B$68)-СТРОКА($B$13))/(($A$14:$A$68>0)*($E$14:$E$68<>"")*(ИНДЕКС($F$14:$P$68;0;ВЫБОР($A8;1;4;9))=ИНДЕКС($A$2:$A$6;(СТОЛБЕЦ()-СТОЛБЕЦ($A$1))/3+1))*(ПОИСК($A8;$Q$14:$Q$68)>0));1)));"")

Участок _xlfn.SINGLE, то ли у меня версия старая что этой формулы нет, толи ещё что то, но в вашем файле у меня не заработало.
В принципе вычисление столбцов и строк через ф.ЯЧЕЙКА решила мою проблему, но учту и ваши варианты, поэкспериментирую с новыми формулами, может где пригодятся.

А касательно моей проблемы, я не сильно разбираюсь как разрабы делали все эти формулы, но думаю понял что работало не так.
АГРЕГАТ позволяет работать с массивами без использования Ctrl+Shift+Enter, т.е. все функции которые поддерживают работу массивов, автоматически считаются как массивы, без исключений. Функции СТОЛБЕЦ и СТРОКА одни из них, и хоть они были в ф.СМЕЩ, в целом они всё равно находились в АГРЕГАТе и выдавали результатом массив, даже если значение было всего одно, отсюда и брались цифры в фигурных скобках
Код
=СТРОКА(A1:A3)={1:2:3}

Код
=СТРОКА(А1)={1}

а СМЕЩ похоже не может использовать массивы для вычислений смещения ссылки или ширины с высотой, даже если значение всего одно, вот и выдавала ошибку #ЗНАЧ. А функция ЯЧЕЙКА наоборот не вычисляет массивы, поэтому и СМЕЩ принимает результаты вычисления этой функции.
Код
=ЯЧЕЙКА("строка";A1:A3)=1


Чтож, в целом Pelena спасибо, помогли отстраниться от корня проблемы и порассматривать другие варианты, что и помогло, а то со вчера сидел не мог разобраться :D

Автор - ZetMenChavo
Дата добавления - 10.05.2021 в 14:44
Pelena Дата: Понедельник, 10.05.2021, 16:11 | Сообщение № 14
Группа: Админы
Ранг: Местный житель
Сообщений: 18616
Репутация: 4220 ±
Замечаний: ±

Excel 2016 & Mac Excel
В файле что то странное

а так?
К сообщению приложен файл: 7436665.xlsx(30.2 Kb)


"Черт возьми, Холмс! Но как??!!"
Ю-money 41001765434816
 
Ответить
Сообщение
В файле что то странное

а так?

Автор - Pelena
Дата добавления - 10.05.2021 в 16:11
ZetMenChavo Дата: Понедельник, 10.05.2021, 16:20 | Сообщение № 15
Группа: Проверенные
Ранг: Форумчанин
Сообщений: 138
Репутация: 7 ±
Замечаний: 0% ±

Excel 2010
Pelena, да, работает, тоже хороший вариант :)
 
Ответить
СообщениеPelena, да, работает, тоже хороший вариант :)

Автор - ZetMenChavo
Дата добавления - 10.05.2021 в 16:20
Светлый Дата: Понедельник, 10.05.2021, 19:40 | Сообщение № 16
Группа: Друзья
Ранг: Старожил
Сообщений: 1742
Репутация: 478 ±
Замечаний: 0% ±

Excel 2013, 2016
Сильно разбираться не стал. Вот подправленная формула для ячеек B8:P10 :
Код
=ЕСЛИОШИБКА(ИНДЕКС($B$14:$B$68;АГРЕГАТ(15;6;(СТРОКА($B$14:$B$68)-СТРОКА($B$13))/(($A$14:$A$68>0)*($E$14:$E$68<>"")*(ИНДЕКС($F$14:$P$68;;ПСТР(149;$A8;1))=ИНДЕКС($A$2:$A$6;СТОЛБЕЦ(C4)/3))*(ПОИСК($A8;$Q$14:$Q$68)>0));1));"")
*Или с поправкой по столбцу:
Код
=ЕСЛИОШИБКА(ИНДЕКС($B$14:$B$68;АГРЕГАТ(15;6;(СТРОКА($B$14:$B$68)-СТРОКА($B$13))/(($A$14:$A$68>0)*($E$14:$E$68<>"")*(ИНДЕКС($F$14:$P$68;;$A8^2)=ИНДЕКС($A$2:$A$6;СТОЛБЕЦ(C4)/3))*(ПОИСК($A8;$Q$14:$Q$68)>0));1));"")


Программировать проще, чем писать стихи.

Сообщение отредактировал Светлый - Понедельник, 10.05.2021, 19:44
 
Ответить
СообщениеСильно разбираться не стал. Вот подправленная формула для ячеек B8:P10 :
Код
=ЕСЛИОШИБКА(ИНДЕКС($B$14:$B$68;АГРЕГАТ(15;6;(СТРОКА($B$14:$B$68)-СТРОКА($B$13))/(($A$14:$A$68>0)*($E$14:$E$68<>"")*(ИНДЕКС($F$14:$P$68;;ПСТР(149;$A8;1))=ИНДЕКС($A$2:$A$6;СТОЛБЕЦ(C4)/3))*(ПОИСК($A8;$Q$14:$Q$68)>0));1));"")
*Или с поправкой по столбцу:
Код
=ЕСЛИОШИБКА(ИНДЕКС($B$14:$B$68;АГРЕГАТ(15;6;(СТРОКА($B$14:$B$68)-СТРОКА($B$13))/(($A$14:$A$68>0)*($E$14:$E$68<>"")*(ИНДЕКС($F$14:$P$68;;$A8^2)=ИНДЕКС($A$2:$A$6;СТОЛБЕЦ(C4)/3))*(ПОИСК($A8;$Q$14:$Q$68)>0));1));"")

Автор - Светлый
Дата добавления - 10.05.2021 в 19:40
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Смещ в Агрегатее выдает ЗНАЧ при вычислении (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2022 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!