Option Explicit

Private Sub Workbook_Open()
    Dim i As Long, j As Long

    Dim ws          As Worksheet
    Set ws = ThisWorkbook.Worksheets("Лист1")

    Dim checkCol    As String
    checkCol = "AH"

    Dim linkSources As Variant
    linkSources = ThisWorkbook.linkSources(Type:=xlExcelLinks)

    ThisWorkbook.RefreshAll
    DoEvents

    If Not IsEmpty(linkSources) Then

        For j = LBound(linkSources) To UBound(linkSources)
            ThisWorkbook.UpdateLink Name:=linkSources(j), Type:=xlLinkTypeExcelLinks
        Next j

    End If

    Application.CalculateFull
    DoEvents

    Dim calc_mode   As Long
    calc_mode = Application.Calculation

    Application.ScreenUpdating = False
    Application.Calculation = xlCalculationManual

    For i = 6 To ws.Cells(ws.Rows.Count, ws.Columns(checkCol).Column).End(xlUp).Row

        If IsRowEmpty(i, checkCol) Then
            Rows(i).EntireRow.Hidden = True
        End If

    Next i

    Application.Calculation = calc_mode
    Application.ScreenUpdating = True
End Sub

Function IsRowEmpty(ByVal rowNum As Long, ByVal checkCol As String) As Boolean
    Dim cellValue   As Variant
    cellValue = Cells(rowNum, checkCol).Value

    IsRowEmpty = False

    If Len(cellValue) = 0 Or cellValue = 0 Then
        IsRowEmpty = True
    End If

End Function