Сократить длинные ФИО до коротких ФИО.

Страница 1 из 1 1
Модератор форума: китин, _Boroda_, DrMini

Сократить длинные ФИО до коротких ФИО. (Формулы/Formulas)

Mark1976

Дата: Среда, 13.11.2024, 19:32 | Сообщение № 1

Группа: Проверенные

Ранг: Ветеран

Сообщений: 815

Репутация: 3 ±

Замечаний: 0% ±

Excel 2010, 2013

Здравствуйте. Есть таблица с данными. В ячейке А3 написано Иванов Иван Иванович мне надо быстро сделать формулой И.И.И. Заранее спасибо.

Ответить

прохожий2019

Дата: Среда, 13.11.2024, 19:54 | Сообщение № 2

Группа: Проверенные

Ранг: Старожил

Сообщений: 1398

Репутация: 364 ±

Замечаний: 0% ±

365 Beta Channel

365

=СЦЕП(ЛЕВБ(ТЕКСТРАЗД(A1;" "))&".")

Сообщение отредактировал прохожий2019 - Среда, 13.11.2024, 20:20

Ответить

i691198

Дата: Среда, 13.11.2024, 20:08 | Сообщение № 3

Группа: Проверенные

Ранг: Обитатель

Сообщений: 423

Репутация: 131 ±

Замечаний: 0% ±

2016

Для старых версий офиса формула длиннее.

=ЛЕВСИМВ(A3;1)&". "&ЛЕВСИМВ(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(A3;" ";ПОВТОР(" ";50));50;50));1)&". " &ЛЕВСИМВ(СЖПРОБЕЛЫ(ПСТР(ПОДСТАВИТЬ(A3;" ";ПОВТОР(" ";50));100;50));1)&"."

Ответить

Mark1976

Дата: Среда, 13.11.2024, 20:17 | Сообщение № 4

Группа: Проверенные

Ранг: Ветеран

Сообщений: 815

Репутация: 3 ±

Замечаний: 0% ±

Excel 2010, 2013

прохожий2019, не получилось.

Ответить

прохожий2019

Дата: Среда, 13.11.2024, 20:17 | Сообщение № 5

Группа: Проверенные

Ранг: Старожил

Сообщений: 1398

Репутация: 364 ±

Замечаний: 0% ±

365 Beta Channel

для старых

=ЛЕВБ(A1)&"."&ПСТР(A1;ПОИСК(" ";A1)+1;1)&"."&ПСТР(A1;ПОИСК(" ";A1;ПОИСК(" ";A1)+1)+1;1)&"."

Ответить

Mark1976

Дата: Среда, 13.11.2024, 20:22 | Сообщение № 6

Группа: Проверенные

Ранг: Ветеран

Сообщений: 815

Репутация: 3 ±

Замечаний: 0% ±

Excel 2010, 2013

прохожий2019, ваша формула сработала. спасибо. Всем спасибо за интерес к теме.

Ответить

2version

Дата: Среда, 13.11.2024, 20:28 | Сообщение № 7

Группа: Пользователи

Ранг: Новичок

Сообщений: 41

Репутация: 2 ±

Замечаний: 0% ±

Здравствуйте, попробуйте так:

=ЛЕВСИМВ(A1;1) & "." & ЛЕВСИМВ(ПСТР(A1;ПОИСК(" ";A1)+1;99);1) & "." & ЛЕВСИМВ(ПСТР(A1;ПОИСК(" ";A1;ПОИСК(" ";A1)+1)+1;99);1) & "."

Сообщение отредактировал 2version - Среда, 13.11.2024, 20:29

Ответить

Egyptian

Дата: Среда, 13.11.2024, 20:59 | Сообщение № 8

Группа: Проверенные

Ранг: Ветеран

Сообщений: 534

Репутация: 196 ±

Замечаний: 0% ±

Excel 2013/2016

Для более коротких имен (типа Чонг Ли, Ю Чжоу и Бен Джонсон) в том числе:

=ЕСЛИОШИБКА(ЗАМЕНИТЬ(ЗАМЕНИТЬ(ЗАМЕНИТЬ(ПОВТОР(".";2);1;1;ЛЕВСИМВ(A3));НАЙТИ(" ";A3)+2;2;ПСТР(A3;НАЙТИ(" ";A3);2)&".");НАЙТИ("@";ПОДСТАВИТЬ(A3;" ";"@";2));2;ПСТР(A3;НАЙТИ("@";ПОДСТАВИТЬ(A3;" ";"@";2));2)&".");ЗАМЕНИТЬ(ЗАМЕНИТЬ(ПОВТОР(".";2);1;1;ЛЕВСИМВ(A3));НАЙТИ(" ";A3)+2;2;ПСТР(A3;НАЙТИ(" ";A3);2)&"."))

Ответить

Nic70y

Дата: Четверг, 14.11.2024, 08:58 | Сообщение № 9

Группа: Друзья

Ранг: Экселист

Сообщений: 9140

Репутация: 2416 ±

Замечаний: 0% ±

Excel 2010

Цитата Egyptian, 13.11.2024 в 20:59, в сообщении № 8 (

писал(а)):

Для более коротких имен

=ПОДСТАВИТЬ(ЛЕВБ(A1)&ПСТР(A1;ПОИСК(" ";A1);2)&ПСТР(A1;ПОИСК(" ";ПОДСТАВИТЬ(A1;" ";;1)&" ")+1;2);" ";".")&"."

ЮMoney 41001841029809

Ответить

Mark1976

Дата: Воскресенье, 08.06.2025, 19:53 | Сообщение № 10

Группа: Проверенные

Ранг: Ветеран

Сообщений: 815

Репутация: 3 ±

Замечаний: 0% ±

Excel 2010, 2013

Здравствуйте. Можно внести изменение в формулу? Надо из Иванов Иван Иванович сделать Иванов И.И. Первое имя в ячейке A2

Сообщение отредактировал Mark1976 - Воскресенье, 08.06.2025, 19:55

Ответить

прохожий2019

Дата: Воскресенье, 08.06.2025, 19:59 | Сообщение № 11

Группа: Проверенные

Ранг: Старожил

Сообщений: 1398

Репутация: 364 ±

Замечаний: 0% ±

365 Beta Channel

Цитата Mark1976, 08.06.2025 в 19:53, в сообщении № 10 (

писал(а)):

Можно внести изменение в формулу?

просто радикальное изменение потребуется...

=ЛЕВБ(A1;ПОИСК(" ";A1))&ПСТР(A1;ПОИСК(" ";A1)+1;1)&"."&ПСТР(A1;ПОИСК(" ";A1;ПОИСК(" ";A1)+1)+1;1)&"."

Ответить

Mark1976

Дата: Воскресенье, 08.06.2025, 20:13 | Сообщение № 12

Группа: Проверенные

Ранг: Ветеран

Сообщений: 815

Репутация: 3 ±

Замечаний: 0% ±

Excel 2010, 2013

прохожий2019, спасибо.

Ответить

DrMini

Дата: Понедельник, 09.06.2025, 06:35 | Сообщение № 13

Группа: Модераторы

Ранг: Старожил

Сообщений: 2057

Репутация: 320 ±

Замечаний: 0% ±

Excel LTSC 2024 RUS

Здравствуйте Mark1976.
Как вариант.
Длиннее, но тут можно без Отчества (иногда бывает нужно).

=ЛЕВСИМВ(A1;НАЙТИ(" ";A1))&ЕСЛИ(ДЛСТР(A1)-ДЛСТР(ПОДСТАВИТЬ(A1;" ";""))=1;ПСТР(A1;НАЙТИ(" ";A1)+1;1);ПСТР(A1;НАЙТИ(" ";A1)+1;1)&"."&ПСТР(A1;НАЙТИ(" ";A1;НАЙТИ(" ";A1)+1)+1;1))&"."