Домашняя страница Undo Do New Save Карта сайта Обратная связь Поиск по форуму
МИР MS EXCEL - Гость.xls

Вход

Регистрация

Напомнить пароль

 

= Мир MS Excel/Сократить длинные ФИО до коротких ФИО. - Мир MS Excel

Старая форма входа
  • Страница 1 из 1
  • 1
Модератор форума: китин, _Boroda_, DrMini  
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Сократить длинные ФИО до коротких ФИО. (Формулы/Formulas)
Сократить длинные ФИО до коротких ФИО.
Mark1976 Дата: Среда, 13.11.2024, 19:32 | Сообщение № 1
Группа: Проверенные
Ранг: Ветеран
Сообщений: 809
Репутация: 3 ±
Замечаний: 0% ±

Excel 2010, 2013
Здравствуйте. Есть таблица с данными. В ячейке А3 написано Иванов Иван Иванович мне надо быстро сделать формулой И.И.И. Заранее спасибо.
 
Ответить
СообщениеЗдравствуйте. Есть таблица с данными. В ячейке А3 написано Иванов Иван Иванович мне надо быстро сделать формулой И.И.И. Заранее спасибо.
Автор - Mark1976
Дата добавления - 13.11.2024 в 19:32
прохожий2019 Дата: Среда, 13.11.2024, 19:54 | Сообщение № 2
Группа: Проверенные
Ранг: Старожил
Сообщений: 1395
Репутация: 364 ±
Замечаний: 0% ±

365 Beta Channel
365
Код
=СЦЕП(ЛЕВБ(ТЕКСТРАЗД(A1;" "))&".")


Сообщение отредактировал прохожий2019 - Среда, 13.11.2024, 20:20
 
Ответить
Сообщение365
Код
=СЦЕП(ЛЕВБ(ТЕКСТРАЗД(A1;" "))&".")
Автор - прохожий2019
Дата добавления - 13.11.2024 в 19:54
i691198 Дата: Среда, 13.11.2024, 20:08 | Сообщение № 3
Группа: Проверенные
Ранг: Обитатель
Сообщений: 422
Репутация: 131 ±
Замечаний: 0% ±

2016
Для старых версий офиса формула длиннее.
Код
=ЛЕВСИМВ(A3;1)&". "&ЛЕВСИМВ(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(A3;" ";ПОВТОР(" ";50));50;50));1)&". " &ЛЕВСИМВ(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(A3;" ";ПОВТОР(" ";50));100;50));1)&"."
 
Ответить
СообщениеДля старых версий офиса формула длиннее.
Код
=ЛЕВСИМВ(A3;1)&". "&ЛЕВСИМВ(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(A3;" ";ПОВТОР(" ";50));50;50));1)&". " &ЛЕВСИМВ(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(A3;" ";ПОВТОР(" ";50));100;50));1)&"."
Автор - i691198
Дата добавления - 13.11.2024 в 20:08
Mark1976 Дата: Среда, 13.11.2024, 20:17 | Сообщение № 4
Группа: Проверенные
Ранг: Ветеран
Сообщений: 809
Репутация: 3 ±
Замечаний: 0% ±

Excel 2010, 2013
прохожий2019, не получилось.
 
Ответить
Сообщениепрохожий2019, не получилось.
Автор - Mark1976
Дата добавления - 13.11.2024 в 20:17
прохожий2019 Дата: Среда, 13.11.2024, 20:17 | Сообщение № 5
Группа: Проверенные
Ранг: Старожил
Сообщений: 1395
Репутация: 364 ±
Замечаний: 0% ±

365 Beta Channel
для старых
Код
=ЛЕВБ(A1)&"."&ПСТР(A1;ПОИСК(" ";A1)+1;1)&"."&ПСТР(A1;ПОИСК(" ";A1;ПОИСК(" ";A1)+1)+1;1)&"."
 
Ответить
Сообщениедля старых
Код
=ЛЕВБ(A1)&"."&ПСТР(A1;ПОИСК(" ";A1)+1;1)&"."&ПСТР(A1;ПОИСК(" ";A1;ПОИСК(" ";A1)+1)+1;1)&"."
Автор - прохожий2019
Дата добавления - 13.11.2024 в 20:17
Mark1976 Дата: Среда, 13.11.2024, 20:22 | Сообщение № 6
Группа: Проверенные
Ранг: Ветеран
Сообщений: 809
Репутация: 3 ±
Замечаний: 0% ±

Excel 2010, 2013
прохожий2019, ваша формула сработала. спасибо. Всем спасибо за интерес к теме.
 
Ответить
Сообщениепрохожий2019, ваша формула сработала. спасибо. Всем спасибо за интерес к теме.
Автор - Mark1976
Дата добавления - 13.11.2024 в 20:22
2version Дата: Среда, 13.11.2024, 20:28 | Сообщение № 7
Группа: Пользователи
Ранг: Новичок
Сообщений: 41
Репутация: 2 ±
Замечаний: 0% ±

Здравствуйте, попробуйте так:
Код
=ЛЕВСИМВ(A1;1) & "." & ЛЕВСИМВ(ПСТР(A1;ПОИСК(" ";A1)+1;99);1) & "." & ЛЕВСИМВ(ПСТР(A1;ПОИСК(" ";A1;ПОИСК(" ";A1)+1)+1;99);1) & "."


Сообщение отредактировал 2version - Среда, 13.11.2024, 20:29
 
Ответить
СообщениеЗдравствуйте, попробуйте так:
Код
=ЛЕВСИМВ(A1;1) & "." & ЛЕВСИМВ(ПСТР(A1;ПОИСК(" ";A1)+1;99);1) & "." & ЛЕВСИМВ(ПСТР(A1;ПОИСК(" ";A1;ПОИСК(" ";A1)+1)+1;99);1) & "."
Автор - 2version
Дата добавления - 13.11.2024 в 20:28
Egyptian Дата: Среда, 13.11.2024, 20:59 | Сообщение № 8
Группа: Проверенные
Ранг: Ветеран
Сообщений: 531
Репутация: 194 ±
Замечаний: 0% ±

Excel 2013/2016
Для более коротких имен (типа Чонг Ли, Ю Чжоу и Бен Джонсон) в том числе:
Код
=IFERROR(REPLACE(REPLACE(REPLACE(REPT(".";2);1;1;LEFT(A3));FIND(" ";A3)+2;2;MID(A3;FIND(" ";A3);2)&".");FIND("@";SUBSTITUTE(A3;" ";"@";2));2;MID(A3;FIND("@";SUBSTITUTE(A3;" ";"@";2));2)&".");REPLACE(REPLACE(REPT(".";2);1;1;LEFT(A3));FIND(" ";A3)+2;2;MID(A3;FIND(" ";A3);2)&"."))
 
Ответить
СообщениеДля более коротких имен (типа Чонг Ли, Ю Чжоу и Бен Джонсон) в том числе:
Код
=IFERROR(REPLACE(REPLACE(REPLACE(REPT(".";2);1;1;LEFT(A3));FIND(" ";A3)+2;2;MID(A3;FIND(" ";A3);2)&".");FIND("@";SUBSTITUTE(A3;" ";"@";2));2;MID(A3;FIND("@";SUBSTITUTE(A3;" ";"@";2));2)&".");REPLACE(REPLACE(REPT(".";2);1;1;LEFT(A3));FIND(" ";A3)+2;2;MID(A3;FIND(" ";A3);2)&"."))
Автор - Egyptian
Дата добавления - 13.11.2024 в 20:59
Nic70y Дата: Четверг, 14.11.2024, 08:58 | Сообщение № 9
Группа: Друзья
Ранг: Экселист
Сообщений: 9130
Репутация: 2415 ±
Замечаний: 0% ±

Excel 2010
Цитата Egyptian, 13.11.2024 в 20:59, в сообщении № 8 ()
Для более коротких имен
Код
=ПОДСТАВИТЬ(ЛЕВБ(A1)&ПСТР(A1;ПОИСК(" ";A1);2)&ПСТР(A1;ПОИСК(" ";ПОДСТАВИТЬ(A1;" ";;1)&" ")+1;2);" ";".")&"."

ЮMoney 41001841029809
 
Ответить
Сообщение
Цитата Egyptian, 13.11.2024 в 20:59, в сообщении № 8 ()
Для более коротких имен
Код
=ПОДСТАВИТЬ(ЛЕВБ(A1)&ПСТР(A1;ПОИСК(" ";A1);2)&ПСТР(A1;ПОИСК(" ";ПОДСТАВИТЬ(A1;" ";;1)&" ")+1;2);" ";".")&"."
Автор - Nic70y
Дата добавления - 14.11.2024 в 08:58
Mark1976 Дата: Воскресенье, 08.06.2025, 19:53 | Сообщение № 10
Группа: Проверенные
Ранг: Ветеран
Сообщений: 809
Репутация: 3 ±
Замечаний: 0% ±

Excel 2010, 2013
Здравствуйте. Можно внести изменение в формулу? Надо из Иванов Иван Иванович сделать Иванов И.И. Первое имя в ячейке A2


Сообщение отредактировал Mark1976 - Воскресенье, 08.06.2025, 19:55
 
Ответить
СообщениеЗдравствуйте. Можно внести изменение в формулу? Надо из Иванов Иван Иванович сделать Иванов И.И. Первое имя в ячейке A2
Автор - Mark1976
Дата добавления - 08.06.2025 в 19:53
прохожий2019 Дата: Воскресенье, 08.06.2025, 19:59 | Сообщение № 11
Группа: Проверенные
Ранг: Старожил
Сообщений: 1395
Репутация: 364 ±
Замечаний: 0% ±

365 Beta Channel
Цитата Mark1976, 08.06.2025 в 19:53, в сообщении № 10 ()
Можно внести изменение в формулу?
просто радикальное изменение потребуется...
Код
=ЛЕВБ(A1;ПОИСК(" ";A1))&ПСТР(A1;ПОИСК(" ";A1)+1;1)&"."&ПСТР(A1;ПОИСК(" ";A1;ПОИСК(" ";A1)+1)+1;1)&"."
 
Ответить
Сообщение
Цитата Mark1976, 08.06.2025 в 19:53, в сообщении № 10 ()
Можно внести изменение в формулу?
просто радикальное изменение потребуется...
Код
=ЛЕВБ(A1;ПОИСК(" ";A1))&ПСТР(A1;ПОИСК(" ";A1)+1;1)&"."&ПСТР(A1;ПОИСК(" ";A1;ПОИСК(" ";A1)+1)+1;1)&"."
Автор - прохожий2019
Дата добавления - 08.06.2025 в 19:59
Mark1976 Дата: Воскресенье, 08.06.2025, 20:13 | Сообщение № 12
Группа: Проверенные
Ранг: Ветеран
Сообщений: 809
Репутация: 3 ±
Замечаний: 0% ±

Excel 2010, 2013
прохожий2019, спасибо.
 
Ответить
Сообщениепрохожий2019, спасибо.
Автор - Mark1976
Дата добавления - 08.06.2025 в 20:13
DrMini Дата: Понедельник, 09.06.2025, 06:35 | Сообщение № 13
Группа: Модераторы
Ранг: Старожил
Сообщений: 2043
Репутация: 316 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Здравствуйте Mark1976.
Как вариант.
Длиннее, но тут можно без Отчества (иногда бывает нужно).
Код
=ЛЕВСИМВ(A1;НАЙТИ(" ";A1))&ЕСЛИ(ДЛСТР(A1)-ДЛСТР(ПОДСТАВИТЬ(A1;" ";""))=1;ПСТР(A1;НАЙТИ(" ";A1)+1;1);ПСТР(A1;НАЙТИ(" ";A1)+1;1)&"."&ПСТР(A1;НАЙТИ(" ";A1;НАЙТИ(" ";A1)+1)+1;1))&"."
 
Ответить
СообщениеЗдравствуйте Mark1976.
Как вариант.
Длиннее, но тут можно без Отчества (иногда бывает нужно).
Код
=ЛЕВСИМВ(A1;НАЙТИ(" ";A1))&ЕСЛИ(ДЛСТР(A1)-ДЛСТР(ПОДСТАВИТЬ(A1;" ";""))=1;ПСТР(A1;НАЙТИ(" ";A1)+1;1);ПСТР(A1;НАЙТИ(" ";A1)+1;1)&"."&ПСТР(A1;НАЙТИ(" ";A1;НАЙТИ(" ";A1)+1)+1;1))&"."
Автор - DrMini
Дата добавления - 09.06.2025 в 06:35
Mark1976 Дата: Понедельник, 09.06.2025, 10:07 | Сообщение № 14
Группа: Проверенные
Ранг: Ветеран
Сообщений: 809
Репутация: 3 ±
Замечаний: 0% ±

Excel 2010, 2013
DrMini, Всем спасибо за решения.
 
Ответить
СообщениеDrMini, Всем спасибо за решения.
Автор - Mark1976
Дата добавления - 09.06.2025 в 10:07
DrMini Дата: Понедельник, 09.06.2025, 10:25 | Сообщение № 15
Группа: Модераторы
Ранг: Старожил
Сообщений: 2043
Репутация: 316 ±
Замечаний: 0% ±

Excel LTSC 2024 RUS
Цитата Mark1976, 09.06.2025 в 10:07, в сообщении № 14 ()
Всем спасибо за решения

[moder]Если Вам помогли и Вы хотите сказать "Спасибо" форумчанину помогшему Вам - нажмите "+" напротив надписи "Репутация" в любом его посте.
[p.s.]дополнение к правилам форума.[/p.s.]
[/moder]
 
Ответить
Сообщение
Цитата Mark1976, 09.06.2025 в 10:07, в сообщении № 14 ()
Всем спасибо за решения

[moder]Если Вам помогли и Вы хотите сказать "Спасибо" форумчанину помогшему Вам - нажмите "+" напротив надписи "Репутация" в любом его посте.
[p.s.]дополнение к правилам форума.[/p.s.]
[/moder]
Автор - DrMini
Дата добавления - 09.06.2025 в 10:25
msi2102 Дата: Понедельник, 09.06.2025, 10:34 | Сообщение № 16
Группа: Проверенные
Ранг: Обитатель
Сообщений: 423
Репутация: 130 ±
Замечаний: 0% ±

Excel 2007
Немного экзотики (массивная)
[vba]
Код
=ОБЪЕДИНИТЬ(".";1;ЛЕВСИМВ(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(A1;" ";"</s><s>")&"</s></t>";"//s")))&"."
[/vba]


Сообщение отредактировал msi2102 - Понедельник, 09.06.2025, 10:44
 
Ответить
СообщениеНемного экзотики (массивная)
[vba]
Код
=ОБЪЕДИНИТЬ(".";1;ЛЕВСИМВ(ФИЛЬТР.XML("<t><s>"&ПОДСТАВИТЬ(A1;" ";"</s><s>")&"</s></t>";"//s")))&"."
[/vba]
Автор - msi2102
Дата добавления - 09.06.2025 в 10:34
Mark1976 Дата: Понедельник, 09.06.2025, 11:27 | Сообщение № 17
Группа: Проверенные
Ранг: Ветеран
Сообщений: 809
Репутация: 3 ±
Замечаний: 0% ±

Excel 2010, 2013
DrMini, здравствуйте. Всегда говорю спасибо плюсом. В этот раз еще не успел. Всем + в репутацию.


Сообщение отредактировал Mark1976 - Понедельник, 09.06.2025, 11:37
 
Ответить
СообщениеDrMini, здравствуйте. Всегда говорю спасибо плюсом. В этот раз еще не успел. Всем + в репутацию.
Автор - Mark1976
Дата добавления - 09.06.2025 в 11:27
прохожий2019 Дата: Понедельник, 09.06.2025, 14:25 | Сообщение № 18
Группа: Проверенные
Ранг: Старожил
Сообщений: 1395
Репутация: 364 ±
Замечаний: 0% ±

365 Beta Channel
Цитата msi2102, 09.06.2025 в 10:34, в сообщении № 16 ()
Немного экзотики
ОБЪЕДИНИТЬ появилась в 2019, а у ТС в профиле 2013, так-то ещё во втором сообщении
Код
=СЦЕП(ЛЕВБ(ТЕКСТРАЗД(A1;" "))&".")
 
Ответить
Сообщение
Цитата msi2102, 09.06.2025 в 10:34, в сообщении № 16 ()
Немного экзотики
ОБЪЕДИНИТЬ появилась в 2019, а у ТС в профиле 2013, так-то ещё во втором сообщении
Код
=СЦЕП(ЛЕВБ(ТЕКСТРАЗД(A1;" "))&".")
Автор - прохожий2019
Дата добавления - 09.06.2025 в 14:25
msi2102 Дата: Понедельник, 09.06.2025, 14:56 | Сообщение № 19
Группа: Проверенные
Ранг: Обитатель
Сообщений: 423
Репутация: 130 ±
Замечаний: 0% ±

Excel 2007
Цитата прохожий2019, 09.06.2025 в 14:25, в сообщении № 18 ()
а у ТС в профиле 2013, так-то ещё во втором сообщении
у меня вообще до сих пор 2007 стоит, надо исправить :D
 
Ответить
Сообщение
Цитата прохожий2019, 09.06.2025 в 14:25, в сообщении № 18 ()
а у ТС в профиле 2013, так-то ещё во втором сообщении
у меня вообще до сих пор 2007 стоит, надо исправить :D
Автор - msi2102
Дата добавления - 09.06.2025 в 14:56
Мир MS Excel » Вопросы и решения » Вопросы по Excel » Сократить длинные ФИО до коротких ФИО. (Формулы/Formulas)
  • Страница 1 из 1
  • 1
Поиск:

Яндекс.Метрика Яндекс цитирования
© 2010-2025 · Дизайн: MichaelCH · Хостинг от uCoz · При использовании материалов сайта, ссылка на www.excelworld.ru обязательна!