Убрать лишние запятые

Страница 1 из 1 1
Модератор форума: китин, _Boroda_, DrMini

Убрать лишние запятые (Формулы/Formulas)

DM11

Дата: Понедельник, 13.10.2025, 14:02 | Сообщение № 1

Группа: Пользователи

Ранг: Новичок

Сообщений: 20

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

Подскажите пожалуйста, как можно убрать лишние запятые в списке значений.

Есть некая строчка в 50 значений, разделенных запятыми, в конце стоит точка.
Не всегда значений именно 50 - их может быть произвольное число от 1 до 50, из-за чего сточка выглядит так (в примере 50 запятых ставить не буду, представим, что в строке 10 значений): 2, 7, 11, 33, , , , , , .
Такая информация приходит от огромных многоэтажных формул (таблица изначально писалась не мой), поэтому править таблицу до этих строк не вариант.

Поэтому вопрос в том, как можно отформатировать конечную строку в формате "2, 7, 11, 33, , , , , , .", а именно отрезать последние сочетания ", " там, где уже нет значений?
То есть из "2, 7, 11, 33, , , , , , ." сделать "2, 7, 11, 33."
В данном примере нужно удалить 6 правых сочетаний ", ", но их количество заранее неизвестно и может быть любым от 0 до 50.

Заранее огромное спасибо за помощь!

Сообщение отредактировал DM11 - Понедельник, 13.10.2025, 14:04

Ответить

elovkov

Дата: Понедельник, 13.10.2025, 14:08 | Сообщение № 2

Группа: Друзья

Ранг: Ветеран

Сообщений: 523

Репутация: 84 ±

Замечаний: 0% ±

Excel 2013

Неплохо бы пример, я так понимаю с помощью "СЦЕПИТЬ" образуется строчка?
формула как-то так выглядит?

Код

=СЦЕПИТЬ(A1;",";B1;",";C1;",";D1;",";E1;",";F1;",";G1;",";H1;",";I1;",";J1;".")

Умное лицо это еще не признак ума. Все глупости на земле делаются именно с этим выражением лица

Сообщение отредактировал elovkov - Понедельник, 13.10.2025, 14:11

Ответить

bigor

Дата: Понедельник, 13.10.2025, 14:13 | Сообщение № 3

Группа: Проверенные

Ранг: Старожил

Сообщений: 1402

Репутация: 275 ±

Замечаний: 0% ±

нет

DM11, какой офис, в относительно новых есть ОБЪЕДИНИТЬ(), если нужно убрать лишние запятые, меняем их на пробелы и TRIM

Код

=SUBSTITUTE(TRIM(SUBSTITUTE(F42;",";" "));" ";",")

? придется еще одну ПОДСТАВИТЬ использовать для замены ., на .

Ответить

DM11

Дата: Понедельник, 13.10.2025, 14:22 | Сообщение № 4

Группа: Пользователи

Ранг: Новичок

Сообщений: 20

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

> Неплохо бы пример, я так понимаю с помощью "СЦЕПИТЬ" образуется строчка?
формула как-то так выглядит?

elovkov, если бы. ((

Эти строчки образуются по формулам типа

Код

=A102&", "&B102&", "&C102&", "&D102&", "&E102&", "&F102&", "&G102&", "&H102&", "&I102&", "&J102&", "&K102&", "&L102&", "&M102&", "&N102&", "&O102&", "&A103&", "&B103&", "&C103&", "&D103&", "&E103&", "&F103&", "&G103&", "&H103&", "&I103&", "&J103&", "&K103&", "&L103&", "&M103&", "&N103&", "&O103&", "&A104&", "&B104&", "&C104&", "&D104&", "&E104&", "&F104&", "&G104&", "&H104&", "&I104&", "&J104&", "&K104&", "&L104&", "&M104&", "&N104&", "&O104&", "&A105&", "&B105&", "&C105&", "&D105&", "&E105&", "&F105&", "&G105&", "&H105&", "&I105&", "&J105&", "&K105&", "&L105&", "&M105&", "&N105&", "&O105&", "&A106&", "&B106&", "&C106&", "&D106&", "&E106&", "&F106&", "&G106&", "&H106&", "&I106&", "&J106&", "&K106&", "&L106&", "&M106&", "&N106&", "&O106&", "&A107&", "&B107&", "&C107&", "&D107&", "&E107&", "&F107&", "&G107&", "&H107&", "&I107&", "&J107&", "&K107&", "&L107&", "&M107&", "&N107&", "&O107&", "&A108&", "&B108&", "&C108&", "&D108&", "&E108&", "&F108&", "&G108&", "&H108&", "&I108&", "&J108&", "&K108&", "&L108&", "&M108&", "&N108&", "&O108&"."

А ячейки по ссылкам в этой формуле содержат другие формулы типа

Код

=ЕСЛИ(ДВССЫЛ(АДРЕС(100+(ПОИСКПОЗ($C$1;ДВССЫЛ(АДРЕС(101;1;;;ДВССЫЛ(АДРЕС(5;ОКРУГЛВНИЗ((СТРОКА()-90)/10;0);;;)))):ДВССЫЛ(АДРЕС(150;1;;;ДВССЫЛ(АДРЕС(5;ОКРУГЛВНИЗ((СТРОКА()-90)/10;0);;;))));0));(((СТРОКА()-ОКРУГЛВНИЗ(СТРОКА();-1)-1)*15)+СТОЛБЕЦ()-5);;;ДВССЫЛ(АДРЕС(5;ОКРУГЛВНИЗ((СТРОКА()-90)/10;0);;;))))<>"";ЕСЛИ(ДВССЫЛ(АДРЕС(9;(((СТРОКА()-ОКРУГЛВНИЗ(СТРОКА();-1)-1)*15)+СТОЛБЕЦ()-5);;;ДВССЫЛ(АДРЕС(5;ОКРУГЛВНИЗ((СТРОКА()-90)/10;0);;;))))<>"";ТЕКСТ(ДВССЫЛ(АДРЕС(100+(ПОИСКПОЗ($C$1;ДВССЫЛ(АДРЕС(101;1;;;ДВССЫЛ(АДРЕС(5;ОКРУГЛВНИЗ((СТРОКА()-90)/10;0);;;)))):ДВССЫЛ(АДРЕС(150;1;;;ДВССЫЛ(АДРЕС(5;ОКРУГЛВНИЗ((СТРОКА()-90)/10;0);;;))));0));(((СТРОКА()-ОКРУГЛВНИЗ(СТРОКА();-1)-1)*15)+СТОЛБЕЦ()-5);;;ДВССЫЛ(АДРЕС(5;ОКРУГЛВНИЗ((СТРОКА()-90)/10;0);;;))));"ЧЧ:ММ")&" "&ДВССЫЛ(АДРЕС(9;(((СТРОКА()-ОКРУГЛВНИЗ(СТРОКА();-1)-1)*15)+СТОЛБЕЦ()-5);;;ДВССЫЛ(АДРЕС(5;ОКРУГЛВНИЗ((СТРОКА()-90)/10;0);;;))));ТЕКСТ(ДВССЫЛ(АДРЕС(100+(ПОИСКПОЗ($C$1;ДВССЫЛ(АДРЕС(101;1;;;ДВССЫЛ(АДРЕС(5;ОКРУГЛВНИЗ((СТРОКА()-90)/10;0);;;)))):ДВССЫЛ(АДРЕС(150;1;;;ДВССЫЛ(АДРЕС(5;ОКРУГЛВНИЗ((СТРОКА()-90)/10;0);;;))));0));(((СТРОКА()-ОКРУГЛВНИЗ(СТРОКА();-1)-1)*15)+СТОЛБЕЦ()-5);;;ДВССЫЛ(АДРЕС(5;ОКРУГЛВНИЗ((СТРОКА()-90)/10;0);;;))));"ЧЧ:ММ"));"")

Причем таких формул на листах много, с незначительными отличиями.

Поэтому мне кажется, что лучше обрабатывать конечные "2, 7, 11, 33, , , , , , .", чем взрывать себе мозг разбором тех формул (таблицу писал не я).

Сообщение отредактировал DM11 - Понедельник, 13.10.2025, 17:21

Ответить

DM11

Дата: Понедельник, 13.10.2025, 14:23 | Сообщение № 5

Группа: Пользователи

Ранг: Новичок

Сообщений: 20

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

bigor, офис 2013 года.
Спасибо, сейчас буду разбираться в Вашей формуле.

Ответить

_Boroda_

Дата: Понедельник, 13.10.2025, 14:24 | Сообщение № 6

Группа: Админы

Ранг: Местный житель

Сообщений: 16956

Репутация: 6631 ±

Замечаний: ±

2003; 2007; 2010; 2013 RUS

Пример - значит файл Ексель, а не вот это вот все
Вот так попробуйте

Код

=ЛЕВБ(A1;ПОИСК(", ,";ПОДСТАВИТЬ(A1;".";","))-1)&"."

Скажи мне, кудесник, любимец ба’гов...
Платная помощь:
Boroda_Excel@mail.ru
Яндекс-деньги: 41001632713405 | Webmoney: R289877159277; Z102172301748; E177867141995

Ответить

elovkov

Дата: Понедельник, 13.10.2025, 14:37 | Сообщение № 7

Группа: Друзья

Ранг: Ветеран

Сообщений: 523

Репутация: 84 ±

Замечаний: 0% ±

Excel 2013

Цитата DM11, 13.10.2025 в 14:22, в сообщении № 4 (

)

если бы. ((

Ну, на самом деле это почти то же, что и я написал, только сцепка через &
Можно еще использовать пользовательскую функцию Вот тут почитайте, сам пользуюсь это аналог ОБЪЕДИНИТЬ на VBA

Умное лицо это еще не признак ума. Все глупости на земле делаются именно с этим выражением лица

Ответить

DM11

Дата: Понедельник, 13.10.2025, 14:47 | Сообщение № 8

Группа: Пользователи

Ранг: Новичок

Сообщений: 20

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

elovkov, почти то же самое, но вручную править не вариант, т.к. там 40 таких строк в каждой из которых по 50 соединенных через & ссылок на разные ячейки (разных в каждой строке).

bigor, мне очень хорошо подошел Ваш вариант, спасибо Вам огромное!
Я его немного доработал:

Код

=ПОДСТАВИТЬ(ПОДСТАВИТЬ(СЖПРОБЕЛЫ(ПОДСТАВИТЬ(A81;",";" "));" .";".");" ";", ")

- теперь значения разделяются не просто запятыми, а запятыми с пробелом и в конце перед точкой убирается лишняя запятая.
Спасибо!!!

_Boroda_, файл Ексель приложить не могу, т.к. он огромный, плюс конфиденциальная рабочая информация, чтобы её вычистить нужен минимум час, а потом еще и ничего не понятно будет, т.к. все ячейки окажутся пустыми.
Плюс я еще сам до конца не разобрался, как он работает ))

Код

=ЛЕВБ(A1;ПОИСК(", ,";ПОДСТАВИТЬ(A1;".";","))-1)&"."

- за формулу спасибо, сейчас её тоже изучу, как она работает.

Сообщение отредактировал DM11 - Понедельник, 13.10.2025, 17:21

Ответить

DM11

Дата: Понедельник, 13.10.2025, 15:39 | Сообщение № 9

Группа: Пользователи

Ранг: Новичок

Сообщений: 20

Репутация: 0 ±

Замечаний: 0% ±

Excel 2007

Код

=ЛЕВБ(A1;ПОИСК(", ,";ПОДСТАВИТЬ(A1;".";","))-1)&"."

_Boroda_, спасибо за формулу (тоже очень лаконичный рабочий вариант), но я не очень понял, зачем в ней использована функция ПОДСТАВИТЬ.

У меня работает и без нее:

Код

=ЛЕВБ(A1;ПОИСК(", ,";A1)-1)&"."